Комплексное XSL-преобразование - PullRequest
Новая
       5

Комплексное XSL-преобразование

0 голосов
/ 30 июня 2010

Я все еще начинающий с XSLT, но передо мной стоит сложная задача.

У меня есть не XML-файл, который необходимо преобразовать. Формат файла следующий: 

type1
type1line1
type1line2
type1line3
type2
type2line1
type2line2
type3
type3line1
type3line2

типы (type1, type2, ...) указываются с использованием определенных кодов, которые не имеют определенного порядка. Каждый тип имеет несколько line внизу.

Итак, мне нужно преобразовать этот файл, но проблема в том, что для каждого type мне нужно выполнить разные преобразования для каждой из его базовых строк.

Теперь я могу читать строку за строкой и определять, что новый тип начался, но я не знаю, как установить флаг (указывающий тип), чтобы использовать его в нижележащих строках.

Вот что у меня сейчас есть: 

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" version="2.0">  
  <xsl:param name="testString" as="xs:string">
  type1
  line1
  line2
  type1
  line1 
  </xsl:param>  
  <xsl:template match="/"> 
    <xsl:call-template name="main"> 
      <xsl:with-param name="testString" select="$testString"/> 
    </xsl:call-template> 
  </xsl:template>  

  <xsl:template name="main"> 
    <xsl:param name="testString"/>
    <xsl:variable name="iniFile" select="$testString"/>  
    <config> 
      <xsl:analyze-string select="$iniFile" regex="\n"> 
        <xsl:non-matching-substring> 
          <item> 
            <xsl:choose> 
              <xsl:when test="starts-with(., 'type1')">
   <!-- do a specific transformation-->     
              </xsl:when> 
              <xsl:when test="starts-with(., 'type2')">
   <!-- do another transformation-->      
              </xsl:when>
            </xsl:choose> 
          </item> 
        </xsl:non-matching-substring> 
      </xsl:analyze-string> 
    </config> 
  </xsl:template> 
</xsl:stylesheet>

Любая идея о том, как решить проблему.

1 Ответ

0 голосов
/ 02 июля 2010

Я думаю, что XSLT 2.1 позволит вам использовать его мощные вещи, такие как for-each-group, для последовательностей атомарных значений, таких как строки, но с XSLT 2.0 у вас есть такие мощные функции только для последовательностей узлов, поэтому мой первый шаг при использовании XSLT 2.0с простыми строковыми данными, которые я хочу обработать / создать группу.Таким образом, вы можете токенизировать свои данные, обернуть каждый токен в некоторый элемент, а затем использовать для каждой группы начало группы с, чтобы обработать каждую группу, начиная с некоторого шаблона, например '^ type [0-9] + $'.Вы действительно не сказали нам, что вы хотите с данными, после того как вы определили группу, поэтому возьмите в качестве примера следующий пример, который вы можете адаптировать: 

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="2.0"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="xs">

  <xsl:output method="xml" indent="yes"/>

  <xsl:param name="input" as="xs:string">type1
type1line1
type1line2
type1line3
type2
type2line1
type2line2
type3
type3line1
type3line2</xsl:param>

   <xsl:template name="main">
     <xsl:variable name="lines" as="element(item)*">
       <xsl:for-each select="tokenize($input, '\n')">
         <item><xsl:value-of select="."/></item>
       </xsl:for-each>
     </xsl:variable>
     <xsl:for-each-group select="$lines" group-starting-with="item[matches(., '^type[0-9]+$')]">
       <xsl:choose>
         <xsl:when test=". = 'type1'">
           <xsl:apply-templates select="current-group() except ." mode="m1"/>
         </xsl:when>
         <xsl:when test=". = 'type2'">
           <xsl:apply-templates select="current-group() except ." mode="m2"/>
         </xsl:when>
         <xsl:when test=". = 'type3'">
           <xsl:apply-templates select="current-group() except ." mode="m3"/>
         </xsl:when>
       </xsl:choose>
     </xsl:for-each-group>
   </xsl:template>

   <xsl:template match="item" mode="m1">
     <foo>
       <xsl:value-of select="."/>
     </foo>
   </xsl:template>

   <xsl:template match="item" mode="m2">
     <bar>
       <xsl:value-of select="."/>
     </bar>
   </xsl:template>

   <xsl:template match="item" mode="m3">
     <baz>
       <xsl:value-of select="."/>
     </baz>
   </xsl:template>

</xsl:stylesheet>

При применении с Saxon 9 (параметры командной строки -it: main -xsl: sheet.xsl) результат равен 

<foo>type1line1</foo>
<foo>type1line2</foo>
<foo>type1line3</foo>
<bar>type2line1</bar>
<bar>type2line2</bar>
<baz>type3line1</baz>
<baz>type3line2</baz>
...