Почему моя инструкция if не работает, в моей хранимой процедуре

Question

Хорошо, поэтому я даже не уверен, возможно ли это У меня есть q_00 и q_01 и q_02, которые все находятся в моей хранимой процедуре. тогда на дне у меня есть 3 выбора которые выбирают определенную категорию, например Продажи, Чистые продажи и продажи INS

То, что я хочу сделать, - это если пользователь введет exec (имя моего sp) (продажи) (и год, который является @yearparameter), он запустит оператор выбора продаж

Если они введут Exec (имя моего SP) netsales (@Yeartoget), это покажет чистые продажи, если это возможно, или мне нужно несколько хранимых процедур

   ALTER PROCEDURE [dbo].[casof]
 @YearToGet int,
 @mode VARCHAR(20)
 as
;
with
q_00 as (
select
      DIVISION
    , SDESCR
    , DYYYY
    , sum(APRICE)        as asofSales 
    , sum(PARTY)         as asofPAX        
    , sum(NetAmount)     as asofNetSales        
    , sum(InsAmount)     as asofInsSales        
    , sum(CancelRevenue) as asofCXSales        
    , sum(OtherAmount)   as asofOtherSales        
    , sum(CXVALUE)       as asofCXValue  
from dbo.B101BookingsDetails 
where Booked <= CONVERT(int,DateAdd(year, @YearToGet - Year(getdate()), DateAdd(day, DateDiff(day, 1, getdate()), 0)))
  and DYYYY = @YearToGet
group by DIVISION, SDESCR, DYYYY 
),
q_01 as (
select     
      DIVISION 
    , SDESCR
    , DYYYY 
    , sum(APRICE)        as YESales 
    , sum(PARTY)         as YEPAX 
    , sum(NetAmount)     as YENetSales
    , sum(InsAmount)     as YEInsSales 
    , sum(CancelRevenue) as YECXSales 
    , sum(OtherAmount)   as YEOtherSales
    , sum(CXVALUE)       as YECXValue
from  dbo.B101BookingsDetails 
where DYYYY=@YearToGet
group by DIVISION, SDESCR, DYYYY 
),
q_02 as (
select
      DIVISION
    , SDESCR
    , DYYYY
    , sum(APRICE)        as CurrentSales 
    , sum(PARTY)         as CurrentPAX        
    , sum(NetAmount)     as CurrentNetSales        
    , sum(InsAmount)     as CurrentInsSales        
    , sum(CancelRevenue) as CurrentCXSales        
    , sum(OtherAmount)   as CurrentOtherSales        
    , sum(CXVALUE)       as CurrentCXValue  
from dbo.B101BookingsDetails 
where Booked <= CONVERT(int,DateAdd(year, (year( getdate() )) - Year(getdate()), DateAdd(day, DateDiff(day, 1, getdate()), 0)))
  and DYYYY = (year( getdate() ))
group by DIVISION, SDESCR, DYYYY 
)

IF @mode = 'sales'
select
      a.DIVISION 
    , a.SDESCR
    , a.DYYYY
    , asofSales 
    , asofPAX        
    , YESales 
    , YEPAX 
    , CurrentSales 
    , CurrentPAX 
    , asofsales/ ISNULL(NULLIF(yesales,0),1) as percentsales
    , asofpax/yepax as percentpax
    ,currentsales/ISNULL(NULLIF((asofsales/ISNULL(NULLIF(yesales,0),1)),0),1) as projectedsales
    ,currentpax/ISNULL(NULLIF((asofpax/ISNULL(NULLIF(yepax,0),1)),0),1) as projectedpax
from q_00 as a
join q_01 as b on (b.DIVISION = a.DIVISION and b.SDESCR = a.SDESCR and b.DYYYY = a.DYYYY) 
join q_02 as c on (b.DIVISION = c.DIVISION and b.SDESCR = c.SDESCR)
order by a.DIVISION, a.SDESCR, a.DYYYY ;


else if @mode= 'netsales'

select
      a.DIVISION 
    , a.SDESCR
    , a.DYYYY
    , asofPAX        
    , asofNetSales        
    , YEPAX 
    , YENetSales
    , CurrentPAX 
    , CurrentNetSales
    , asofnetsales/ ISNULL(NULLIF(yenetsales,0),1) as percentnetsales
    , asofpax/yepax as percentpax


,currentnetsales/ISNULL(NULLIF((asofnetsales/ISNULL(NULLIF(yenetsales,0),1)),0),1) as projectednetsales
,currentpax/ISNULL(NULLIF((asofpax/ISNULL(NULLIF(yepax,0),1)),0),1) as projectedpax

from q_00 as a
join q_01 as b on (b.DIVISION = a.DIVISION and b.SDESCR = a.SDESCR and b.DYYYY = a.DYYYY) 
join q_02 as c on (b.DIVISION = c.DIVISION and b.SDESCR = c.SDESCR)
order by a.DIVISION, a.SDESCR, a.DYYYY ;

 ELSE IF @mode = 'inssales'

select
      a.DIVISION 
    , a.SDESCR
    , a.DYYYY
    , asofPAX     
    , asofInsSales        
    , YEPAX 
    , YEInsSales 
    , CurrentPAX 
    , CurrentInsSales 
    , asofinssales/ ISNULL(NULLIF(yeinssales,0),1) as percentsales
    , asofpax/yepax as percentpax
    ,currentinssales/ISNULL(NULLIF((asofinssales/ISNULL(NULLIF(yeinssales,0),1)),0),1) as projectedinssales

from q_00 as a
join q_01 as b on (b.DIVISION = a.DIVISION and b.SDESCR = a.SDESCR and b.DYYYY = a.DYYYY) 
join q_02 as c on (b.DIVISION = c.DIVISION and b.SDESCR = c.SDESCR)
order by a.DIVISION, a.SDESCR, a.DYYYY ;

Answer 1

Просто добавьте еще один параметр с именем say @mode и используйте if @mode='sales' для выполнения условной логики.

После вашего обновления, хотя у меня возникнет желание создать два встроенных TVF с параметром помощника.

CREATE FUNCTION dbo.AggregateBookingDetails  
(   
    @Booked datetime, 
    @YearToGet int
)
RETURNS TABLE 
AS
RETURN 
(
select
      DIVISION
    , SDESCR
    , DYYYY
    , sum(APRICE)        as Sales 
    , sum(PARTY)         as PAX        
    , sum(NetAmount)     as NetSales        
    , sum(InsAmount)     as InsSales        
    , sum(CancelRevenue) as CXSales        
    , sum(OtherAmount)   as OtherSales        
    , sum(CXVALUE)       as CXValue  
from dbo.B101BookingsDetails 
where @Booked IS NULL OR Booked <= @Booked
  and DYYYY = @YearToGet
group by DIVISION, SDESCR, DYYYY 
)

GO

CREATE FUNCTION fn_casof
(   
    @YearToGet int
)
RETURNS TABLE 
AS
RETURN 
(
select       
      a.DIVISION
    , a.SDESCR
    , a.DYYYY
    , a.Sales as a_Sales
    , b.Sales as b_Sales
    , c.Sales as c_Sales
    , .... /*etc. etc*/
from dbo.AggregateBookingDetails(CONVERT(int,DateAdd(year, @YearToGet - Year(getdate()), DateAdd(day, DateDiff(day, 1, getdate()), 0))), @YearToGet) as a
join dbo.AggregateBookingDetails(NULL, @YearToGet) as b on (b.DIVISION = a.DIVISION and b.SDESCR = a.SDESCR and b.DYYYY = a.DYYYY) 
join dbo.AggregateBookingDetails(CONVERT(int,DateAdd(year, (year( getdate() )) - Year(getdate()), DateAdd(day, DateDiff(day, 1, getdate()), 0))), year( getdate() )) as c on (b.DIVISION = c.DIVISION and b.SDESCR = c.SDESCR)
)

Тогда вашей условной логике хранимой процедуры нужно будет просто выбрать нужные столбцы из второго из этих TVF.

ALTER PROCEDURE [dbo].[casof]
@YearToGet int,
@mode VARCHAR(20)
as
IF (@mode='sales')
SELECT collist1 FROM dbo.fn_casof(@yeartoget)
ELSE
    IF (@mode='netsales')
    SELECT collist2 FROM dbo.fn_casof(@yeartoget)
    ELSE
    SELECT collist3 FROM dbo.fn_casof(@yeartoget)

Answer 2

Не уверен, что это то, что вы спрашиваете, но:

CREATE PROCEDURE prcSelector @query VARCHAR(20), @yeartoget INT
AS
        IF @query = 'sales'
                SELECT  @yeartoget
        ELSE IF @query = 'netsales'
                SELECT  'netsales'
        ELSE IF @query = 'other'
                SELECT  'other'

Замените SELECT заявления вашими запросами.