Используйте двойное отрицание:
/[^\S\r\n]/
То есть не-не-пробел (заглавная S дополняет) или не-возврат каретки или не-перевод строки. Распределение внешнего не ( т.е. , дополняющего ^ в классе символов) с законом Де Моргана , это эквивалентно «пробелу, но не возврату каретки или переводу строки». \r и \n в шаблоне корректно обрабатывают все Unix (LF), классические Mac OS (CR) и DOS-иш (CR LF) соглашения новой строки .
Не нужно верить мне на слово:
#! /usr/bin/env perl
use strict;
use warnings;
use 5.005; # for qr//
my $ws_not_crlf = qr/[^\S\r\n]/;
for (' ', '\f', '\t', '\r', '\n') {
my $qq = qq["$_"];
printf "%-4s => %s\n", $qq,
(eval $qq) =~ $ws_not_crlf ? "match" : "no match";
}
Выход:
" " => match
"\f" => match
"\t" => match
"\r" => no match
"\n" => no match
Обратите внимание на исключение вертикальной табуляции, но это , адресованное в v5.18 .
Прежде чем возражать слишком резко, в документации Perl используется та же техника. Сноска в разделе «Пробел» в perlrecharclass гласит:
До Perl v5.18 \s не соответствовал вертикальной табуляции. [^\S\cK] (неясно) соответствует тому, что традиционно делал \s.
В том же разделе 1036 * perlrecharclass также предлагаются другие подходы, которые не будут оскорблять оппозицию учителей языка двойным негативам.
Вне локали и правил Unicode или когда действует переключатель /a, «\s соответствует [\t\n\f\r ] и, начиная с Perl v5.18, вертикальная вкладка, \cK». Discard \r и \n оставить /[\t\f\cK ]/ для совпадения пробелов, но не для новой строки.
Если ваш текст Unicode, используйте код, подобный приведенному ниже, для построения шаблона из таблицы в вышеупомянутом разделе документации .
sub ws_not_nl {
local($_) = <<'EOTable';
0x0009 CHARACTER TABULATION h s
0x000a LINE FEED (LF) vs
0x000b LINE TABULATION vs [1]
0x000c FORM FEED (FF) vs
0x000d CARRIAGE RETURN (CR) vs
0x0020 SPACE h s
0x0085 NEXT LINE (NEL) vs [2]
0x00a0 NO-BREAK SPACE h s [2]
0x1680 OGHAM SPACE MARK h s
0x2000 EN QUAD h s
0x2001 EM QUAD h s
0x2002 EN SPACE h s
0x2003 EM SPACE h s
0x2004 THREE-PER-EM SPACE h s
0x2005 FOUR-PER-EM SPACE h s
0x2006 SIX-PER-EM SPACE h s
0x2007 FIGURE SPACE h s
0x2008 PUNCTUATION SPACE h s
0x2009 THIN SPACE h s
0x200a HAIR SPACE h s
0x2028 LINE SEPARATOR vs
0x2029 PARAGRAPH SEPARATOR vs
0x202f NARROW NO-BREAK SPACE h s
0x205f MEDIUM MATHEMATICAL SPACE h s
0x3000 IDEOGRAPHIC SPACE h s
EOTable
my $class;
while (/^0x([0-9a-f]{4})\s+([A-Z\s]+)/mg) {
my($hex,$name) = ($1,$2);
next if $name =~ /\b(?:CR|NL|NEL|SEPARATOR)\b/;
$class .= "\\N{U+$hex}";
}
qr/[$class]/u;
}
Другие приложения
Двойной отрицательный трюк также удобен для сопоставления буквенных символов. Помните, что \w соответствует «символам слова», буквенным символам и , цифрам и подчеркиванию. Мы, некрасивые американцы, иногда хотим написать это, скажем,
if (/[A-Za-z]+/) { ... }
но класс символов с двойным отрицанием может уважать локаль:
if (/[^\W\d_]+/) { ... }
Выражение «символ слова, но не цифра или подчеркивание» таким образом немного непрозрачно. Символьный класс POSIX сообщает намерение более прямо
if (/[[:alpha:]]+/) { ... }
или со свойством Unicode как szbalint рекомендуется
if (/\p{Letter}+/) { ... }