Как я могу изменить регистр хеш-ключа?

Question

Я пишу сценарий, который может быть изменен пользователями. В настоящее время я храню настройки конфигурации внутри скрипта. Он существует в виде хэша хэшей.

Я хотел бы защититься от людей, случайно использующих строчные символы в хеш-ключах, потому что это сломает мой сценарий.

Было бы просто проверить ключи хеша и просто выдавать предупреждения для любых клавиш с строчными буквами, но я бы лучше исправил чувствительность к регистру автоматически.

Другими словами, я хочу преобразовать все ключи хеша в хеше верхнего уровня в верхний регистр.

Answer 1

Ответ Энди является хорошим ответом, за исключением того, что он uc с каждым ключом, а затем uc с, если он не совпадает.

Это uc один раз:

%hash = map { uc $_ => $hash{$_} } keys %hash;

Но поскольку вы говорили о пользователях , хранящих ключи , связывание является гораздо более надежным способом, даже если и медленнее.

package UCaseHash;
require Tie::Hash;

our @ISA = qw<Tie::StdHash>;

sub FETCH { 
    my ( $self, $key ) = @_;
    return $self->{ uc $key };
}

sub STORE { 
    my ( $self, $key, $value ) = @_;
    $self->{ uc $key } = $value;
}

1;

А потом в основном:

tie my %hash, 'UCaseHash'; 

Это шоу. tie «магия» заключает его в капсулу, поэтому пользователи не могут неосознанно возиться с ним.

Конечно, пока вы используете «класс», вы можете передать имя файла конфигурации и инициализировать его оттуда:

package UCaseHash;
use Tie::Hash;
use Carp qw<croak>;

...

sub TIEHASH { 
    my ( $class_name, $config_file_path ) = @_;
    my $self = $class_name->SUPER::TIEHASH;
    open my $fh, '<', $config_file_path 
        or croak "Could not open config file $config_file_path!"
        ;
    my %phash = _process_config_lines( <$fh> );
    close $fh;
    $self->STORE( $_, $phash{$_} ) foreach keys %phash;
    return $self;
}

Где вы должны были бы назвать это как:

tie my %hash, 'UCaseHash', CONFIG_FILE_PATH;

... при условии некоторой константы CONFIG_FILE_PATH.

Answer 2

Пройдите по хешу и замените все строчные ключи их прописными эквивалентами и удалите старые. Грубо говоря:

for my $key ( grep { uc($_) ne $_ } keys %hash ) {
    my $newkey = uc $key;
    $hash{$newkey} = delete $hash{$key};
}

Answer 3

Это преобразует многоуровневый хэш в нижний регистр

my $lowercaseghash = convertmaptolowercase(\%hash);

sub convertmaptolowercase(){
    my $output=$_[0];
    while(my($key,$value) = each(%$output)){
        my $ref;
        if(ref($value) eq "HASH"){
            $ref=convertmaptolowercase($value);
        } else {
           $ref=$value;
        }
        delete $output->{$key}; #Removing the existing key
        $key = lc $key;
        $output->{$key}=$ref; #Adding new key
    }
    return $output;
}