Выполните действие для каждого ожидаемого матча - PullRequest
Новая
       4

Выполните действие для каждого ожидаемого матча

0 голосов
/ 21 сентября 2010

Я полный ожидающий новичок.

Я пишу сценарий ожидания для тестового случая, в котором я хочу подсчитать количество вхождений строки «Ok» и выполнить действие для каждого вхождения изследующий вывод: 

Reloading configuration on all nodes
Reloading configuration on node 1 (node1-c5)
OK
Reloading configuration on node 2 (node2-c5)
OK
Reloading configuration on node 3 (node3-c5)
OK
Reloading configuration on node 4 (node4-c5)
OK

Как бы выглядел мой ожидаемый блок?

Ответы [ 2 ]

3 голосов
/ 21 сентября 2010

Я бы переписал ваш код, чтобы удалить цикл while: 

set number_ok 0
set node_patt "(Reloading configuration on node (\\d+?) \\((\[^)]+?)\\))\r\n(.+?)\r\n"

send "cluster config -r -a\r"
expect {
    ERROR {cluster_exit 1}
    -re $node_patt {
        set line "<$cmdline> $expect_out(1,string)"
        set node_num  $expect_out(2,string)
        set node_name $expect_out(3,string)
        set result    $expect_out(4,string)

        switch -regexp $result {
            "Node .+ not found" {
                ok 0 "$line (not found)"
            }
            "Node .+ not responding, skipped" {
                ok 0 "$line (not responding)"
            }
            OK {
                ok 1 $line
                incr number_ok
            }
        }
        exp_continue   ;# loop back to top of expect block
    }
    $ROOT_PROMPT  ;# no action, so fall out of the expect block
}

Обратите внимание, что регулярные выражения Tcl либо полностью жадные, либо не жадные.Я использую \r\n(.+)\r\n для захвата строки, следующей за «Перезагружать конфигурацию на узле ...».Однако часть .+ не должна содержать переводы строки, поэтому она не должна быть жадной.Таким образом, каждый квантификатор в node_patt должен быть не жадным.

1 голос
/ 21 сентября 2010

Код в итоге выглядел так (простой цикл): 

send "cluster config -r -a \r"
set done 0
set number_ok 0
while {$done == 0} {
   set done 1
   expect {
      $ROOT_PROMPT { set done 1 }
      "ERROR" { cluster_exit 1 }
      -re "Reloading configuration on node.*\r" {
         set line "<$cmdline> $expect_out(0,string)"
         expect {
            $ROOT_PROMPT { set done 1 }
            "ERROR" { cluster_exit 1 }
            -re "Node * not found" { ok 0 "$line (not found)" }
            -re "Node * not responding, skipped" { ok 0 "$line (not responding)" }
            "OK" {
               ok 1 "$line"
               set number_ok [expr $number_ok + 1] 
               set done 0
            }
         }
      }
   }
}
diag "Done $done"
diag "Count $number_ok"
...