Как добавить изображение в определенном месте в Flex / Spark TextArea или TextFlow - PullRequest
Новая
       17

Как добавить изображение в определенном месте в Flex / Spark TextArea или TextFlow

5 голосов
/ 24 августа 2010

У меня есть Spark TextArea: 

<s:TextArea id="editor">
    <s:textFlow>
        <s:TextFlow id="_tf" >
            <s:p>Lorem ipsum etc.</s:p>
            <s:p>
                 <s:img source="http://example.com/example.jpg" />
             </s:p>
            <s:p>Aliquam tincidunt tempor etc.</s:p>
        </s:TextFlow>
    </s:textFlow>
</s:TextArea>

И кнопка для добавления изображения: 

<s:Button id="imageBtn" 
    label="insert image" 
    width="89"
    click="imageBtn_clickHandler(event);" />

Работает следующий скрипт: 

    import flashx.textLayout.elements.*;

    import mx.events.FlexEvent;

    protected function imageBtn_clickHandler(evt:MouseEvent):void {
        var img:InlineGraphicElement = new InlineGraphicElement();
        img.source = "http://example.com/example.jpg";

        var p:ParagraphElement = new ParagraphElement();
        p.addChild(img);
        _tf.addChild(p);
        _tf.flowComposer.updateAllControllers();
        editor.setFocus();
    }

, но добавляется только в конец TextFlow. Как я могу вставить InlineGraphicElement в активную каретку в TextArea? Моя первая мысль что-то вроде: 

    import flashx.textLayout.elements.*;

    import mx.events.FlexEvent;

    protected function imageBtn_clickHandler(evt:MouseEvent):void {
        var img:InlineGraphicElement = new InlineGraphicElement();
        img.source = "http://example.com/example.jpg";

        var p:ParagraphElement;
    //pseudocode
    p = _tf.getCaret.AncestorThatIsParagraphElement;
    // end pseudocode
    p.addChild(img);
        _tf.flowComposer.updateAllControllers();
        editor.setFocus();
    }

Но это все равно будет добавлено только в конце текущего абзаца, при условии, что я даже смогу найти текущий абзац как объект для .addChild () с. Итак, как я могу вставить InlineGraphicElement в середине текста (или даже заменить текст) в дочернем абзаце объекта TextFlow.

Спасибо за понимание.

ОБНОВЛЕНИЕ: ближе.

Я могу добавить в начало или конец абзаца. 

protected function imageBtn_clickHandler(evt:MouseEvent):void {
    var img:InlineGraphicElement = new InlineGraphicElement();
    img.source = "http://example.com/example.jpg";
    var insertInto:ParagraphElement = new ParagraphElement();
    insertInto = editor.textFlow.getChildAt(
        editor.textFlow.findChildIndexAtPosition(
            editor.selectionAnchorPosition
        )).getParagraph();
    insertInto.addChildAt(0, img); // inserts at beginning of paragraph
    insertInto.addChildAt(1, img); // inserts at end of paragraph

    _tf.flowComposer.updateAllControllers();
    editor.setFocus();
}

Но по-прежнему нет радости от вставки в середину. Кроме того, приведенный выше код не заменит выделенный текст, но здесь это не имеет значения.

РЕШЕНИЕ:

Основываясь на ссылке Юджина, ключом к этому является EditManager.

Следующий код представляет рабочую обновленную функцию: 

protected function imageBtn_clickHandler(evt:MouseEvent):void {
    var em:EditManager = editor.textFlow.interactionManager as EditManager;
    em.selectRange(editor.selectionAnchorPosition, editor.selectionActivePosition);
    em.insertInlineGraphic("http://example.com/example.jpg","auto","auto");
    _tf.flowComposer.updateAllControllers();
    editor.setFocus();
}

1 Ответ

0 голосов
/ 04 июня 2015

Используйте этот код, чтобы получить решение.

здесь изображение из вашей системной папки 

        protected function addImg_clickHandler(event:MouseEvent):void {
            _file_ref = new FileReference();
            _file_ref.addEventListener( Event.SELECT, handleFileSelect,false,0,true );
            var filter:FileFilter = new FileFilter("Images", "*.jpg;*.gif;*.png");
            _file_ref.browse([filter]);
        }

        private function handleFileSelect(e:Event):void {
            _file_ref.removeEventListener( Event.SELECT, handleFileSelect );
            _file_ref.addEventListener(Event.COMPLETE, handleFileOpen,false,0,true );
            _file_ref.load();
        }

        private function handleFileOpen(e:Event):void {
            _file_ref.removeEventListener(Event.COMPLETE, handleFileOpen );
            var data:ByteArray = _file_ref.data as ByteArray;
            _img_loader= new Loader();
            _img_loader.loadBytes(data);
            _img_loader.contentLoaderInfo.addEventListener(Event.COMPLETE,imageLoadComplete,false,0,true);
        }

        protected function imageLoadComplete(e:Event):void{
            _img_loader.contentLoaderInfo.removeEventListener(Event.COMPLETE,imageLoadComplete);
            var bmd:BitmapData=Bitmap(_img_loader.content).bitmapData;
            var bm:Bitmap=new Bitmap(bmd);  
            var em:EditManager = editorText.textFlow.interactionManager as EditManager;
            em.selectRange(editorText.selectionAnchorPosition, editorText.selectionActivePosition);
            em.insertInlineGraphic(bm,bm.width,bm.height);
            editorText.textFlow.flowComposer.updateAllControllers();
            editorText.setFocus();
        } 


        protected function addTable_clickHandler(event:MouseEvent):void
        {
            var tblement:TableElement = new TableElement();
            var em:EditManager = editorText.textFlow.interactionManager as EditManager;
            em.selectRange(editorText.selectionAnchorPosition, editorText.selectionActivePosition);
            em.insertTableElement(tblement);
            editorText.textFlow.flowComposer.updateAllControllers();
            editorText.setFocus();
        }
...