Уважает ли Spark List интерфейсы IDropInItemRenderer? - PullRequest
Новая
       4

Уважает ли Spark List интерфейсы IDropInItemRenderer?

1 голос
/ 31 декабря 2010

Похоже, что новый компонент списка искры не поддерживает интерфейс IDropInItemRenderer.

Т.е. - если я реализую IDropInItemRenderer на моем рендере, установщик listData никогда не вызывается.

Я что-то упустил или этот интерфейс устарел?

Если так, каков предлагаемый подход для предоставления подобной контекстной информации dataProvider для средства визуализации?

Например, я хочу, чтобы средство рендеринга для последнего элемента в коллекции немного отличалось.

Я вижу, что IItemRenderer теперь определяет свойство listIndex, однако этот подход не работает без знания счетчика источника dataProvider.

Ответы [ 2 ]

1 голос
/ 31 декабря 2010

Вот обходной путь, который я в итоге использовал.

По-своему, DataGroup истощает композиционное совершенство Spark в том смысле, что предоставляет свойство rendererUpdateDelegate, которое вы можете установить с помощью своего собственного класса, чтобы обеспечить любую пользовательскую функцию, к которой вы стремитесь.

Несмотря на разочарование, что интерфейс был утерян без рекламы, этот подход гораздо более эффективен.

Вот пример класса. В моем примере я хочу, чтобы у последнего средства визуализации было установлено свойство collapsable равное false: 

/**
 * Decorates another IItemRendererOwner (eg., a DataGroup) and augments the updateRenderer method
 * to set the isCollapsable property */
public class ThreadMessageRendererUpdateDelegate implements IItemRendererOwner
{
    private var _dataGroup:DataGroup;

    public function get dataGroup():DataGroup
    {
        return _dataGroup;
    }

    public function set dataGroup(value:DataGroup):void
    {
        _dataGroup = value;
        if (dataGroup)
        {
            dataGroup.rendererUpdateDelegate = this;
        }
    }


    public var dataProvider:ArrayCollection;

    public function ThreadMessageRendererUpdateDelegate(owner:DataGroup=null)
    {
        this.dataGroup = owner;
    }

    public function itemToLabel(item:Object):String
    {
        return dataGroup.itemToLabel(item);
    }

    public function updateRenderer(renderer:IVisualElement, itemIndex:int, data:Object):void
    {
        dataGroup.updateRenderer(renderer,itemIndex,data);
        if (renderer is ThreadMessageRenderer)
        {
            ThreadMessageRenderer(renderer).collapsable = itemIndex < dataProvider.length - 1;
        }
    }
}

А вот пример использования: 

<fx:Declarations>
    <viewer:ThreadMessageRendererUpdateDelegate dataProvider="{dataProvider}" dataGroup="{threadList}" />
</fx:Declarations>
<fx:Script>
    <![CDATA[
        [Bindable]
        public var dataProvider:ArrayCollection
    ]]>
</fx:Script>
    <s:DataGroup height="100%"
                 width="100%"
                 dataProvider="{dataProvider}"
                 itemRenderer="ThreadMessageRenderer"
                 id="threadList"
                 >
    </s:DataGroup>
0 голосов
/ 28 июня 2012

Человек!Просто потратил целую вечность, пытаясь найти DataGroup.rendererUpdateDelegate(...), в конце концов, обнаружив, почему я не смог, благодаря этому посту ТАК.Я понимаю, что ни один из них не является действительно необходимым.

DataGroup имеет событие rendererAdd, которое дает вам достаточно информации в нужное время, чтобы сделать то, что вы хотите;например: 

...

<s:DataGroup id="dg"
    dataProvider="{model.dataProvider}"
    itemRenderer="{model.itemRendererFactory}"
    rendererAdd="model.updateRenderer(event.data, event.index, event.renderer)">

...

... а в model мы имеем: 

public function updateRenderer(data:Object, index:int, renderer:IVisualElement):void
{
    if (renderer is ICollapsable)
    {
        ICollapsable(renderer).collapse = index < dataProvider.length - 1;
    }
}

Меньше строк кода и более ясное намерение

...