Объединение столбцов в строки

Question

Вот сценарий с продуктом, который мы купили. Продукт позволяет нам создавать настраиваемые поля, но эти поля хранятся в виде строк в таблице CUSTOM.

Я хочу написать запрос, который будет подключаться к нескольким настраиваемым полям и извлекать одну строку.

Позвольте привести пример.

1) PERSON TABLE (ID int, NAME varchar2(30));
2) CUSTOMFIELDS TABLE(CFID int, CFTable varchar2(30), CFFieldName varchar2(30), CFFieldType varchar2(30));
3) CUSTOMFIELDVALUE TABLE(CFVID int, CFID int, CFFieldName varchar2(100), CFFieldValue varchar2(100));

В моей личной таблице есть одна запись

1) 1001 - Clark Kent

Допустим, я создал два пользовательских поля для человека с именами ВОЗРАСТ и ВЕС. В этом случае в таблице CUSTOMFIELDS будут созданы две записи.

1) 100 - PERSON - AGE - INTEGER
2) 200 - PERSON - WEIGHT - INTEGER

Теперь значения для этих настраиваемых полей будут храниться в таблице CUSTOMFIELDVALUE следующим образом.

1) 100 - 100 - 1001 - 44
2) 101 - 200 - 1001 - 200 lbs

Я хочу написать запрос на выборку, который будет извлекать запись, подобную этой

PERSON, AGE , WEIGHT
Clark Kent, 44, 200 lbs

Я думаю, как этого можно достичь с помощью чистого SQL. Количество настраиваемых полей может увеличиваться или уменьшаться в зависимости от конфигурации продукта.

Answer 1

Это интересная проблема.Вы хотите динамически изменить количество и название столбцов.Это невозможно создать с помощью «нормального» SQL.Я попытался создать образец с использованием PIPELINED FUNCTION.

Сначала я создал таблицу:

CREATE TABLE PERSON (ID int, NAME varchar2(30));
CREATE TABLE CUSTOMFIELDS (CFID int, CFTable varchar2(30), CFFieldName varchar2(30), CFFieldType varchar2(30));
CREATE TABLE CUSTOMFIELDVALUE (CFVID int, CFID int, CFFieldName varchar2(100), CFFieldValue varchar2(100));

INSERT INTO PERSON(id, name) values(1001, 'Clark Kent');
INSERT INTO CUSTOMFIELDS(CFID, CFTable, CFFieldName, CFFieldType) values(100, 'PERSON', 'AGE', 'INTEGER');
INSERT INTO CUSTOMFIELDS(CFID, CFTable, CFFieldName, CFFieldType) values(200, 'PERSON', 'WEIGHT', 'INTEGER');

... и поместил некоторые данные:

INSERT INTO CUSTOMFIELDVALUE (CFVID, CFID, CFFieldName, CFFieldValue) values(100, 100, 1001, 44);
INSERT INTO CUSTOMFIELDVALUE (CFVID, CFID, CFFieldName, CFFieldValue) values(101, 200, 1001, 200);

ЗатемЯ создал тип объекта:

CREATE TYPE CustomFieldType AS OBJECT
(
  row_id number,
  fieldType varchar2(200),
  person_id number,
  fieldValue1 varchar2(2000),
  fieldValue2 varchar2(2000),
  fieldValue3 varchar2(2000),
  fieldValue4 varchar2(2000),
  fieldValue5 varchar2(2000)
)
/

CREATE TYPE CustomFieldTypeSet AS TABLE OF CustomFieldType
/

А также создал ТРУБОПРОВОДНУЮ ФУНКЦИЮ:

CREATE OR REPLACE
    FUNCTION GET_PERSON_FIELDS(person_id_in   IN NUMBER
                                    ,field_names_in IN VARCHAR2) RETURN CustomFieldTypeSet
        PIPELINED
    IS

        -- constructor CustomFieldType()
        l_header_row          CustomFieldType := CustomFieldType(NULL, NULL, NULL, NULL, NULL, NULL, NULL, NULL);
        l_data_row            CustomFieldType := CustomFieldType(NULL, NULL, NULL, NULL, NULL, NULL, NULL, NULL);
        l_tablen              BINARY_INTEGER;
        l_tab                 DBMS_UTILITY.uncl_array;
        l_num_of_field_values PLS_INTEGER := 5;
        l_counter             PLS_INTEGER := 1;
        l_position            PLS_INTEGER;
        l_field_names_in      VARCHAR2(2000) := field_names_in;

        TYPE type_header_hash IS TABLE OF PLS_INTEGER INDEX BY VARCHAR2(200);
        l_header_hash type_header_hash;

    BEGIN

        -- 1) check, what fields you can display

        IF (l_field_names_in IS NULL) THEN

            <<get_all_fields>>
            FOR cur_all_fields IN  (SELECT DISTINCT flds.CFFIELDNAME
                                               FROM CUSTOMFIELDS flds
                                                   ,CUSTOMFIELDVALUE cfv
                                              WHERE cfv.CFID = flds.CFID
                                                AND flds.CFTable = 'PERSON' ) LOOP
                l_field_names_in := l_field_names_in ||
                                    cur_all_fields.CFFIELDNAME ||
                                    ',';
            END LOOP get_all_fields;

        END IF;

        -- 2) generate header (function RTRIM prevent ORA-00931 exception!)

        DBMS_UTILITY.comma_to_table(list => RTRIM(l_field_names_in, ','), tablen => l_tablen, tab => l_tab);
        l_header_row.row_id := 1;
        l_header_row.fieldType := 'HEADER';

        <<header_cursor>>
        FOR i IN 1..l_tablen LOOP

            IF (i = 1) THEN
                l_header_row.fieldValue1 := l_tab(i);
                l_header_hash(l_tab(i)) := i;
            ELSIF (i = 2) THEN
                l_header_row.fieldValue2 := l_tab(i);
                l_header_hash(l_tab(i)) := i;
            ELSIF (i = 3) THEN
                l_header_row.fieldValue3 := l_tab(i);
                l_header_hash(l_tab(i)) := i;
            ELSIF (i = 4) THEN
                l_header_row.fieldValue4 := l_tab(i);
                l_header_hash(l_tab(i)) := i;
            ELSIF (i = 5) THEN
                l_header_row.fieldValue5 := l_tab(i);
                l_header_hash(l_tab(i)) := i;
            END IF;

        END LOOP header_cursor;

        -- 3) print data to SQL (over pipe)...

        PIPE ROW(l_header_row);

        FOR cur_persons IN  (SELECT ID
                               FROM PERSON
                              WHERE ID = COALESCE(person_id_in, ID) ) LOOP
            l_data_row.row_id := NULL;
            l_data_row.person_id := NULL;
            l_data_row.fieldType := NULL;
            l_data_row.fieldValue1 := NULL;
            l_data_row.fieldValue2 := NULL;
            l_data_row.fieldValue3 := NULL;
            l_data_row.fieldValue4 := NULL;
            l_data_row.fieldValue5 := NULL;
            l_data_row.fieldType := 'DATA';
            FOR cur_data IN  (SELECT p.ID AS person_id
                                    ,cfv.CFID
                                    ,flds.CFTABLE
                                    ,flds.CFFIELDNAME
                                    ,cfv.CFFIELDVALUE
                                FROM PERSON p
                                    ,CUSTOMFIELDS flds
                                    ,CUSTOMFIELDVALUE cfv
                               WHERE p.ID = cur_persons.ID
                                 AND p.ID = cfv.CFFIELDNAME
                                 AND cfv.CFID = flds.CFID ) LOOP
                l_data_row.person_id := cur_persons.ID;
                l_position := NULL;

                IF (l_header_hash.EXISTS(cur_data.CFFIELDNAME)) THEN
                    l_position := l_header_hash(cur_data.CFFIELDNAME);
                END IF;

                IF (l_position = 1) THEN
                    l_data_row.fieldValue1 := cur_data.CFFIELDVALUE;
                ELSIF (l_position = 2) THEN
                    l_data_row.fieldValue2 := cur_data.CFFIELDVALUE;
                ELSIF (l_position = 3) THEN
                    l_data_row.fieldValue3 := cur_data.CFFIELDVALUE;
                ELSIF (l_position = 4) THEN
                    l_data_row.fieldValue4 := cur_data.CFFIELDVALUE;
                ELSIF (l_position = 5) THEN
                    l_data_row.fieldValue5 := cur_data.CFFIELDVALUE;
                END IF;

            END LOOP;
            l_counter := l_counter + 1;
            l_data_row.row_id := l_counter;
            PIPE ROW(l_data_row);
        END LOOP;

        RETURN;
    END GET_PERSON_FIELDS;

Чем вы можете использовать SQL для получения примеров данных (примечание: исключите исключение ORA-22905, вы должныустановить переменную сеанса "ALTER SESSION SET CURSOR_SHARING = EXACT;"):

SELECT * FROM TABLE(GET_PERSON_FIELDS(1001,'AGE,WEIGHT'));

А вот и вывод:

ROW_ID FIELDTYPE  PERSON_ID FIELDVALUE FIELDVALUE FIELDVALUE
------ ---------- --------- ---------- ---------- ----------
     1 HEADER               AGE
     2 DATA            1001 44

В первом столбце находится заголовок, где хранится информация о полеимена и после заголовка хранятся данные.Вы можете использовать комбинацию этих SQL:

SELECT * FROM TABLE(GET_PERSON_FIELDS(1001,'AGE,WEIGHT'));
SELECT * FROM TABLE(GET_PERSON_FIELDS(1002,'AGE,GENDER'));
SELECT * FROM TABLE(GET_PERSON_FIELDS(1001,NULL));
SELECT * FROM TABLE(GET_PERSON_FIELDS(NULL,NULL));

1. Первый аргумент это person_id
2. Второй аргумент - это список элементов, которые вы хотите увидеть на выходе
3. , еслипервый аргумент равен NULL, вы можете увидеть список всех лиц
4. , если второй аргумент равен NULL, вы можете увидеть список всех аргументов
5. Сценарий не завершен и имеет некоторые ограничения:
   1. в объекте CustomFieldType вы не можете динамически изменять количество полей (я имею в виду fieldValue1, fieldValue2 ...)
   2. в теле функции GET_PERSON_FIELDS, как вы можете видеть, динамически проблема также в выражениях IF (IF (l_position)= 1) THEN l_data_row.fieldValue1, IF (l_position = 2) THEN l_data_row.fieldValue1) ...

Наконец, когда я ввел некоторые примеры данных, например:

INSERT INTO PERSON(id, name) values(1002, 'Lois Lane');
INSERT INTO CUSTOMFIELDS(CFID, CFTable, CFFieldName, CFFieldType) values(300, 'PERSON', 'GENDER', 'VARCHAR');
INSERT INTO CUSTOMFIELDS(CFID, CFTable, CFFieldName, CFFieldType) values(400, 'PERSON', 'SINGLE', 'VARCHAR');
INSERT INTO CUSTOMFIELDVALUE (CFVID, CFID, CFFieldName, CFFieldValue) values(102, 100, 1002, 45);
INSERT INTO CUSTOMFIELDVALUE (CFVID, CFID, CFFieldName, CFFieldValue) values(103, 300, 1002, 'FEMALE');
INSERT INTO CUSTOMFIELDVALUE (CFVID, CFID, CFFieldName, CFFieldValue) values(104, 400, 1002, 'YES');

... и запустил эту команду SQL:

SELECT * FROM TABLE(GET_PERSON_FIELDS(NULL,NULL));

... вывод выглядел так:

ROW_ID FIELDTYPE  PERSON_ID FIELDVALUE FIELDVALUE FIELDVALUE FIELDVALUE
------ ---------- --------- ---------- ---------- ---------- ----------
     1 HEADER               AGE        GENDER     SINGLE     WEIGHT
     2 DATA            1001 44                               200
     3 DATA            1002 45         FEMALE     YES

Answer 2

Возможно, что-то вроде этого:

select p.name, age.CFFieldValue, weight.CFFieldValue
from person p
inner join CUSTOMFIELDVALUE age
 on p.id = age.CFFieldName
inner join CUSTOMFIELDS age_f
 on age_f.cfid = age.cfid and age_f.CFFieldName = 'AGE' and age_f.CFTable = 'PERSON'
inner join CUSTOMFIELDVALUE weight
 on p.id = weight.CFFieldName and weight_f.CFFieldName = 'AGE' and weight_f.CFTable = 'PERSON'
inner join CUSTOMFIELDS weight_f
 on weight_f.cfid = weight.cfid;

Мне не совсем понятно, что person.id присоединяется к customfieldvalue.cfieldname, но вы говорите 100 - 100 - 1001 - 44, так что я думаю, вы пытаетесьскажи 1001 это третий столбец?По сути, запрос фильтрует таблицу customfieldvalues ​​и использует ее как две отдельные таблицы.То, что я думаю, то, что вы хотите - ваш вопрос не очень ясно дает понять.