сохранить и загрузить значение из реестра в vb.net

Question

У меня есть приложение, в котором пользователь выбирает конфигурацию, мне нужно написать в первую функцию, чтобы сохранить конфигурацию, когда приложение закрыто, и другое загрузить конфигурацию, когда приложение загружено, мне нужно использовать реестр, если бы вы могли помочь мне, дав мне 2 небольших примера, как сохранить и загрузить из реестра. благодарю вас Jp

Answer 1

Класс «Мой» в VB содержит почти все, что вам нужно. Для чтения данных:

My.Computer.Registry.LocalMachine.GetValue("mykey")

Для записи данных:

My.Computer.Registry.LocalMachine.SetValue("mykey", "myvalue")

Надеюсь, это поможет.

Answer 2

Посмотрите на Класс реестра .КЛЮЧИ, предоставляемые этим классом:

• CurrentUser - хранит информацию о пользовательских настройках.
• LocalMachine - хранит информацию о конфигурации для локального компьютера.
• ClassesRoot - хранит информацию о типах (и классах) и их свойствах.
• Users - хранит информацию о конфигурации пользователя по умолчанию.
• PerformanceData - хранит информацию о производительности для компонентов программного обеспечения..
• CurrentConfig - хранит не зависящую от пользователя информацию об оборудовании.

Важно понимать использование этих ключей, чтобы информация могла быть сохранена для конкретных пользовательских экземпляров или компьютера.

Я не был уверен, какую версию .NET Framework вы используете.

Пример данных из MS

Imports Microsoft.VisualBasic
Imports System
Imports System.Security.Permissions
Imports Microsoft.Win32

Public Class RegKey
    Shared Sub Main()

        ' Create a subkey named Test9999 under HKEY_CURRENT_USER.
        Dim test9999 As RegistryKey = _
            Registry.CurrentUser.CreateSubKey("Test9999")

        ' Create two subkeys under HKEY_CURRENT_USER\Test9999.
        test9999.CreateSubKey("TestName").Close()
        Dim testSettings As RegistryKey = _
            test9999.CreateSubKey("TestSettings")

        ' Create data for the TestSettings subkey.
        testSettings.SetValue("Language", "French")
        testSettings.SetValue("Level", "Intermediate")
        testSettings.SetValue("ID", 123)
        testSettings.Close()

        ' Print the information from the Test9999 subkey.
        Console.WriteLine("There are {0} subkeys under Test9999.", _
            test9999.SubKeyCount.ToString())
        For Each subKeyName As String In test9999.GetSubKeyNames()
            Dim tempKey As RegistryKey = _
                test9999.OpenSubKey(subKeyName)
            Console.WriteLine(vbCrLf & "There are {0} values for " & _
                "{1}.", tempKey.ValueCount.ToString(), tempKey.Name)
            For Each valueName As String In tempKey.GetValueNames()
                Console.WriteLine("{0,-8}: {1}", valueName, _
                    tempKey.GetValue(valueName).ToString())
            Next
        Next

        ' Delete the ID value.
        testSettings = test9999.OpenSubKey("TestSettings", True)
        testSettings.DeleteValue("id")

        ' Verify the deletion.
        Console.WriteLine(CType(testSettings.GetValue( _
            "id", "ID not found."), String))
        testSettings.Close()

        ' Delete or close the new subkey.
        Console.Write(vbCrLf & "Delete newly created " & _
            "registry key? (Y/N) ")
        If Char.ToUpper(Convert.ToChar(Console.Read())) = "Y"C Then
            Registry.CurrentUser.DeleteSubKeyTree("Test9999")
            Console.WriteLine(vbCrLf & "Registry key {0} deleted.", _
                test9999.Name)
        Else
            Console.WriteLine(vbCrLf & "Registry key {0} closed.", _
                test9999.ToString())
            test9999.Close()
        End If

    End Sub
End Class