Как начать работу с обработки на Flash CS5? - PullRequest
Новая
       6

Как начать работу с обработки на Flash CS5?

0 голосов
/ 31 января 2011

Я использую процессинг уже около двух лет, и мне это очень нравится. Тем не менее, я чувствую, что Flash немного более полезен для кодирования игр, поскольку он более универсален и гибок. Я начинаю чувствовать, что понятия не имею, что делаю, и у меня действительно нет таких понятий, как видеоклипы, сцена и так далее. В Обработка, скажем, для мяча, я мог бы сделать это: 

<code>Ball[] ballArray = new Ball[ 0 ]; //Array to store each ball in</p>

<p>void setup()
{
size( 400, 400 );
}</p>

<p>void draw()
{
background( 255 );
for( int i = 0; i < ballArray.length; i++ )
{
ballArray[ i ].display(); //Run each ball's display code every time step
}
}</p>

<p>class Ball
{
PVector location; //Vector to store this ball's location in
Ball( int x, int y )
{
location = new PVector( x, y );
ballArray = ( Ball[] ) append( ballArray, this ); //Add this ball to the array
}
void display()
{
fill( 0 );
ellipse( location.x, location.y ); //Display this ball at its location
}
}</p>

<p>void mousePressed()
{
new Ball( mouseX, mouseY ); //Create a new ball at the mouse location
}

И это позволило бы мне создавать столько экземпляров, сколько мне нравится, где угодно. Я не имею ни малейшего понятия, как создать аналогичный апплет во Flash. Я попытался создать класс 'ball' в отдельном файле .as, но он выдает ошибку из-за слишком большого количества аргументов. Я также не знаю, как нарисовать фигуру прямо на экране.

Может кто-нибудь подобрать это во Flash, чтобы у меня было с чего начать? Также было бы здорово, если бы я мог порекомендовать почитать общее количество флеш нубов, или разработчики переходят с Java на Flash.

Ответы [ 2 ]

3 голосов
/ 31 января 2011

Ниже приведен простой флэш-фильм / приложение, которое создает новый экземпляр Ball и добавляет его на сцену, когда и где вы щелкаете мышью на сцене. Также при каждом создании нового экземпляра Ball он добавляется в массив из Ball объектов, называемых _balls.

Main.as (класс документа): 

package
{
    import com.display.Ball;
    import flash.display.Sprite;
    import flash.events.MouseEvent;

    public class Main extends Sprite
    {
        private var _balls:Array;

        public function Main()
        {
            init();

        }// end function

        private function init():void
        {
            _balls = new Array();

            stage.addEventListener(MouseEvent.CLICK, onStageMouseClick);

        }// end function

        private function onStageMouseClick(e:MouseEvent):void
        {
            createBall(e.stageX, e.stageY); 

        }// end function

        private function createBall(p_x:Number, p_y:Number):void
        {
            var ball:Ball = new Ball(p_x, p_y);
            addChild(ball);
            _balls.push(ball);

        }// end function

    }// end class

}// end package

Ball.as: 

package com.display
{
    import flash.display.Sprite;

    public class Ball extends Sprite
    {
        private var _radius:Number = 50;
        private var _x:Number;
        private var _y:Number;
        private var _color:uint = 0xFF0000; // red

        public function Ball(p_x:Number, p_y:Number)
        {
            _x = p_x;
            _y = p_y;

            init();

        }// end function

        public function init():void
        {
            draw();

        }// end function

        public function draw():void
        {
            this.graphics.beginFill(_color);
            this.graphics.drawCircle(_x, _y, _radius);
            this.graphics.endFill();

        }// end function

    }// end class

}// end package

Я рекомендую прочесть книгу «Библия ActionScript 3.0 Роджера Браунштейна» для флеш (а также флекс) «нубов». Кроме того, даже если вы знакомы с ActionScript 3, он служит хорошим справочным пособием.

Кроме того, как только вы начнете хорошо понимать ActionScript 3, вы можете рассмотреть возможность вступления в сферу шаблонов проектирования. Чтобы упростить шаблоны проектирования в простом предложении, вероятно, они будут «инструментами для того, чтобы справляться с постоянными изменениями в проектировании и разработке программного обеспечения». Я рекомендую прочитать «О'Рейли, шаблоны проектирования ActionScript 3.0 Уильяма Сандерса и Чандима Кумаранатунге».

0 голосов
/ 31 января 2011

Посмотрите видеоурок Коллин Мука «Потерянный ActionScript Week End», он даст вам хороший обзор ActionScript и достаточное понимание, чтобы применить свои знания по обработке во Flash. Помните, что в Processing многие методы скрыты от вас, и вам, возможно, придется написать намного больше кода, чтобы адаптировать концепции Processing к AS3.

http://tv.adobe.com/show/colin-moocks-lost-actionscript-weekend/

...