Как бы я получил эту нечетную таблицу из XSLT? - PullRequest
Новая
       12

Как бы я получил эту нечетную таблицу из XSLT?

2 голосов
/ 02 июля 2010

Используя этот входной XML: 

<?xml version="1.0" encoding="utf-8"?>
<Employees>
   <Employee ID="1">
      <FirstName>Klaus</FirstName>
      <LastName>Salchner</LastName>
   </Employee>
   <Employee ID="2">
      <FirstName>Peter</FirstName>
      <LastName>Pan</LastName>
   </Employee>
</Employees>

Как бы вы получили этот вывод: 

<Employees>
    <FirstName>
        <Employee>Klaus</Employee>
        <Employee>Peter</Employee>
    </FirstName>
    <LastName>
        <Employee>Salchner</Employee>
        <Employee>Pan</Employee>
    </LastName>
</Employees>

Но, если вы не знаете, сколько полей будет вэлементы Employee - однако, давайте предположим, что одни и те же элементы (в данном случае FirstName и LastnName) обязательно будут присутствовать в каждом элементе Employee.

Лучшее, что у меня есть: 

<Employees>
    <xsl:for-each select="*/Employee/.">
        <xsl:value-of select=".">
            <xsl:value-of select="./." />
        </xsl:value-of>
    </xsl:for-each>
</Employees>

И я знаю, что это неправильно!

Ответы [ 3 ]

1 голос
/ 02 июля 2010

Это преобразование : 

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:key name="kElsByName" match="Employee/*"
  use="name()"/>

 <xsl:template match="/*">
   <Employees>
     <xsl:for-each select=
      "Employee/*[generate-id()
                 =
                  generate-id(key('kElsByName', name())[1])
                  ]">
       <xsl:element name="{name()}">
         <xsl:for-each select="key('kElsByName', name())">
           <Employee>
             <xsl:value-of select="."/>
           </Employee>
         </xsl:for-each>
       </xsl:element>
     </xsl:for-each>
   </Employees>
 </xsl:template>
</xsl:stylesheet>

при применении к этому документу XML (добавлено <DOB>, чтобы сделать его общим): 

<Employees>
   <Employee ID="1">
      <FirstName>Klaus</FirstName>
      <LastName>Salchner</LastName>
      <DOB>19670823</DOB>
   </Employee>
   <Employee ID="2">
      <FirstName>Peter</FirstName>
      <LastName>Pan</LastName>
      <DOB>19881113</DOB>
   </Employee>
</Employees>

дает желаемый результат : 

<Employees>
   <FirstName>
      <Employee>Klaus</Employee>
      <Employee>Peter</Employee>
   </FirstName>
   <LastName>
      <Employee>Salchner</Employee>
      <Employee>Pan</Employee>
   </LastName>
   <DOB>
      <Employee>19670823</Employee>
      <Employee>19881113</Employee>
   </DOB>
</Employees>

Примечание :

  1. Использование ключей и метод Мюнхена для группировки, чтобы найти все разные имена элементов, которые являются потомками Employee.

  2. Использование <xsl:element> с AVT для его атрибута name для генерации элементов с неизвестным именем во время компиляции.

0 голосов
/ 02 июля 2010

Ну, в конце концов, я разобрался с этим - в основном мне нужно for-each для элементов в первом Employee и назначить переменную внутри for-each для значения position ().

Затемво втором, вложенном для каждого, я перебираю внешние элементы Employee.

Для каждого элемента Employee я использую переменную (которая содержит «строку» внутреннего элемента) для индексации своего внутреннего элемента.

Что-то вроде: 

<xsl:for-each select="*/Employee[1]/.">
    <tr>
        <xsl:variable name="row" select="position()" />
        <xsl:for-each select="/*/Employee">
            <td>
                <xsl:value-of select=".[$row]/."/>
            </td>
        </xsl:for-each>
    </tr>
</xsl:for-each>

Признаюсь, мое немного более лаконично, но это суть.

Короткий (глубокий вдох) цикл по спискуэлементов первого внешнего элемента.Для каждого из них пройдитесь по внешним элементам и используйте индекс внутренних элементов, чтобы последовательно выбрать внутренние элементы.

0 голосов
/ 02 июля 2010

Если вам нужно обрабатывать узлы более одного раза, вы можете использовать шаблонные режимы . Следующее сделало бы: 

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="Employees">
    <Employees>
      <FirstName>
        <xsl:apply-templates mode="firstname" />
      </FirstName>
      <LastName>
        <xsl:apply-templates mode="lastname" />
      </LastName>
    </Employees>
  </xsl:template>

  <xsl:template match="Employee" mode="firstname">
    <Employee>
      <xsl:value-of select="FirstName"/>
    </Employee>
  </xsl:template>

  <xsl:template match="Employee" mode="lastname">
    <Employee>
      <xsl:value-of select="LastName"/>
    </Employee>
  </xsl:template>

</xsl:stylesheet>
...