Группировка узлов сравнения - PullRequest
Новая
       2

Группировка узлов сравнения

1 голос
/ 04 октября 2010

У меня возникла следующая проблема при группировке узлов сравнения с xsl:

ввод: 

<?xml version="1.0" encoding="UTF-8"?>
<concept id="ads">
    <p>para1 content goes here</p>
    <Bullet>1</Bullet>
    <Bullet>2</Bullet>
    <Bullet>3</Bullet>
    <p>para2 content goes here</p>
    <Bullet>4</Bullet>
    <Bullet>5</Bullet>
    <p>para2 content goes here</p>
</concept>

Вывод должен быть: 

<?xml version="1.0" encoding="UTF-8"?>
<concept id="ads">
    <p>para1 content goes here</p>
    <ul>
    <li>1</li>
    <li>2</li>
    <li>3</li>
    </ul>
    <p>para2 content goes here</p>
    <ul>
    <li>4</li>
    <li>5</li>
    </ul>
    <p>para2 content goes here</p>
</concept>

Все элементы «Bullet», которые не имеют предшествующего имитата, как «Bullet», должны быть заключены в элементы «UL» и «Li».

Я пытаюсь что-то вроде этого, но не могу достичь результата: 

<xsl:for-each select="Bullet[not(preceding-sibling::Bullet)]">
<ul>
<xsl:copy-of select="."/>
<xsl:variable name="current-name" select="generate-id(.)"/>
<xsl:for-each select="following-sibling::*[Bullet][generate-id(preceding-sibling::*[Bullet]) = $current-name]">
<xsl:copy-of select="."/>
</xsl:for-each>
</ul>
</xsl:for-each>

Пожалуйста, помогите.

--- Схожий вопрос ----

Это нормально работает при заданном вводе xml, но 1. В моем реальном xml эти теги <Bullet> могут появляться где угодно под узлом понятия, поэтому группировка с элементом <p> в этом случае не работает.

  1. В настоящее время я обрабатываю все узлы, кроме узлов «Bullet», поэтому мне нужно сопоставить только <Bullet> узлы, которые имеют ближайшего брата как <Bullet>, и обернуть последовательность в <ul> и каждый <Bullet> в <li>. Мой текущий контекстный узел - <concept>.

  2. Текущая таблица стилей выглядит следующим образом:

    узлы, которые должны отображаться в том же месте, что и на входе .-->

Фактический шаблон XML: 

<?xml version="1.0" encoding="UTF-8"?> 
<concept id="ads"> 
    <p>para1 content goes here</p> 
    <Body-text>Body1 content goes here</Body-text>
    <Bullet>1</Bullet> 
    <Bullet>2</Bullet> 
    <Bullet>3</Bullet> 
    <Body-text>Body2 content goes here</Body-text>
    <p>para2 content goes here</p> 
    <Bullet>4</Bullet> 
    <Bullet>5</Bullet> 
    <p>para3 content goes here</p>
    <Bullet>6</Bullet> 
    <Bullet>7</Bullet> 
    <Body-text>Body2 content goes here</Body-text>
    <Bullet>6</Bullet> 
    <Bullet>7</Bullet> 
</concept>
<concept id="ads"> 
    <p>para1 content goes here</p> 
    <Body-text>Body1 content goes here</Body-text>
    <Bullet>1</Bullet> 
    <Bullet>2</Bullet> 
    <Bullet>3</Bullet> 
    <Body-text>Body2 content goes here</Body-text>
    <p>para2 content goes here</p> 
    <Bullet>4</Bullet> 
    <Bullet>5</Bullet> 
    <p>para3 content goes here</p>
    <Bullet>6</Bullet> 
    <Bullet>7</Bullet> 
    <Body-text>Body2 content goes here</Body-text>
    <Bullet>6</Bullet> 
    <Bullet>7</Bullet> 
</concept>

Ответы [ 2 ]

1 голос
/ 04 октября 2010

Эта таблица стилей: 

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="node()[1]|@*"/>
        </xsl:copy>
        <xsl:apply-templates select="following-sibling::node()[1]"/>
    </xsl:template>
    <xsl:template match="Bullet[preceding-sibling::node()[1]
                               [not(self::Bullet)]]">
        <ul>
            <xsl:call-template name="makeLi"/>
        </ul>
        <xsl:apply-templates select="following-sibling::node()
                                                     [not(self::Bullet)][1]"/>
    </xsl:template>
    <xsl:template match="Bullet" name="makeLi">
        <li>
            <xsl:value-of select="."/>
        </li>
        <xsl:apply-templates select="following-sibling::node()[1]
                                                              [self::Bullet]"/>
    </xsl:template>
</xsl:stylesheet>

РЕДАКТИРОВАТЬ : Просто измените следующее применяя правило "первый Bullet" к первому следующему не Bullet вместо p.

Вывод (завершение ввода с корневым элементом для правильного отображения): 

<concept id="ads">
    <p>para1 content goes here</p>
    <Body-text>Body1 content goes here</Body-text>
    <ul>
        <li>1</li>
        <li>2</li>
        <li>3</li>
    </ul>
    <Body-text>Body2 content goes here</Body-text>
    <p>para2 content goes here</p>
    <ul>
        <li>4</li>
        <li>5</li>
    </ul>
    <p>para3 content goes here</p>
    <ul>
        <li>6</li>
        <li>7</li>
    </ul>
    <Body-text>Body2 content goes here</Body-text>
    <ul>
        <li>6</li>
        <li>7</li>
    </ul>
</concept>
<concept id="ads">
    <p>para1 content goes here</p>
    <Body-text>Body1 content goes here</Body-text>
    <ul>
        <li>1</li>
        <li>2</li>
        <li>3</li>
    </ul>
    <Body-text>Body2 content goes here</Body-text>
    <p>para2 content goes here</p>
    <ul>
        <li>4</li>
        <li>5</li>
    </ul>
    <p>para3 content goes here</p>
    <ul>
        <li>6</li>
        <li>7</li>
    </ul>
    <Body-text>Body2 content goes here</Body-text>
    <ul>
        <li>6</li>
        <li>7</li>
    </ul>
</concept>

Примечание : Мелкозернистый обход.

При группировании эта таблица стилей: 

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="concept">
        <xsl:copy>
            <xsl:copy-of select="@*"/>
            <xsl:for-each-group select="*" 
                                group-adjacent="boolean(self::Bullet)">
                <xsl:choose>
                    <xsl:when test="current-grouping-key()">
                        <ul>
                            <xsl:apply-templates select="current-group()"/>
                        </ul>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:apply-templates select="current-group()"/>
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:for-each-group>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="Bullet">
        <li>
            <xsl:value-of select="."/>
        </li>
    </xsl:template>
    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

РЕДАКТИРОВАТЬ : Ussing group-adjacent.

0 голосов
/ 04 октября 2010

Это преобразование XSLT 2.0 : 

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

    <xsl:template match="/*">
      <xsl:copy>
       <xsl:copy-of select="@*"/>
        <xsl:for-each-group select="*" group-starting-with="p">
          <xsl:copy-of select="current-group()[1]"/>
           <xsl:if test="current-group()[2]">
               <ul>
                <xsl:apply-templates select="current-group()[position() gt 1]"/>
              </ul>
          </xsl:if>
        </xsl:for-each-group>
      </xsl:copy>
    </xsl:template>

    <xsl:template match="Bullet">
      <li><xsl:value-of select="."/></li>
    </xsl:template>
</xsl:stylesheet>

при применении к предоставленному документу XML : 

<concept id="ads">
    <p>para1 content goes here</p>
    <Bullet>1</Bullet>
    <Bullet>2</Bullet>
    <Bullet>3</Bullet>
    <p>para2 content goes here</p>
    <Bullet>4</Bullet>
    <Bullet>5</Bullet>
    <p>para2 content goes here</p>
</concept>

дает желаемый, правильный результат : 

<concept id="ads">
   <p>para1 content goes here</p>
   <ul>
      <li>1</li>
      <li>2</li>
      <li>3</li>
   </ul>
   <p>para2 content goes here</p>
   <ul>
      <li>4</li>
      <li>5</li>
   </ul>
   <p>para2 content goes here</p>
</concept>

Do note : использование <xsl:for-each-group> с атрибутом group-starting-with и функцией current-group().

...