Использовать ссылку на динамически созданный элемент управления в Word VBA - PullRequest
Новая
       30

Использовать ссылку на динамически созданный элемент управления в Word VBA

4 голосов
/ 24 ноября 2008

Я пишу форму в Word 2003, чтобы собрать несколько ответов на один вопрос. У меня есть макрос при нажатии кнопки, который дублирует различные поля ввода (раскрывающиеся списки, переключатели и т. Д.), Готовый для нового ответа.

Однако мне нужно изменить текст переключателей и установить событие OnChange в выпадающем списке, и я не могу найти правильный синтаксис для этого. Оба элемента управления находятся на панели инструментов Control Toolbox.

Код макроса, который мне нужно продублировать, находится ниже. 

Private Sub CommandButton11_Click() 
Set Doc = ActiveDocument
Response = MsgBox("Add another response?", vbYesNo, "Confirm action")
    If Response = vbYes Then
        If Doc.ProtectionType <> wdNoProtection Then
          Doc.Unprotect
        End If

        Selection.MoveRight
        Selection.MoveDown
        Selection.TypeParagraph
        ''# keep the reference to this control and set the OnChange event handler
        Selection.InlineShapes.AddOLEControl ClassType:="Forms.ComboBox.1"
        Selection.MoveRight Unit:=wdCharacter, Count:=1
        Selection.TypeText Text:=vbTab
        Selection.TypeText Text:=vbTab
        ''# keep the reference to this control and set text
        Selection.InlineShapes.AddOLEControl ClassType:="Forms.OptionButton.1"
        Selection.MoveRight Unit:=wdCharacter, Count:=1

        Doc.Protect Type:=wdAllowOnlyFormFields, NoReset:=True
    End If
End Sub

1 Ответ

3 голосов
/ 29 ноября 2008

динамическое добавление обработчиков событий немного сложнее.

Вы можете динамически добавлять код в ThisDocument. Microsoft описывает этот способ так: http://support.microsoft.com/?scid=kb%3Ben-us%3B246299&x=14&y=10. Однако, когда я попробовал этот Word 2007, произошел сбой.

Другой способ - добавить класс для обработки событий и создать экземпляр этого класса для каждого элемента управления. Поместите следующий код в модуль: 

Option Explicit

Public objControls() As clsComboBox

Private Sub CommandButton11_Click()
    Dim objShape As InlineShape

    If ActiveDocument.ProtectionType <> wdNoProtection Then
        ActiveDocument.Unprotect
    End If

    Selection.MoveRight
    Selection.MoveDown
    Selection.TypeParagraph
    ' keep the reference to this control and set the OnChange event handler
    Set objShape = Selection.InlineShapes.AddOLEControl(ClassType:="Forms.ComboBox.1")
    With objShape.OLEFormat.Object
        .AddItem "Item 1"
        .AddItem "Item 2"
    End With

    Selection.MoveRight Unit:=wdCharacter, Count:=1
    Selection.TypeText Text:=vbTab
    Selection.TypeText Text:=vbTab
    ' keep the reference to this control and set text
    Set objShape = Selection.InlineShapes.AddOLEControl(ClassType:="Forms.OptionButton.1")
    With objShape.OLEFormat.Object
        .Caption = "My great option"
    End With
    Selection.MoveRight Unit:=wdCharacter, Count:=1

    ActiveDocument.Protect Type:=wdAllowOnlyFormFields, NoReset:=True

    ' we have to execute the creation of the event handlers with a delay
    ' to make it work (seems Word needs some time for object creation)
    Application.OnTime When:=Now + TimeValue("00:00:01"), Name:="prcCreateReference"

End Sub

Public Sub prcCreateReference()
    Dim objShape As InlineShape
    Dim intCount As Integer

    On Error Resume Next
    For Each objShape In ThisDocument.InlineShapes
        intCount = intCount + 1
        ReDim Preserve objControls(1 To intCount)
        If TypeOf objShape.OLEFormat.Object Is ComboBox Then
            Set objControls(intCount) = New clsComboBox
            Set objControls(intCount).ComboBox = objShape.OLEFormat.Object
        ElseIf TypeOf objShape.OLEFormat.Object Is OptionButton Then
            ' add event handlers for option buttons
        End If
    Next
End Sub

Этот код должен входить в модуль класса с именем clsComboBox: 

Option Explicit

Private WithEvents mobjComboBox As MSForms.ComboBox

Friend Property Set ComboBox(objComboBox As MSForms.ComboBox)
    Set mobjComboBox = objComboBox
End Property

Private Sub mobjComboBox_Change()
    MsgBox "Selection changed."
End Sub

Private Sub mobjComboBox_Click()
    MsgBox "Clicked."
End Sub

Обратите внимание, что переменная objControls должна иметь тип clsComboBox. Объявление этой переменной как Object или Variant мне не помогло (кто-нибудь может объяснить, почему ???).

...