Извлечь строку из текстового файла, используя 2 разделителя

Question

Я пытаюсь извлечь строку из текстового файла, используя 2 разделителя. Один начать и один остановить.

Пример:

Hi my name is$John and I'm happy/today

Что мне нужно сделать, так это вызвать функцию, которая возвращает строку между $ и /. Я искал повсюду, но я не могу найти что-то полезное, и я новичок в программировании.

Answer 1

Вы можете сделать это с Pos и Copy:

function ExtractText(const Str: string; const Delim1, Delim2: char): string;
var
  pos1, pos2: integer;
begin
  result := '';
  pos1 := Pos(Delim1, Str);
  pos2 := Pos(Delim2, Str);
  if (pos1 > 0) and (pos2 > pos1) then
    result := Copy(Str, pos1 + 1, pos2 - pos1 - 1);
end;

Answer 2

Вышеуказанные функции не будут работать, если второй текст также появляется перед первым шаблоном ...

Вы должны использовать PosEx() вместо Pos():

Вы можетесделать это с помощью Pos и ​​Copy:

function ExtractText(const Str: string; const Delim1, Delim2: string): string;
var
  pos1, pos2: integer;
begin
  result := '';
  pos1 := Pos(Delim1, Str);
  if pos1 > 0 then begin
    pos2 := PosEx(Delim2, Str, pos1+1);
    if pos2 > 0 then
      result := Copy(Str, pos1 + 1, pos2 - pos1 - 1);
  end;
end;

Answer 3

Я бы сделал это примерно так:

function ExtractDelimitedString(const s: string): string;
var
  p1, p2: Integer;
begin
  p1 := Pos('$', s);
  p2 := Pos('/', s);
  if (p1<>0) and (p2<>0) and (p2>p1) then begin
    Result := Copy(s, p1+1, p2-p1-1);
  end else begin
    Result := '';//delimiters not found, or in the wrong order; raise error perhaps
  end;
end;

Answer 4

Получить их все

function ExtractText(const Str: string; const Delim1, Delim2: string): TStringList;
var
  c,pos1, pos2: integer;
begin
  result:=TStringList.Create;
  c:=1;
  pos1:=1;

  while pos1>0 do
  begin
    pos1 := PosEx(Delim1, Str,c);
    if pos1 > 0 then begin
      pos2 := PosEx(Delim2, Str, pos1+1);
    if pos2 > 0 then
      result.Add(Copy(Str, pos1 + length(delim1), pos2 - (length(delim1) + pos1)));
      c:=pos1+1;
     end;

  end;
end;

Answer 5

Габ, вы можете написать функцию для этого, используя класс TFileStream и функции Copy и Pos.

см. Этот образец:

uses
  Classes,
  SysUtils;

function ExtractString(Const FileName: TFileName;Const IDel,FDel : AnsiString) : AnsiString;
Var
 FileStream : TFileStream;
 i,f        : Integer;
begin
  FileStream:= TFileStream.Create(FileName, fmOpenRead or fmShareDenyWrite); //oopen the file
  try
    try
      SetLength(Result, FileStream.Size); //set the size of the string
      FileStream.Read(Pointer(Result)^, FileStream.Size);//read the content into a string
      i:=Pos(IDel,Result);//search the initial delimiter
      f:=Pos(FDel,Result);//search the final delimiter
      Result:=Copy(Result,i+1,f-i-1); //extract the value between the delimiters
    except
      Result := '';
      raise;
    end;
  finally
    FileStream.Free;
  end;
end;

и используйте его таким образом

ExtractString('your_file_name','$','/');

Answer 6

В более новых Delphi вы можете сделать это следующим образом .. (yay)

program Project40; {$APPTYPE CONSOLE}

uses RegularExpressions;

const
  str = 'Is$John and I''m happy/today';

function GetStr(const aStr: string): string;
begin
  Result := TRegEx.Match(aStr, '\$.*/').Value;
  Result := Copy(Result, 2, Length(Result) - 2);
end;

begin
  Writeln(GetStr(str));
  ReadLn;
end.

Answer 7

Предполагая, что оба разделителя являются отдельными символами согласно вашему сообщению:

function ExtractDelimitedValueFromFile(const aFilename: String;
                                       const aOpenDelim: Char;
                                       const aCloseDelim: Char;
                                       var aValue: String): Boolean;
var
  i: Integer;
  strm: TStringStream;
  delimStart: Integer;
  delimEnd: Integer;
begin
  result      := FALSE;
  aValue      := '';
  delimStart  := -1;
  delimEnd    := -1;

  strm := TStringStream.Create;
  try
    strm.LoadFromFile(aFileName);

    for i := 1 to strm.Size do
    begin
      if (delimStart = -1) and (strm.DataString[i] = aOpenDelim) then
        delimStart := i
      else if (delimStart <> -1) and (strm.DataString[i] = aCloseDelim) then
        delimEnd := i;

      result := (delimStart <> -1) and (delimEnd <> -1);
      if result then
      begin
        aValue := Copy(strm.DataString, delimStart + 1, delimEnd - delimStart - 1);
        BREAK;
      end;
    end;

  finally
    strm.Free;
  end;
end;

Использование:

  var
    str: String;
  begin
    if ExtractDelimitedValueFromFile('path\filename.ext', '$', '/', str) then
      // work with str
    else
      // delimited value not found in file
  end;