Как мне написать таблицу стилей xsl для перевода частей документа на основе содержимого совпадающих тегов ... вроде? - PullRequest
Новая
       0

Как мне написать таблицу стилей xsl для перевода частей документа на основе содержимого совпадающих тегов ... вроде?

2 голосов
/ 29 октября 2010

У меня есть xml-структура, которая выглядит примерно так: 

<Page>
 <Id>Page1</Id>
 <Content>
  <Header>This is the Header</Header>
  <Body>This is the body</Body>
  <Nested>
   <NestedItem>
    <Id>N1</Id>
    <Content>This is a nested element</Content>
   </NestedItem>
   <NestedItem>
    <Id>N2</Id>
    <Content>This too is a nested element</Content>
   </NestedItem>
  </Nested>
 </Content>
 <Localizations>
  <Localization>
   <Locale>ES</Locale>
   <Content>
    <Header>Esta un caballo</Header>
    <Body>Esta body</Body>
    <Nested>
     <NestedItem>
      <Id>N2</Id>
      <Content>Esta una element nestado</Content>
     </NestedItem>
    </Nested>
   </Content>
  <Localization>
 </Localizations>
</Page>

и после xslt-преобразования, в которое я передаю переменную "ES", в данном случае я хочу, чтобы она выгляделачто-то вроде этого: 

<Page>
 <Id>Page1</Id>
 <Content>
  <Header>Esta un caballo</Header>
  <Body>Esta body</Body>
  <Nested>
   <NestedItem>
    <Id>N1</Id>
    <Content>This is a nested element</Content>
   </NestedItem>
   <NestedItem>
    <Id>N2</Id>
    <Content>Esta una element nestado</Content>
   </NestedItem>
  </Nested>
 </Content>
</Page>

т.е. я хочу перевести элементы, имеющие соответствующие элементы в локализацию, но сохранить исходный текст там, где есть оригинальный текст.Дело в том, что структура элемента содержимого может быть неизвестна, поэтому я не могу использовать определенные имена тегов в xsl-файле.

пока, я пришел с этим: 

<?xml version="1.0" encoding="utf-8"?>

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" encoding="utf-8" doctype-public="-//W3C//DTD XHTML 1.0 Transitional//EN" doctype-system="http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd"/>
<xsl:param name="locale"></xsl:param>





<xsl:template match="/" name="foo">

  <xsl:for-each select="./*">
   <xsl:if test="name() != 'Localizations'">
    <xsl:element name="{name()}">

     <xsl:variable name="elementName" select="name()"/>
     <xsl:variable name="elementId" select="Id"/>

     <xsl:variable name="elementContent">
      <xsl:value-of select="./text()" />
     </xsl:variable> 

     <xsl:variable name="localContent">
      <xsl:for-each select="./ancestor::Page[1]/Localizations/Localization">
       <xsl:if test="./Locale = $locale">

          <xsl:copy-of select="*[name()=$elementName]/*"/>

       </xsl:if>
      </xsl:for-each>
     </xsl:variable> 

       <xsl:copy-of select="$localContent"/>
       <xsl:call-template name="foo"/>


    </xsl:element>

   </xsl:if>
  </xsl:for-each>  


</xsl:template>


</xsl:stylesheet>

, который выводит xml в порядке, но он создает дубликаты элементов в теге содержимого и только испанский контентостальные теги остаются пустыми.Я вообще правильно иду по этому поводу?Любые указатели будут оценены, справочники по xslt довольно сложно найти, и я пытаюсь научить себя здесь ...

Ответы [ 3 ]

2 голосов
/ 29 октября 2010

Это преобразование : 

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:key name="kContentByElName" match="Localization/Content/*"
  use="name()"/>

 <xsl:key name="kNestedById" match="Localization/Content/Nested/NestedItem"
  use="Id"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="/*/Content/*[not(self::Nested)]/text()">
   <xsl:variable name="vTranslation"
        select="key('kContentByElName', name(..))"/>
   <xsl:value-of select="$vTranslation | self::node()[not($vTranslation)]"/>
 </xsl:template>

 <xsl:template match=
   "NestedItem[not(ancestor::Localization)]/Content/text()">
   <xsl:variable name="vTranslation"
        select="key('kNestedById', ../../Id)/Content"/>
   <xsl:value-of select="$vTranslation | self::node()[not($vTranslation)]"/>
 </xsl:template>

 <xsl:template match="Localizations"/>
</xsl:stylesheet>

при применении к предоставленному XML-документу : 

<Page>
 <Id>Page1</Id>
 <Content>
  <Header>This is the Header</Header>
  <Body>This is the body</Body>
  <Nested>
   <NestedItem>
    <Id>N1</Id>
    <Content>This is a nested element</Content>
   </NestedItem>
   <NestedItem>
    <Id>N2</Id>
    <Content>This too is a nested element</Content>
   </NestedItem>
  </Nested>
 </Content>
 <Localizations>
  <Localization>
   <Locale>ES</Locale>
   <Content>
    <Header>Esta un caballo</Header>
    <Body>Esta body</Body>
    <Nested>
     <NestedItem>
      <Id>N2</Id>
      <Content>Esta una element nestado</Content>
     </NestedItem>
    </Nested>
   </Content>
  </Localization>
 </Localizations>
</Page>

создает искомое, правильный результат : 

<Page>
   <Id>Page1</Id>
   <Content>
      <Header>Esta un caballo</Header>
      <Body>Esta body</Body>
      <Nested>
         <NestedItem>
            <Id>N1</Id>
            <Content>This is a nested element</Content>
         </NestedItem>
         <NestedItem>
            <Id>N2</Id>
            <Content>Esta una element nestado</Content>
         </NestedItem>
      </Nested>
   </Content>
</Page>

Обратите внимание :

  1. Это чисто решение XSLT 1.0.

  2. Ключи используются для быстрого поиска.

  3. Все узлы копируются «как есть» с использованием правила идентификации .

  4. Шаблоны, соответствующие узлам, нуждающимся в обработке, переопределяют правило идентификации.

  5. При отсутствии перевода оригинальный текст сохраняется.

1 голос
/ 29 октября 2010

Эта таблица стилей: 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:param name="pLang" select="'ES'"/>
    <xsl:key name="kElementByLang"
             match="Localization/Content/*[not(self::Nested)]|
                    Localization/Content/Nested/NestedItem"
             use="concat(ancestor::Localization/Locale,'++',
                         name(),'++',Id)"/>
    <xsl:template match="node()|@*" name="identity">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="Localizations"/>
    <xsl:template match="Page/Content//*">
        <xsl:variable name="vMatch"
                      select="key('kElementByLang',
                                  concat($pLang,'++',
                                         name(),'++',
                                         Id))"/>
        <xsl:apply-templates select="$vMatch"/>
        <xsl:if test="not($vMatch)">
            <xsl:call-template name="identity"/>
        </xsl:if>
    </xsl:template>
</xsl:stylesheet>

Вывод: 

<Page>
    <Id>Page1</Id>
    <Content>
        <Header>Esta un caballo</Header>
        <Body>Esta body</Body>
        <Nested>
            <NestedItem>
                <Id>N1</Id>
                <Content>This is a nested element</Content>
            </NestedItem>
            <NestedItem>
                <Id>N2</Id>
                <Content>Esta una element nestado</Content>
            </NestedItem>
        </Nested>
    </Content>
</Page>
0 голосов
/ 29 октября 2010

Вот таблица стилей XSLT 2.0 (вы можете работать с Saxon 9 или AltovaXML Tools или XQSharp ) 

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="2.0">

  <xsl:param name="locale" select="'ES'"/>

  <xsl:key name="k1" 
    match="Localizations/Localization[Locale = $locale]//*[Id]" 
    use="Id"/>
  <xsl:key name="k2" 
    match="Localizations/Localization[Locale = $locale]//*[not(Id) and not(*)]" 
    use="local-name()"/>

  <xsl:template match="Page/Content//*[not(Id) and *]">
    <xsl:copy>
      <xsl:apply-templates/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="Page">
    <xsl:copy>
      <xsl:copy-of select="Id"/>
      <xsl:apply-templates select="Content"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="Page//*[Id]">
    <xsl:variable name="loc" select="key('k1', Id)"/>
    <xsl:choose>
      <xsl:when test="$loc">
        <xsl:copy-of select="$loc"/>
      </xsl:when>
      <xsl:otherwise>
        <xsl:copy-of select="."/>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

  <xsl:template match="Page//*[not(Id) and not(*)]">
    <xsl:variable name="loc" select="key('k2', local-name())"/>
    <xsl:choose>
      <xsl:when test="$loc">
        <xsl:copy-of select="$loc"/>
      </xsl:when>
      <xsl:otherwise>
        <xsl:copy>
          <xsl:apply-templates/>
        </xsl:copy>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

</xsl:stylesheet>

Но я не уверен, что ваши требования четко сформулированы и реализованы в этой таблице стилей.

Добро пожаловать на сайт PullRequest, где вы можете задавать вопросы и получать ответы от других членов сообщества.

Нет похожих вопросов

...