Почему я получаю NPE в следующем коде? - PullRequest
Новая
       8

Почему я получаю NPE в следующем коде?

7 голосов
/ 14 июля 2010

Следующий код выполняется должным образом, но в конце выдает NullPointerException.Что я здесь не так делаю? 

(ns my-first-macro)

(defmacro exec-all [& commands]
  (map (fn [c] `(println "Code: " '~c "\t=>\tResult: " ~c)) commands))

(exec-all
  (cons 2 [4 5 6])
  ({:k 3 :m 8} :k)
  (conj [4 5 \d] \e \f))

; Output:
; Clojure 1.2.0-master-SNAPSHOT
; Code:  (cons 2 [4 5 6])   =>  Result:  (2 4 5 6)
; Code:  ({:k 3, :m 8} :k)  =>  Result:  3
; Code:  (conj [4 5 d] e f)     =>  Result:  [4 5 d e f]
; java.lang.NullPointerException (MyFirstMacro.clj:0)
; 1:1 user=> #<Namespace my-first-macro>
; 1:2 my-first-macro=>

(для правильного синтаксиса выделенного кода, перейдите здесь .)

Ответы [ 2 ]

11 голосов
/ 14 июля 2010

Посмотрите на происходящее расширение: 

(macroexpand '(exec-all (cons 2 [4 5 6])))
=>
((clojure.core/println "Code: " (quote (cons 2 [4 5 6])) "\t=>\tResult: " (cons 2 [4 5 6])))

Как видите, вокруг вашего расширения есть дополнительная пара скобок, что означает, что Clojure пытается выполнить результат printlnфункция, которая равна nil.

Чтобы исправить это, я бы предложил изменить макрос так, чтобы он включал "do" в начале, например 

(defmacro exec-all [& commands]
  (cons 'do (map (fn [c] `(println "Code: " '~c "\t=>\tResult: " ~c)) commands)))
6 голосов
/ 14 июля 2010

Поскольку ОП запросил другие возможные способы написания этого макроса (см. Комментарии к принятому ответу), здесь идет речь: 

(defmacro exec-all [& commands]
  `(doseq [c# ~(vec (map (fn [c]
                           `(fn [] (println "Code: " '~c "=> Result: " ~c)))
                         commands))]
     (c#)))

Это расширяется до чего-то вроде 

(doseq [c [(fn []
             (println "Code: "      '(conj [2 3 4] 5)
                      "=> Result: " (conj [2 3 4] 5)))
           (fn []
             (println "Code: "      '(+ 1 2)
                      "=> Result: " (+ 1 2)))]]
  (c))

Обратите внимание, что формы fn, значения которых будут связаны с c, собираются в векторе во время расширения макроса.

Излишне говорить, что оригинальная версия проще, поэтому я думаю, что (do ...)идеальное решение.: -)

Пример взаимодействия: 

user=> (exec-all (conj [2 3 4] 5) (+ 1 2))                                                                                                    
Code:  (conj [2 3 4] 5) => Result:  [2 3 4 5]
Code:  (+ 1 2) => Result:  3
nil
...