программным способом убрать указатель пролистывания компонента гибкого списка

Question

Кто-нибудь знает, как добавить пользовательские rolloveridicatorskins к компоненту списка flex 3?в css нет ролловеридаторской кожи.

Answer 1

Вот код.

package 
    {
        import flash.display.Graphics;
        import flash.display.Sprite;
        import flash.filters.DropShadowFilter;

        import mx.controls.List;
        import mx.controls.listClasses.IListItemRenderer;
        import mx.core.ClassFactory;


        public class friendList extends List
        {
            private var dropShadow:DropShadowFilter = new DropShadowFilter(2,117,0x000000,0.4);
            private var filtersArray:Array = new Array(dropShadow); 

           override protected function drawSelectionIndicator(indicator:Sprite, x:Number,
               y:Number, width:Number, height:Number, color:uint,
               itemRenderer:IListItemRenderer):void

           {

              var g:Graphics = Sprite(indicator).graphics;
              g.clear();
              g.beginFill(0x000000, 0.5);
              g.lineStyle(2,0xffffff,0.5);
              g.drawRoundRect(0, 0, width-2, height-2, 6);
              g.endFill();

              indicator.x = x;
              indicator.y = y;   
              indicator.filters = filtersArray;
           }
           override protected function drawHighlightIndicator(
                                    indicator:Sprite, x:Number, y:Number,
                                    width:Number, height:Number, color:uint,
                                    itemRenderer:IListItemRenderer):void
            {
                var g:Graphics = Sprite(indicator).graphics;
                g.clear();
                g.beginFill(0x163e76, 0.5);
                g.lineStyle(2,0xffffff,0.5);
                g.drawRoundRect(0, 0, width-2, height-2, 6);
                g.endFill();

                indicator.x = x;
                indicator.y = y;
                indicator.filters = filtersArray;
            }
       }
    }

Answer 2

Если вы просто хотите изменить цвет фона и текста отображаемых элементов, класс ListBase определяет следующие стили:

• rollOverColor
  • Цвет фона рендерера, когда пользователь переворачивает его.
  • Значение по умолчанию: 0xEEFEE6.
• textRollOverColor
  • Цвет текста средства визуализации, когда пользователь переворачивает его.,
  • Значением по умолчанию является 0x2B333C.

Так что-то вроде:

<mx:List rollOverColor="#FF0000" textRollOverColor="#FFFF00"/>

Даст вам желтый текст на красном фоне (!) при наведении мыши на элемент.