Скрипт пинга с электронной почтой в vbs - PullRequest
Новая
       9

Скрипт пинга с электронной почтой в vbs

0 голосов
/ 16 июня 2010

я знаю, что уже задавал вопрос о сценарии пинга, но теперь у меня есть новый вопрос об этом :-) Я надеюсь, что кто-то может помочь мне снова. 

strText = "here comes the mail message"

strFile = "test.log"

PingForever strHost, strFile

Sub PingForever(strHost, outputfile)
    Dim Output, Shell, strCommand, ReturnCode

    Set Output = CreateObject("Scripting.FileSystemObject").OpenTextFile(outputfile, 8, True)
    Set Shell = CreateObject("wscript.shell")
    strCommand = "ping -n 1 -w 300 " & strHost
    While(True)
        ReturnCode = Shell.Run(strCommand, 0, True)     
        If ReturnCode = 0 Then
            Output.WriteLine Date() & " - " & Time & " | " & strHost & " - ONLINE"
        Else
            Output.WriteLine Date() & " - " & Time & " | " & strHost & " - OFFLINE"

            Set objEmail = CreateObject("CDO.Message")
            objEmail.From = "noreply@test.net"
            objEmail.To = "test@test.net"
            objEmail.Subject = "Computer" & strHost & " is offline" 
            objEmail.Textbody = strText
            objEmail.Configuration.Fields.Item _
                ("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
            objEmail.Configuration.Fields.Item _
                ("http://schemas.microsoft.com/cdo/configuration/smtpserver") = _
                    "smtpadress" 
            objEmail.Configuration.Fields.Item _
                ("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
            objEmail.Configuration.Fields.Update
            objEmail.Send

        End If
        Wscript.Sleep 2000
    Wend
End Sub

Моя проблема сейчас, почта приходит все 2 секунды, когда компьютер не подключен. Может кто-нибудь показать мне, как сделать это с флагами? Таким образом, только одно письмо приходит в автономном режиме?

Спасибо за вашу помощь.

1 Ответ

1 голос
/ 16 июня 2010

Использовать флаг и сообщать только при изменении состояния 

FLAG0 = "ON"
While(True)
    ReturnCode = Shell.Run(strCommand, 0, True)     
    If ReturnCode = 0 Then
        Output.WriteLine Date() & " - " & Time & " | " & strHost & " - ONLINE"
        FLAG0 = "ON"
    Else
        Output.WriteLine Date() & " - " & Time & " | " & strHost & " - OFFLINE"
        IF FLAG0 = "ON" THEN
           FLAG0 = "OFF"
           Set objEmail = CreateObject("CDO.Message")
           ...... rest of mailing code
        END IF

    End If
...