ANTLR 4
Для предикатов в ANTLR 4, проверьте эти стек переполнение Вопросы и ответы:
ANTLR 3
A семантический предикат - это способ применения дополнительных (семантических) правил к грамматическим действиям с использованием простого кода.
Существует 3 типа семантических предикатов:
- проверка семантических предикатов;
- gated семантических предикатов;
- устранение неоднозначности семантические предикаты.
Пример грамматики
Допустим, у вас есть блок текста, состоящий только из чисел, разделенных запятыми, игнорируя любые пробелы.Вы хотели бы проанализировать этот ввод, убедившись, что числа имеют длину не более 3 цифр (не более 999).Следующая грамматика (Numbers.g) будет делать такие вещи:
grammar Numbers;
// entry point of this parser: it parses an input string consisting of at least
// one number, optionally followed by zero or more comma's and numbers
parse
: number (',' number)* EOF
;
// matches a number that is between 1 and 3 digits long
number
: Digit Digit Digit
| Digit Digit
| Digit
;
// matches a single digit
Digit
: '0'..'9'
;
// ignore spaces
WhiteSpace
: (' ' | '\t' | '\r' | '\n') {skip();}
;
Тестирование
Грамматику можно проверить с помощью следующего класса:
import org.antlr.runtime.*;
public class Main {
public static void main(String[] args) throws Exception {
ANTLRStringStream in = new ANTLRStringStream("123, 456, 7 , 89");
NumbersLexer lexer = new NumbersLexer(in);
CommonTokenStream tokens = new CommonTokenStream(lexer);
NumbersParser parser = new NumbersParser(tokens);
parser.parse();
}
}
Протестируйте его, сгенерировав лексер и парсер, скомпилировав все файлы .java и запустив класс Main:
java -cp antlr-3.2.jar org.antlr.Tool Numbers.g
javac -cp antlr-3.2.jar *.java
java -cp .:antlr-3.2.jar Main
При этом на консоль ничего не выводится, что указывает на то, что ничего не произошлонеправильно.Попробуйте изменить:
ANTLRStringStream in = new ANTLRStringStream("123, 456, 7 , 89");
на:
ANTLRStringStream in = new ANTLRStringStream("123, 456, 7777 , 89");
и повторите тест: вы увидите ошибку, появляющуюся на консоли сразу после строки 777.
Семантические предикаты
Это подводит нас к семантическим предикатам.Допустим, вы хотите проанализировать числа длиной от 1 до 10 цифр.Правило типа:
number
: Digit Digit Digit Digit Digit Digit Digit Digit Digit Digit
| Digit Digit Digit Digit Digit Digit Digit Digit Digit
/* ... */
| Digit Digit Digit
| Digit Digit
| Digit
;
станет громоздким.Семантические предикаты могут помочь упростить этот тип правил.
1.Проверка семантических предикатов
A Проверка семантического предиката - это не что иное, как блок кода, за которым следует знак вопроса:
RULE { /* a boolean expression in here */ }?
Для решения вышеуказанной проблемы с помощью проверка семантический предикат, измените правило number в грамматике на:
number
@init { int N = 0; }
: (Digit { N++; } )+ { N <= 10 }?
;
Части { int N = 0; } и { N++; } являются простыми операторами Java, для которыхпервый инициализируется, когда анализатор «входит» в правило number.Фактический предикат: { N <= 10 }?, который заставляет синтаксический анализатор выдавать FailedPredicateException всякий раз, когда число длиннее 10 цифр.
Проверьте его с помощью следующего ANTLRStringStream:
// all equal or less than 10 digits
ANTLRStringStream in = new ANTLRStringStream("1,23,1234567890");
, который не создает исключений, в то время как следующее делает исключение:
// '12345678901' is more than 10 digits
ANTLRStringStream in = new ANTLRStringStream("1,23,12345678901");
2.Стробированные семантические предикаты
A стробированный семантический предикат аналогичен проверяющему семантическому предикату , только версия gated создает синтаксическую ошибку вместоFailedPredicateException.
Синтаксис стробированного семантического предиката :
{ /* a boolean expression in here */ }?=> RULE
Чтобы вместо этого решить вышеуказанную проблему, используя gated предикаты для совпадения чисел длиной до 10 цифр, которые вы написали бы:
number
@init { int N = 1; }
: ( { N <= 10 }?=> Digit { N++; } )+
;
Проверьте его снова с помощью:
// all equal or less than 10 digits
ANTLRStringStream in = new ANTLRStringStream("1,23,1234567890");
и:
// '12345678901' is more than 10 digits
ANTLRStringStream in = new ANTLRStringStream("1,23,12345678901");
, и вы увидите, что последнее включение выдаст ошибку.
3.Устранение неоднозначности семантических предикатов
Последним типом предиката является неоднозначность семантического предиката , который немного похож на валидирующий предикат ({boolean-expression}?), но действует больше как стробированный семантический предикат (нетисключение выдается, когда логическое выражение оценивается как false).Вы можете использовать его в начале правила, чтобы проверить какое-либо свойство правила и позволить парсеру соответствовать указанному правилу.
Допустим, примерная грамматика создает токены Number (правило лексера вместо правила синтаксического анализатора), которые будут соответствовать числам в диапазоне 0..999. Теперь в синтаксическом анализаторе вы хотели бы провести различие между низкими и высокими числами (низкий: 0,500, высокий: 501 ... 999). Это можно сделать с помощью однозначного семантического предиката , где вы проверяете токен, следующий в потоке (input.LT(1)), чтобы проверить, является ли он низким или высоким.
Демонстрация:
grammar Numbers;
parse
: atom (',' atom)* EOF
;
atom
: low {System.out.println("low = " + $low.text);}
| high {System.out.println("high = " + $high.text);}
;
low
: {Integer.valueOf(input.LT(1).getText()) <= 500}? Number
;
high
: Number
;
Number
: Digit Digit Digit
| Digit Digit
| Digit
;
fragment Digit
: '0'..'9'
;
WhiteSpace
: (' ' | '\t' | '\r' | '\n') {skip();}
;
Если вы сейчас проанализируете строку "123, 999, 456, 700, 89, 0", вы увидите следующий вывод:
low = 123
high = 999
low = 456
high = 700
low = 89
low = 0