Парные и непарные функции на Haskell

Question

У меня написаны следующие две функции.

pair :: [a] -> [(a, a)]
pair [] = []
pair [x] = []
pair (x1:x2:xs) = (x1, x2) : pair xs

unpair :: [(a, a)] -> [a]
unpair [] = []
unpair ((x1, x2):xs) = x1 : x2 : unpair xs

Пара возьмет пары элементов и сделает из них 2 кортежа. Если список содержит нечетное количество элементов, откажитесь от последнего. Unpair является обратной парой.

Это работает, но интересно, есть ли более лаконичный способ их написания.

Answer 1

Однострочные:

pair xs = map snd . filter fst . zip (iterate not True) $ zip xs (drop 1 xs)
unpair = concatMap (\(x,y) -> [x,y])

Вы могли бы также немного сократить свое определение pair:

pair (x1:x2:xs) = (x1, x2) : pair xs
pair _ = []

Answer 2

Это не более кратко, но для ясности я бы использовал splitEvery из Data.List.Split для pair:

pair = map tuplify . filter ((>1) . length) . splitEvery 2
  where
    tuplify [x, y] = (x, y)

Это не в моей голове, было бы лучше проверить длину только последнего списка.

Для unpair я бы использовал foldr, чтобы избежать явной рекурсии:

unpair = foldr (\(x, y) -> (x:) . (y:)) []

Это просто вопрос вкуса.

Answer 3

Так много возможностей.Как насчет этого?

unpair' = concatMap (\(x,y) -> [x,y])
pair' xs = map snd . filter fst . zip (cycle [True, False]) $ zip xs (tail xs)
pair'' xs = [(x,y) | (True,x,y) <- zip3 (cycle [True,False]) xs (tail xs)]

Две версии пары должны быть одинаковыми.

Редактировать: Что касается моего комментария выше, можно использовать пакет split из Hackage, чтобы написать:

pair xs = map head . splitEvery 2 $ zip xs (tail xs)

, что ближе к желаемому

pair xs = everyOther $ zip xs (tail xs)

Но, в духе бессмысленности, я думаю, что мы, вероятно, все должны согласиться на его написание,

pair = map head . splitEvery 2 . (zip <$> id <*> tail)

дляобеспечить путаницу.

Answer 4

Это хорошее использование для просмотра шаблонов :

{-# LANGUAGE ViewPatterns #-}

pair :: [a] -> [(a,a)]
pair (splitAt 2 -> ([x,y],ys)) = (x,y) : pair ys
pair _ = []

unpair :: [(a,a)] -> [a]
unpair = (>>= \(x,y) -> [x,y])

Answer 5

pair s = dropEven $ zip s (tail s)
     where dropEven s = map fst $ filter snd $ zip s (cycle [True, False])

unpair = concatMap (\(a, b) -> [a, b])

Хотя я определенно предпочитаю ваше определение pair.