Десериализовать комплекс JSON (VB.NET) - PullRequest
Новая
       6

Десериализовать комплекс JSON (VB.NET)

1 голос
/ 10 февраля 2011

Я пытаюсь десериализовать json, возвращаемый API некоторых направлений, похожий на API Карт Google. Мой JSON выглядит следующим образом (я использую VB.NET 2008):

jsontext = { «Версия»: 0,3, "Статус": 0, "Route_summary": { "Total_distance": 300, "Total_time": 14, "Start_point": "43", "End_point": "42" }, "Route_geometry": [[51.025421,18.647631], [51.026131,18.6471], [51.027802,18.645639]], "route_instructions": [["Направляйся на северо-запад 43", 88,0,4, "88 м", "СЗ", 334,8], ["Продолжай 42", 212,1,10, "0,2 км", " СЗ», 331,1, "С", 356,3]] }

До сих пор я придумал следующий код: 

Dim js As New System.Web.Script.Serialization.JavaScriptSerializer
Dim lstTextAreas As Output_CloudMade() = js.Deserialize(Of Output_CloudMade())(jsontext)

Я не уверен, как определить сложный класс, т.е. Output_CloudMade.

Я пытаюсь что-то вроде: 

Public Class RouteSummary
    Private mTotalDist As Long
    Private mTotalTime As Long
    Private mStartPoint As String
    Private mEndPoint As String


    Public Property TotalDist() As Long
        Get
            Return mTotalDist
        End Get
        Set(ByVal value As Long)
            mTotalDist = value
        End Set
    End Property

    Public Property TotalTime() As Long
        Get
            Return mTotalTime
        End Get
        Set(ByVal value As Long)
            mTotalTime = value
        End Set
    End Property

    Public Property StartPoint() As String
        Get
            Return mStartPoint
        End Get
        Set(ByVal value As String)
            mStartPoint = value
        End Set
    End Property

    Public Property EndPoint() As String
        Get
            Return mEndPoint
        End Get
        Set(ByVal value As String)
            mEndPoint = value
        End Set
    End Property

End Class

Public Class Output_CloudMade

    Private mVersion As Double
    Private mStatus As Long
    Private mRSummary As RouteSummary
    'Private mRGeometry As RouteGeometry
    'Private mRInstructions As RouteInstructions

    Public Property Version() As Double
        Get
            Return mVersion
        End Get
        Set(ByVal value As Double)
            mVersion = value
        End Set
    End Property

    Public Property Status() As Long
        Get
            Return mStatus
        End Get
        Set(ByVal value As Long)
            mStatus = value
        End Set
    End Property

    Public Property Summary() As RouteSummary
        Get
            Return mRSummary
        End Get
        Set(ByVal value As RouteSummary)
            mRSummary = value
        End Set
    End Property


    'Public Property Geometry() As String
    '    Get

    '    End Get
    '    Set(ByVal value As String)

    '    End Set
    'End Property

    'Public Property Instructions() As String
    '    Get

    '    End Get
    '    Set(ByVal value As String)

    '    End Set
    'End Property

End Class

но это не работает. Проблема со сложными свойствами, такими как route_summary. Это заполнено "ничем". Другие свойства, такие как «статус» или «версия», заполнены правильно.

Есть идеи, как определить класс для вышеупомянутого JSON?

Можете ли вы поделиться рабочим кодом для десериализации JSON в VB.NET?

Спасибо

1 Ответ

2 голосов
/ 10 февраля 2011

Ниже приведен пример класса Converter, который будет принимать входящий поток JSON и преобразовывать его в указанный вами объект. Я должен отметить, что приведенный ниже код .Net 4.0. Сериализатор JSON в 4 намного проще в использовании. Дайте мне знать, если вы не можете использовать 4, и я посмотрю, смогу ли я найти версию 3.5. По сути, вам нужно создать структуру класса, чтобы сопоставить JSON с классом. Я создал для вас классы Route и RouteSummary. Я оставил route_geometry и route_instructions как объекты. Вы должны создать определения классов для каждого, но это должно помочь вам начать. 

Imports System.IO
Imports System.Runtime.Serialization.Json
Imports System.Runtime.Serialization

<DataContract(Namespace:="")> _
Public Class Route

    <DataMember(Name:="version")>
    Public Property version As Double

    <DataMember(Name:="status")>
    Public Property status As Double

    <DataMember(Name:="route_summary")>
    Public Property route_summary As route_summary

    <DataMember(Name:="route_geometry")>
    Public Property route_geometry As Object()

    <DataMember(Name:="route_instructions")>
    Public Property route_instructions() As Object

End Class

<DataContract(Name:="route_summary", Namespace:="")> _
Public Class route_summary
    <DataMember(Name:="total_distance")>
    Public Property total_distance As Double

    <DataMember(Name:="total_time")>
    Public Property total_time As Double

    <DataMember(Name:="start_point")>
    Public Property start_point As Double

    <DataMember(Name:="end_point")>
    Public Property end_point As Double
End Class

Public Class Converter(Of t)
    Public Function ReturnJSON(ByRef sreader As StreamReader) As t
        If GetType(t).Equals(GetType(String)) Then
            Dim result As Object = sreader.ReadToEnd.Replace("""", "")
            Return result
        Else
            Dim ds As New DataContractJsonSerializer(GetType(t))
            Dim result As t = DirectCast(ds.ReadObject(sreader.BaseStream), t)
            ds = Nothing
            Return result
        End If
    End Function
End Class

    Sub Main()
        Dim json As String = "{""version"":0.3, ""status"":0, ""route_summary"": { ""total_distance"":300, ""total_time"":14, ""start_point"":""43"", ""end_point"":""42"" }, ""route_geometry"":[[51.025421,18.647631],[51.026131,18.6471],[51.027802,18.645639]], ""route_instructions"": [[""Head northwest on 43"",88,0,4,""88 m"",""NW"",334.8],[""Continue on 42"",212,1,10,""0.2 km"",""NW"",331.1,""C"",356.3]]}"

        Dim encoding As New System.Text.UTF8Encoding
        Dim bytes() As Byte = encoding.GetBytes(json)

        Using os As New MemoryStream
            os.Write(bytes, 0, bytes.Length)
            os.Position = 0

            Using reader As New StreamReader(os)
                Dim converter As New Converter(Of Route)
                Dim output As Route

                output = converter.ReturnJSON(reader)

                'output contains data
            End Using
        End Using
    End Sub

См. Эту страницу для подробного описания того, как читать данные JSON. http://www.json.org/

...