Разделить коллекцию на подколлекции в Groovy

Question

У меня есть массив, содержащий неизвестное количество элементов, которые я хотел бы разделить на отдельные массивы, чтобы каждый отдельный массив содержал не более 4 элементов. Каков наилучший способ сделать это в Groovy? Спасибо!

Answer 1

У нас было это здесь: Как разбить список на списки одинакового размера в Groovy?

Я придумал это:

List.metaClass.partition = { size ->
  def rslt = delegate.inject( [ [] ] ) { ret, elem ->
    ( ret.last() << elem ).size() >= size ? ret << [] : ret
  }
  !rslt.last() ? rslt[ 0..-2 ] : rslt
}

def list = [1, 2, 3, 4, 5, 6].partition( 4 )

Что должно дать вам:

[ [ 1, 2, 3, 4 ], [ 5, 6 ] ]

Обновление!

С Groovy 1.8.6+ вы можете использовать list.collate( 4 ), чтобы получить тот же результат

Answer 2

Ответ tim_yates - это круто, но он выбрасывает java.lang.ArrayIndexOutOfBoundsException в пустые списки (например: [].partition(4)). Это можно исправить следующим образом:

List.metaClass.partition = {size ->
    if (!delegate)
        return []

    def rslt = delegate.inject([[]]) {ret, elem ->
        (ret.last() << elem).size() >= size ? (ret << []) : ret
    }
    !rslt.last() ? rslt[0..-2] : rslt
}

assert [].partition(4) == []
assert [1, 2, 3, 4, 5, 6].partition(4) == [[1, 2, 3, 4], [5, 6]]

Answer 3

Начиная с Groovy 1.8.6, вы можете использовать сопоставление:

def letters = 'a'..'g'
assert letters.collate(3) == [['a', 'b', 'c'], ['d', 'e', 'f'], ['g']]

def letters = 'a'..'g'
assert letters.collate(3) == [['a', 'b', 'c'], ['d', 'e', 'f'], ['g']]

Благодарность за сериал Mrhaki's Groovy: http://mrhaki.blogspot.com.au/2012/04/groovy-goodness-collate-list-into-sub.html