XSLT строка заменить

Question

Я действительно не знаю XSL, но мне нужно исправить этот код, я уменьшил его, чтобы упростить его.
Я получаю эту ошибку

Неправильная функция XSLT / XPath

в этой строке

<xsl:variable name="text" select="replace($text,'a','b')"/>

Это XSL

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:inm="http://www.inmagic.com/webpublisher/query" version="1.0">
    <xsl:output method="text" encoding="UTF-8" />

    <xsl:preserve-space elements="*" />
    <xsl:template match="text()" />

    <xsl:template match="mos">
        <xsl:apply-templates />

        <xsl:for-each select="mosObj">
          'Notes or subject' 
           <xsl:call-template
                name="rem-html">
                <xsl:with-param name="text" select="SBS_ABSTRACT" />
            </xsl:call-template>
        </xsl:for-each>
    </xsl:template>

    <xsl:template name="rem-html">
        <xsl:param name="text" />
        <xsl:variable name="text" select="replace($text, 'a', 'b')" />
    </xsl:template>
</xsl:stylesheet>

Может кто-нибудь сказать мне, что с ним не так?

Answer 1

replace недоступно для XSLT 1.0.

У Codesling есть шаблон для замены строк , который можно использовать вместо функции:

<xsl:template name="string-replace-all">
    <xsl:param name="text" />
    <xsl:param name="replace" />
    <xsl:param name="by" />
    <xsl:choose>
        <xsl:when test="$text = '' or $replace = ''or not($replace)" >
            <!-- Prevent this routine from hanging -->
            <xsl:value-of select="$text" />
        </xsl:when>
        <xsl:when test="contains($text, $replace)">
            <xsl:value-of select="substring-before($text,$replace)" />
            <xsl:value-of select="$by" />
            <xsl:call-template name="string-replace-all">
                <xsl:with-param name="text" select="substring-after($text,$replace)" />
                <xsl:with-param name="replace" select="$replace" />
                <xsl:with-param name="by" select="$by" />
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="$text" />
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

вызывается как:

<xsl:variable name="newtext">
    <xsl:call-template name="string-replace-all">
        <xsl:with-param name="text" select="$text" />
        <xsl:with-param name="replace" select="a" />
        <xsl:with-param name="by" select="b" />
    </xsl:call-template>
</xsl:variable>

С другой стороны, если вам буквально нужно заменить только один символ другим, вы можете позвонить translate, который имеет аналогичную подпись. Примерно так должно работать нормально:

<xsl:variable name="newtext" select="translate($text,'a','b')"/>

Кроме того, обратите внимание, что в этом примере я изменил имя переменной на «newtext», в XSLT переменные являются неизменяемыми, поэтому вы не можете сделать эквивалент $foo = $foo, как в исходном коде.

Answer 2

Вот функция XSLT, которая будет работать аналогично функции String.Replace () в C #.

Этот шаблон имеет 3 параметра, как показано ниже

текст : - ваша основная строка

replace : - строка, которую вы хотите заменить

от : - строка, которая будет отвечать новой строкой

Ниже приведены шаблоны

<xsl:template name="string-replace-all">
  <xsl:param name="text" />
  <xsl:param name="replace" />
  <xsl:param name="by" />
  <xsl:choose>
    <xsl:when test="contains($text, $replace)">
      <xsl:value-of select="substring-before($text,$replace)" />
      <xsl:value-of select="$by" />
      <xsl:call-template name="string-replace-all">
        <xsl:with-param name="text" select="substring-after($text,$replace)" />
        <xsl:with-param name="replace" select="$replace" />
        <xsl:with-param name="by" select="$by" />
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <xsl:value-of select="$text" />
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

Ниже приведен пример, как его назвать

<xsl:variable name="myVariable ">
  <xsl:call-template name="string-replace-all">
    <xsl:with-param name="text" select="'This is a {old} text'" />
    <xsl:with-param name="replace" select="'{old}'" />
    <xsl:with-param name="by" select="'New'" />
  </xsl:call-template>
</xsl:variable>

Для получения подробной информации вы также можете обратиться к ниже URL .

Answer 3

Примечание: В случае, если вы хотите использовать уже упомянутый алгоритм для случаев, когда вам нужно заменить огромное количество экземпляров в исходной строке (например, новые строки в длинном тексте), есть высокая вероятность того, что вы получите StackOverflowException из-за рекурсивного вызова.

Я решил эту проблему благодаря Xalan (не смотрел, как это сделатьв Saxon ) встроенное встраивание Java-типа:

<xsl:stylesheet version="1.0" exclude-result-prefixes="xalan str"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:xalan="http://xml.apache.org/xalan"
                xmlns:str="xalan://java.lang.String"
        >
...
<xsl:value-of select="str:replaceAll(
    str:new(text()),
    $search_string,
    $replace_string)"/>
...
</xsl:stylesheet>

Answer 4

Вы можете использовать следующий код, когда ваш процессор работает в .NET или использует MSXML (в отличие от основанных на Java или других собственных процессоров) Используется msxsl:script.

Обязательно добавьте пространство имен xmlns:msxsl="urn:schemas-microsoft-com:xslt" к корневому элементу xsl:stylesheet или xsl:transform.

Кроме того, привяжите outlet к любому пространству имен, которое вам нравится, например xmlns:outlet = "http://my.functions".

<msxsl:script implements-prefix="outlet" language="javascript">
function replace_str(str_text,str_replace,str_by)
{
     return str_text.replace(str_replace,str_by);
}
</msxsl:script>


<xsl:variable name="newtext" select="outlet:replace_str(string(@oldstring),'me','you')" />

Answer 5

Процедура довольно хорошая, однако она вызывает зависание моего приложения, поэтому мне нужно было добавить регистр:

  <xsl:when test="$text = '' or $replace = ''or not($replace)" >
    <xsl:value-of select="$text" />
    <!-- Prevent thsi routine from hanging -->
  </xsl:when>

, прежде чем функция будет вызываться рекурсивно.

Я получилОтвет отсюда: При тестировании зависания в бесконечном цикле

Спасибо!