Есть ли в libxslt возможность разбивать документ на несколько документов? - PullRequest
Новая
       28

Есть ли в libxslt возможность разбивать документ на несколько документов?

6 голосов
/ 02 июля 2010

Похоже, libxslt не поддерживает XSLT 2.0 и xsl:result-document. Есть ли способ имитировать xsl:result-document, используя libxslt или xsltproc?

Ответы [ 3 ]

14 голосов
/ 03 июля 2010

Да, есть, используя exsl: document . Простой пример: 

==== foo.xsl ====
<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
                xmlns:exsl="http://exslt.org/common"
                extension-element-prefixes="exsl">
  <xsl:output method="html"/>
  <xsl:template match="/">
    <exsl:document href="toc.html" method="html">
      <html>
        <body>
          <xsl:apply-templates select=".//h1"/>
        </body>
      </html>
    </exsl:document>
    <xsl:apply-templates/>
  </xsl:template>
  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>

принимая это как ввод: 

==== foo.html ====
<html>
  <body>
    <h1>Hello, world!</h1>
    <p>Some longwinded text follows.</p>
  </body>
</html>

при запуске так: 

xsltproc foo.xsl foo.html

выдаст это stdout: 

<html>
  <body>
    <h1>Hello, world!</h1>
    <p>Some longwinded text follows.</p>
  </body>
</html>

при этом также записывает это в toc.html: 

<html><body><h1>Hello, world!</h1></body></html>
3 голосов
/ 02 июля 2010

Если libxslt реализует EXSLT , то вы можете использовать элемент расширения <exsl:document>.

Если нет, то вы должны написать свои собственные функции расширения, поскольку XSLT 1.0 не поддерживает создание нескольких документов результатов.

Обновление : Как подтверждено в этом комментарии , libxslt реализует EXSLT. Просто возьмите его и используйте <exsl:document>.

1 голос
/ 07 сентября 2015

А вот пример, который показывает, как использовать расширение для создания неограниченного количества файлов при обходе набора узлов.Опять же, используя xsltproc (libxslt)

Образец XML-ввода: 

<clients>
    <client id="ACME1" name="ACME Company 1"/>
    <client id="ACME2" name="ACME Company 2"/>
    <client id="ACME3" name="ACME Company 3"/>
</clients>

Образец XSLT: 

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0" 
                xmlns:exsl="http://exslt.org/common"
                extension-element-prefixes="exsl">

<xsl:output method="html" indent="yes" encoding="UTF-8" />

<xsl:template match="/">
    <xsl:for-each select="/clients/client">
    <exsl:document href="{@id}.html" method="html">
      <html>
        <body>
          <h1>Company: <xsl:apply-templates select="@name"/></h1>
        </body>
      </html>
    </exsl:document>
    </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

Создает 3 файла ACME1.html, ACME2.htmlи т.д.

...