Проверка начального символа должна быть 'T', а следующие 3 символа должны быть числом в xslt - PullRequest
Новая
       28

Проверка начального символа должна быть 'T', а следующие 3 символа должны быть числом в xslt

5 голосов
/ 05 сентября 2010

Я использую XSLT1.0 для преобразования моего XML.

У меня ниже Tabs.xml 

<?xml version="1.0"?>
<tcm:ListItems xmlns:tcm="http://www.tridion.com/ContentManager/5.0" ID="tcm:481-87289-4" Managed="68">
  <tcm:Item ID="tcm:481-596728-64" Title="T000. Brisbane" pageURL="/australia/brisbane/index.aspx" componentTitle="Overview"/>
  <tcm:Item ID="tcm:481-598671-64" Title="Tabs XML"/>
  <tcm:Item ID="tcm:481-598672-64" Title="T030 Special Offers" pageURL="/australia/brisbane/specialoffers.aspx" componentTitle="Special Offers"/>
  <tcm:Item ID="tcm:481-598673-64" Title="020 Flight Schedules" pageURL="/australia/brisbane/flightschedules.aspx" componentTitle="Flight Schedules"/>
  <tcm:Item ID="tcm:481-598674-64" Title="T010 Guide" pageURL="/australia/brisbane/guide.aspx" componentTitle="Guide"/>
</tcm:ListItems>

И я использую ниже xslt для его преобразования! 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:tcm="http://www.tridion.com/ContentManager/5.0" xmlns:xlink="http://www.w3.org/1999/xlink" xmlns:em="http://www.emirates.com/tridion/schemas" xmlns:tcmse="http://www.tridion.com/ContentManager/5.1/TcmScriptAssistant" exclude-result-prefixes="em xlink tcmse tcm">
  <xsl:output method="xml" version="1.0" encoding="UTF-16" indent="yes"/>
  <xsl:template match="tcm:ListItems">
    <list type="Tabs">
      <xsl:apply-templates select="tcm:Item">
        <xsl:sort select="@Title" order="ascending"/>
      </xsl:apply-templates>
    </list>
  </xsl:template>
  <!-- add field values for each item-->
  <xsl:template match="tcm:Item">
    <xsl:if test="@componentTitle != ''">
      <xsl:element name="tab">
        <xsl:attribute name="id">
          <xsl:value-of select="substring-after(@ID, '-')"/>
        </xsl:attribute>
        <xsl:attribute name="title">
          <xsl:value-of select="@componentTitle"/>
        </xsl:attribute>
        <xsl:attribute name="url">
          <xsl:value-of select="@pageURL"/>
        </xsl:attribute>
      </xsl:element>
    </xsl:if>
  </xsl:template>
</xsl:stylesheet>

Раньше все работало нормально, но теперь требуется еще одно изменение, теперь мне нужно отобразить те узлы, чей @Title начинается с 'T' или 't', а следующие 3 символа должны быть числами дляПример выше xml «Расписание полетов» не должно прийти, я полагаю, мне просто нужно написать еще одно и условие в <xsl:if test="@componentTitle != ''">,

Пожалуйста, предложите!как это можно сделать!

Ответы [ 5 ]

2 голосов
/ 09 сентября 2010

Вот самое простое выражение, которое выполнит сопоставление: 

translate(substring(@Title, 1, 4), 't12345679', 'T000000000') = 'T000'

Вот шаблон: 

<xsl:template match="
 tcm:Item[translate(substring(@Title, 1, 4), 't12345679', 'T000000000') = 'T000'
 and @componentTitle != '' "/>
1 голос
/ 05 сентября 2010

Логика выбора лучше всего поместить в шаблон соответствия шаблона - и это тоже можно немного упростить. 

<xsl:template match=
 "tcm:Item[contains('tT', substring(@Title,1,1))
         and
           number(substring(@Title,2,3)) 
          =    
           number(substring(@Title,2,3)) 
          ]
 ">

Одно правило, которое нужно запомнить: всегда проверять, представляет ли какая-либо строка $s число - например:

number($s) = number($s)

1 голос
/ 05 сентября 2010

Вы должны выбрать узлы, с которыми вы хотите работать в ваших шаблонах, в элементе apply-templates: 

<xsl:apply-templates select="tcm:Item[@componentTitle != '' 
                           and (starts-with(translate(@Title, 't', 'T'), 'T') 
                           and string(number(substring(@Title,2,3))) != 'NaN')]">

Я использовал тест, который @solution разработал для этого - он хорошо работает по требованию (проверено здесь ).

Это лучше, чем выбирать все tcm:Item узлы и тестировать их по одному в шаблоне.

0 голосов
/ 05 сентября 2010

Я придумала решение ниже, пожалуйста, предложите, если оно в порядке! 

<xsl:template match="tcm:Item">
    <xsl:if test="@componentTitle != '' and (starts-with(translate(@Title, 't', 'T'), 'T')and string(number(substring(@Title,2,3))) != 'NaN')">
      <xsl:element name="tab">
        <xsl:attribute name="id">
          <xsl:value-of select="substring-after(@ID, '-')"/>
        </xsl:attribute>
        <xsl:attribute name="title">
          <xsl:value-of select="@componentTitle"/>
        </xsl:attribute>
        <xsl:attribute name="url">
          <xsl:value-of select="@pageURL"/>
        </xsl:attribute>
      </xsl:element>
    </xsl:if>
  </xsl:template>

Требуется все ваши данные!

0 голосов
/ 05 сентября 2010

Работая с XSLT только изредка, я пришел к следующему решению: 

<xsl:if test="@componentTitle != ''">
  <xsl:if test="starts-with(@Title,'T') or starts-with(@Title,'t')"> 
    <xsl:if test="string-length(@Title) &gt; 3">
      <xsl:if test="string(number(substring(@Title,2,3))) != 'NaN'"> 
...
      </xsl:if>
    </xsl:if>
  </xsl:if>
</xsl:if>

Я заметил, что есть также функции lower-case / upper-case, которые можно использовать для тестирования для первогосимвол t или T, но, похоже, он доступен только в XSLT2.0.

...