Строка SQL Server подстрока с итерациями

Question

У меня есть строка:

@TempCol  =  sigma_x1,sigma_x2,...,sigma_xd,XX,YY,ZZ

Я хочу получить подстроку, чтобы получить строку sigma_x1,sigma_x2,...,sigma_xd.

d - это переменная, поэтому она может быть 1,3, 20, ... и т. Д.

Я знаю значение d, но я не знаю, как получить подстроку исходной строки с d терминами.

Я пробовал это:

@L = ''
SET @ColumnNo = 0
WHILE @ColumnNo <= @d
BEGIN
    SET @L  =  @L + ' ' + SUBSTRING(@TempCol, 1, CHARINDEX(',',@TempCol)-1 )
    SET @TempCol    = REPLACE  ( @TempCol,  LTRIM(RTRIM(@L) ) ,'')
    Set @ColumnNo   = @ColumnNo + 1 
    PRINT @L
END 

но я не знаю, как получить ожидаемый результат.

Answer 1

DECLARE @TempCol varchar(max), @d int, @p int, @Result varchar(max);
SET @TempCol = 'item1,item2,itemA,itemB,item#,item$';
SET @d = 3;

SET @p = 1;

WHILE @d > 0 AND @p > 0 BEGIN
  SET @p = CHARINDEX(',', @TempCol, @p);
  IF @p > 0 SET @p = @p + 1;
  SET @d = @d - 1;
END;

IF @p = 0
  SET @Result = @TempCol
ELSE
  SET @Result = SUBSTRING(@TempCol, 1, @p - 2);

SELECT @Result;

По сути, цикл просто ищет конечную позицию для обрезки.Подстрока извлекается после цикла.

Если вы укажете слишком большое @d, тогда результатом будет просто все @TempCol, в противном случае вы получите нужное количество элементов.

Answer 2

Вам нужна функция разделения (показана внизу).

With SplitItems As
    (
    Select Position, Value
        , Row_Number() Over ( Order By Position ) As ItemNum
    From dbo.udf_Split( @TempCol, ',' )
    )
Select Value
From SplitItems
Where ItemNum <= @d

Если вы хотите собрать собранную строку до заданной точки, вы просто сделаете:

With SplitItems As
    (
    Select Position, Value
        , Row_Number() Over ( Order By Position ) As ItemNum
    From dbo.udf_Split( @TempCol, ',' )
    )
Select ',' + Value
From SplitItems
Where ItemNum <= @d
Order By ItemNum
For Xml Path('')

Функция разделения:

SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
Create FUNCTION [dbo].[udf_Split]
(   
    @DelimitedList nvarchar(max)
    , @Delimiter nvarchar(2) = ','
)
RETURNS TABLE 
AS
RETURN 
    (
    With CorrectedList As
        (
        Select Case When Left(@DelimitedList, Len(@Delimiter)) <> @Delimiter Then @Delimiter Else '' End
            + @DelimitedList
            + Case When Right(@DelimitedList, Len(@Delimiter)) <> @Delimiter Then @Delimiter Else '' End
            As List
            , Len(@Delimiter) As DelimiterLen
        )
        , Numbers As 
        (
        Select TOP( Coalesce(DataLength(@DelimitedList)/2,0) ) Row_Number() Over ( Order By c1.object_id ) As Value
        From sys.columns As c1
            Cross Join sys.columns As c2
        )
    Select CharIndex(@Delimiter, CL.list, N.Value) + CL.DelimiterLen As Position
        , Substring (
                    CL.List
                    , CharIndex(@Delimiter, CL.list, N.Value) + CL.DelimiterLen     
                    , CharIndex(@Delimiter, CL.list, N.Value + 1)                           
                        - ( CharIndex(@Delimiter, CL.list, N.Value) + CL.DelimiterLen ) 
                    ) As Value
    From CorrectedList As CL
        Cross Join Numbers As N
    Where N.Value <= DataLength(CL.List) / 2
        And Substring(CL.List, N.Value, CL.DelimiterLen) = @Delimiter
    )