Как я могу получить список свойств объекта в Actionscript?

Question

У меня есть поставщик данных и функция фильтра для моего массива, назначенная моему поставщику данных.

Как получить список свойств, которые есть в каждой строке провайдера данных (item.data) при его передаче в функцию фильтра?

Например, если мой объект содержал:

• Объект
  • имя
  • Адрес электронной почты
  • адрес

Тогда я бы хотел, чтобы в моей функции фильтра можно было просматривать имя, адрес электронной почты и адрес. К сожалению, я не знаю, что эти свойства будут иметь под рукой.

Есть идеи?

Answer 1

Если это динамический объект, я думаю, вы можете просто сделать что-то вроде этого:

var obj:Object; // I'm assuming this is your object

for(var id:String in obj) {
  var value:Object = obj[id];

  trace(id + " = " + value);
}

Вот как это делается в AS2, и я считаю, что это все еще работает для динамических объектов в AS3. Я думаю, что свойства, которые он покажет, более ограничены для нединамических объектов.

Answer 2

flash.utils.describeType(value:*) также предоставит вам список свойств объекта.

Answer 3

Вы, наверное, ищете

ObjectUtil.getClassInfo(object) 

, см:

http://livedocs.adobe.com/flex/3/langref/mx/utils/ObjectUtil.html#getClassInfo%28%29

Имейте в виду, что в нем есть ошибка, из-за которой он обрабатывает XML как нединамический тип данных. Подробнее об ошибке в: bugs.adobe.com/jira/browse/SDK-17712

Answer 4

for-in работает только для динамических объектов. Для типизированных объектов вам нужно использовать какое-то отражение для получения имен свойств (например, http://www.as3commons.org/as3-commons-reflect/index.html)

/ Андрей.

Answer 5

для меня было полезно только это:

trace('obj = '+getProperties(obj));

        public static function getProperties(obj:*):String  {
            var p:*;
            var res:String = '';
            var val:String;
            var prop:String;
            for (p in obj) {
                prop = String(p);
                if (prop && prop!=='' && prop!==' ') {
                    val = String(obj[p]);
                    if (val.length>10) val = val.substr(0,10)+'...';
                    res += prop+':'+val+', ';
                }
            }
            res = res.substr(0, res.length-2);
            return res;
        }

и вы получите что-то вроде этого:

obj = m:email@ra..., r:true

Answer 6

// this method will work for retrieving properties of a *non-dynamic* (typed) object

// @return - all object properties
public function getProperties(_obj : *) : Array
{
        var _description : XML = describeType(_obj);
        var _properties : Array = new Array();
        for each (var prop:XML in _description.accessor)
        {
                var _property : Object = new Object();
                _property.name = String(prop.@name);
                _property.type = String(simple_type(prop.@type));
                _property.access = String(prop.@access);
                _property.declaredBy = String(prop.@declaredBy);
                try
                {
                   _property.value = _obj[_property.name];
                }
                catch (e : Error)
                {
                   _property.value = "";
                }
                _properties.push(_property)
        }
        _properties.sortOn("name");
        return _properties;
}

// better format for object class information
private function simple_type(_type : String) : String
{
        var lastIndex : int = _type.lastIndexOf("::");
        _type = lastIndex > 0 ? _type.substr(lastIndex + 2) : _type;
        return _type;
}

Answer 7

Это также поможет вам ..
1. для цикла - будет работать на основе индекса
2. для каждого - рекурсивный вызов до длины
3. for in - используется для чтения значений свойств

     for( var obj : String in objectData ) //here objectData is your object
     {
        trace( "Object Name Is : " + obj );
        var data : Object = objectData[obj]; //here we get the object value by using the property name
        trace( "Value Is : " + data ); //Converts object to string
     }

Answer 8

Вы можете использовать цикл for .. in для получения имен свойств или a для каждого .. in цикла, чтобы получать значения свойств ...

for( var o : * in object){
    trace( o + " = " + object[o] );
}
/************* OR ******************/
for each( var o : * in object ){
    trace( "object has property: " + o );
}