XSLT: как получить список всех используемых пространств имен - PullRequest
Новая
       4

XSLT: как получить список всех используемых пространств имен

10 голосов
/ 19 сентября 2010

Я пишу таблицу стилей XSLT 1.0 для преобразования XML-документов с несколькими пространствами имен в HTML.В каком-то месте в результате HTML я хочу перечислить все пространства имен, которые произошли в документе.

Это возможно?

Я думал о чем-то вроде 

<xsl:for-each select="//*|//@*">
  <xsl:value-of select="namespace-uri(.)" />
</xsl:for-each>

но, конечно, я получил бы миллиарды дубликатов.Поэтому мне придется как-то отфильтровать то, что я уже напечатал.

Рекурсивный вызов шаблонов будет работать, но я не могу понять, как добраться до всех элементов.

Доступ к //@xmlns:* напрямую не работает, потому что никто не может получить к нему доступ через XPath (нельзя привязывать какой-либо префикс к пространству имен xmlns:).

Ответы [ 2 ]

7 голосов
/ 20 сентября 2010

Другой без функций расширения: 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="*">
        <xsl:param name="pNamespaces" select="'&#xA;'"/>
        <xsl:variable name="vNamespaces">
            <xsl:variable name="vMyNamespaces">
                <xsl:value-of select="$pNamespaces"/>
                <xsl:for-each select="namespace::*
                                        [not(contains(
                                                 $pNamespaces,
                                                 concat('&#xA;',.,'&#xA;')))]">
                    <xsl:value-of select="concat(.,'&#xA;')"/>
                </xsl:for-each>
            </xsl:variable>
            <xsl:variable name="vChildsNamespaces">
                <xsl:apply-templates select="*[1]">
                    <xsl:with-param name="pNamespaces"
                                        select="$vMyNamespaces"/>
                </xsl:apply-templates>
            </xsl:variable>
            <xsl:value-of select="concat(substring($vMyNamespaces,
                                                   1 div not(*)),
                                         substring($vChildsNamespaces,
                                                   1 div boolean(*)))"/>
        </xsl:variable>
        <xsl:variable name="vFollowNamespaces">
            <xsl:apply-templates select="following-sibling::*[1]">
                <xsl:with-param name="pNamespaces" select="$vNamespaces"/>
            </xsl:apply-templates>
        </xsl:variable>
        <xsl:value-of
             select="concat(substring($vNamespaces,
                                      1 div not(following-sibling::*)),
                            substring($vFollowNamespaces,
                                      1 div boolean(following-sibling::*)))"/>
    </xsl:template>
</xsl:stylesheet>

Выход (с входным образцом Димитра): 

http://www.w3.org/XML/1998/namespace
mynamespace
mynamespace2
mynamespace3

РЕДАКТИРОВАТЬ : Также это выражение XPath: 

//*/namespace::*[not(. = ../../namespace::*|preceding::*/namespace::*)]

В качестве доказательства эта таблица стилей: 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:template match="/">
        <xsl:for-each select="//*/namespace::*
                                     [not(. = ../../namespace::*|
                                              preceding::*/namespace::*)]">
            <xsl:value-of select="concat(.,'&#xA;')"/>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

Вывод: 

http://www.w3.org/XML/1998/namespace
mynamespace
mynamespace2
mynamespace3

РЕДАКТИРОВАНИЕ 4: То же, что и двухпроходное преобразование.

Эта таблица стилей: 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:key name="kElemByNSURI"
             match="*[namespace::*[not(. = ../../namespace::*)]]"
              use="namespace::*[not(. = ../../namespace::*)]"/>
    <xsl:template match="/">
        <xsl:for-each select=
            "//namespace::*[not(. = ../../namespace::*)]
                           [count(..|key('kElemByNSURI',.)[1])=1]">
            <xsl:value-of select="concat(.,'&#xA;')"/>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

Вывод: 

http://www.w3.org/XML/1998/namespace
mynamespace
mynamespace2
mynamespace3

EDIT 5: когда вы имеете дело с процессором XSLT без namespace реализации ax(Как и TransforMiix), вы можете извлечь только те пространства имен, которые фактически используются с этой таблицей стилей: 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:key name="kElemByNSURI" match="*|@*" use="namespace-uri()"/>
    <xsl:template match="/">
        <xsl:for-each select=
            "(//*|//@*)[namespace-uri()!='']
                       [count(.|key('kElemByNSURI',namespace-uri())[1])=1]">
            <xsl:value-of select="concat(namespace-uri(),'&#xA;')"/>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

TransforMiix: 

mynamespace2
5 голосов
/ 19 сентября 2010

Это преобразование : 

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>
 <xsl:template match="/">
   <xsl:for-each select=
    "//namespace::*[not(. = ../../namespace::*)]">
     <xsl:value-of select="concat(.,'&#xA;')"/>
   </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

при применении к этому документу XML : 

<authors xmlns:user="mynamespace">
  <?ttt This is a PI ?>
  <author xmlns:user2="mynamespace2">
    <name idd="VH">Victor Hugo</name>
    <user2:name idd="VH">Victor Hugo</user2:name>
    <nationality xmlns:user3="mynamespace3">French</nationality>
  </author>
</authors>

создает искомое значение,правильный результат : 

http://www.w3.org/XML/1998/namespace
mynamespace
mynamespace2
mynamespace3

Обновление :

Как прокомментировал @svick, вышеупомянутое решение все равно будет иногда создавать дублированные пространства имен, такие как в следующем XMLdocument: 

<authors xmlns:user="mynamespace">
  <?ttt This is a PI ?>
  <author xmlns:user2="mynamespace2">
    <name idd="VH">Victor Hugo</name>
    <user2:name idd="VH">Victor Hugo</user2:name>
    <nationality xmlns:user3="mynamespace3">French</nationality>
  </author>
  <t xmlns:user2="mynamespace2"/>
</authors>

пространство имен "mynamespace2" будет дважды создано в выводе.

Следующее преобразование устраняет эту проблему : 

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common"
 exclude-result-prefixes="ext">
 <xsl:output method="text"/>

 <xsl:key name="kNSbyURI" match="n" use="."/>

 <xsl:template match="/">
   <xsl:variable name="vrtfNS">
       <xsl:for-each select=
        "//namespace::*[not(. = ../../namespace::*)]">
         <n><xsl:value-of select="."/></n>
       </xsl:for-each>
   </xsl:variable>

   <xsl:variable name="vNS" select="ext:node-set($vrtfNS)/*"/>

   <xsl:for-each select=
    "$vNS[generate-id()
         =
          generate-id(key('kNSbyURI',.)[1])
         ]">
     <xsl:value-of select="concat(., '&#xA;')"/>
   </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

Когда это преобразование применяется к вышеуказанному XML-документу, оно создает только все уникальные пространства имен в документе : 

http://www.w3.org/XML/1998/namespace
mynamespace
mynamespace2
mynamespace3

Часть II: решение XSLT 2.0 .

Решение XSLT 2.0 представляет собой простой однострочный XPath 2.0: 

distinct-values(//namespace::*)
...