Как найти позицию подстроки в строке с нечетким соответствием - PullRequest
Новая
       3

Как найти позицию подстроки в строке с нечетким соответствием

8 голосов
/ 07 декабря 2010

Я столкнулся с проблемой сопоставления строки в тексте, распознаваемом OCR, и нашел ее положение, учитывая, что может быть произвольный допуск неправильных, отсутствующих или дополнительных символов. Результатом должна быть позиция наилучшего совпадения, возможно (не обязательно) с длиной совпадающей подстроки.

Например: 

String: 9912, 1.What is your name?
Substring: 1. What is your name?
Tolerance: 1
Result: match on character 7

String: Where is our caat if any?
Substring: your cat
Tolerance: 2
Result: match on character 10

String: Tolerance is t0o h1gh.
Substring: Tolerance is too high;
Tolerance: 1
Result: no match

Я попытался адаптировать алгоритм Левенштейна, но он не работает должным образом для подстрок и не возвращает позицию.

Алгоритм в Delphi предпочтительнее, но подойдет любая реализация или псевд логика.

1 Ответ

8 голосов
/ 07 декабря 2010

Вот рекурсивная реализация, которая работает, но может быть недостаточно быстрой. В худшем случае, когда совпадение не может быть найдено, и все, кроме последнего символа в «Что», сопоставляются с каждым индексом в Where. В этом случае алгоритм выполнит сравнение длины (What) -1 + допусков для каждого символа в Where, плюс один рекурсивный вызов на допуск. Поскольку и допуск, и длина значений являются постоянными, я бы сказал, что алгоритм равен O (n). Его производительность будет линейно снижаться с длиной «что» и «где». 

function BrouteFindFirst(What, Where:string; Tolerance:Integer; out AtIndex, OfLength:Integer):Boolean;
  var i:Integer;
      aLen:Integer;
      WhatLen, WhereLen:Integer;

    function BrouteCompare(wherePos, whatPos, Tolerance:Integer; out Len:Integer):Boolean;
    var aLen:Integer;
        aRecursiveLen:Integer;
    begin
      // Skip perfect match characters
      aLen := 0;
      while (whatPos <= WhatLen) and (wherePos <= WhereLen) and (What[whatPos] = Where[wherePos]) do
      begin
        Inc(aLen);
        Inc(wherePos);
        Inc(whatPos);
      end;
      // Did we find a match?
      if (whatPos > WhatLen) then
        begin
          Result := True;
          Len := aLen;
        end
      else if Tolerance = 0 then
        Result := False // No match and no more "wild cards"
      else
        begin
          // We'll make an recursive call to BrouteCompare, allowing for some tolerance in the string
          // matching algorithm.
          Dec(Tolerance); // use up one "wildcard"
          Inc(whatPos); // consider the current char matched
          if BrouteCompare(wherePos, whatPos, Tolerance, aRecursiveLen) then
            begin
              Len := aLen + aRecursiveLen;
              Result := True;
            end
          else if BrouteCompare(wherePos + 1, whatPos, Tolerance, aRecursiveLen) then
            begin
              Len := aLen + aRecursiveLen;
              Result := True;
            end
          else
            Result := False; // no luck!
        end;
    end;

  begin

    WhatLen := Length(What);
    WhereLen := Length(Where);

    for i:=1 to Length(Where) do
    begin
      if BrouteCompare(i, 1, Tolerance, aLen) then
      begin
        AtIndex := i;
        OfLength := aLen;
        Result := True;
        Exit;
      end;
    end;

    // No match found!
    Result := False;

  end;

Я использовал следующий код для проверки функции: 

procedure TForm18.Button1Click(Sender: TObject);
var AtIndex, OfLength:Integer;
begin
  if BrouteFindFirst(Edit2.Text, Edit1.Text, ComboBox1.ItemIndex, AtIndex, OfLength) then
    Label3.Caption := 'Found @' + IntToStr(AtIndex) + ', of length ' + IntToStr(OfLength)
  else
    Label3.Caption := 'Not found';
end;

Для случая: 

String: Where is our caat if any?
Substring: your cat
Tolerance: 2
Result: match on character 10

показывает совпадение с символом 9 длины 6. Для двух других примеров это дает ожидаемый результат.

...