Запрос SQL для возврата всех строк, в которых одно или несколько полей содержат определенное значение

Question

Можно ли выполнить выборку для таблицы, чтобы быстро выяснить, содержит ли любое (одно или несколько) полей определенное значение?

Или вам нужно выписать все имена столбцов в предложении where?

Answer 1

Как уже говорили другие, вам, вероятно, придется написать все столбцы в предложении WHERE, либо вручную, либо программно. SQL не включает в себя функциональность, чтобы сделать это напрямую. Лучший вопрос может быть: «Зачем вам это нужно?». Необходимость использовать этот тип запроса, возможно, является хорошим показателем того, что ваша база данных неправильно нормализована . Если вы сообщите нам свою схему, мы также сможем помочь с этой проблемой (если это действительно проблема).

Answer 2

Копайте это ... Он будет искать по всем таблицам в БД, но вы можете изменить его до одной таблицы.

/*This script will find any text value in the database*/
/*Output will be directed to the Messages window. Don't forget to look there!!!*/

SET NOCOUNT ON
DECLARE @valuetosearchfor varchar(128), @objectOwner varchar(64)
SET @valuetosearchfor = '%staff%' --should be formatted as a like search 
SET @objectOwner = 'dbo'

DECLARE @potentialcolumns TABLE (id int IDENTITY, sql varchar(4000))

INSERT INTO @potentialcolumns (sql)
SELECT 
    ('if exists (select 1 from [' +
    [tabs].[table_schema] + '].[' +
    [tabs].[table_name] + 
    '] (NOLOCK) where [' + 
    [cols].[column_name] + 
    '] like ''' + @valuetosearchfor + ''' ) print ''SELECT * FROM [' +
    [tabs].[table_schema] + '].[' +
    [tabs].[table_name] + 
    '] (NOLOCK) WHERE [' + 
    [cols].[column_name] + 
    '] LIKE ''''' + @valuetosearchfor + '''''' +
    '''') as 'sql'
FROM information_schema.columns cols
    INNER JOIN information_schema.tables tabs
        ON cols.TABLE_CATALOG = tabs.TABLE_CATALOG
            AND cols.TABLE_SCHEMA = tabs.TABLE_SCHEMA
            AND cols.TABLE_NAME = tabs.TABLE_NAME
WHERE cols.data_type IN ('char', 'varchar', 'nvchar', 'nvarchar','text','ntext')
    AND tabs.table_schema = @objectOwner
    AND tabs.TABLE_TYPE = 'BASE TABLE'
ORDER BY tabs.table_catalog, tabs.table_name, cols.ordinal_position

DECLARE @count int
SET @count = (SELECT MAX(id) FROM @potentialcolumns)
PRINT 'Found ' + CAST(@count as varchar) + ' potential columns.'
PRINT 'Beginning scan...'
PRINT ''
PRINT 'These columns contain the values being searched for...'
PRINT ''
DECLARE @iterator int, @sql varchar(4000)
SET @iterator = 1
WHILE @iterator <= (SELECT Max(id) FROM @potentialcolumns)
BEGIN
    SET @sql = (SELECT [sql] FROM @potentialcolumns where [id] = @iterator)
    IF (@sql IS NOT NULL) and (RTRIM(LTRIM(@sql)) <> '')
    BEGIN
        --SELECT @sql --use when checking sql output
        EXEC (@sql)
    END
    SET @iterator = @iterator + 1
END

PRINT ''
PRINT 'Scan completed'

Answer 3

вам придется выписать это

Answer 4

Конечно, вы должны выписать все столбцы, которые хотите использовать в качестве критерия.

Если вы добавите, какой язык программирования вы используете и в какой среде вы работаете, мы можем дать вам подсказку или решить, как это сделать динамически.

Я думаю, что ваш вопрос действительно заключался в том, как сделать это динамически, в зависимости от того, что пользователь вашей программы заполняет в форме "search". Я прав?

Если нет, тогда .. Дайте нам больше информации. ;)

Answer 5

Я думаю, вам нужно перечислить все столбцы в предложении where. Хотя я далеко не волшебник SQL ... может, кто-то еще знает способ.