Как выделить ячейки таблицы после проверки условия с помощью функции javascript, значения которой передаются XSLT - PullRequest
Новая
       4

Как выделить ячейки таблицы после проверки условия с помощью функции javascript, значения которой передаются XSLT

1 голос
/ 13 августа 2010

Я новичок в JAVASCRIPT и хочу выделить строку таблицы, если значения не совпадают по всей строке, зная, что я использую цикл для извлечения значений из файла XML с использованием XSLT.Как я могу это сделать? 

    <xsl:for-each select="./projects/project">
        <td>
            <xsl:value-of select="weight"/>
             <xsl:variablename="compare"select="weight"/>                       
        </td>
  </xsl:for-each>

Я хочу сохранить переменные "сравнить" в массиве .. затем перебрать его и проверить, все ли значения равны, в противном случае мне нужно использовать JavaScript, чтобы выделитьстрока.Этот код не включает в себя JavaScript, я просто не знаю, как включить в XSLT.

Спасибо

Ответы [ 2 ]

0 голосов
/ 13 августа 2010

Эта таблица стилей: 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml"/>
    <xsl:template match="numbers">
        <html>
            <head>
                <style>.all-equal {background-color:yellow;}</style>
            </head>
            <body>
                <table>
                    <thead>
                        <tr>
                            <th>Value</th>
                        </tr>
                    </thead>
                    <tbody>
                        <xsl:apply-templates>
                            <xsl:with-param name="all-equal"
                            select="not(number[1] != number[position()!=1])"/>
                        </xsl:apply-templates>
                    </tbody>
                </table>
            </body>
        </html>
    </xsl:template>
    <xsl:template match="number">
        <xsl:param name="all-equal"/>
        <tr>
            <td>
                <xsl:if test="$all-equal">
                    <xsl:attribute name="class">all-equal</xsl:attribute>
                </xsl:if>
                <xsl:value-of select="."/>
            </td>
        </tr>
    </xsl:template>
</xsl:stylesheet>

С этим входом: 

<numbers>
  <number>20</number>
  <number>20</number>
  <number>20</number>
</numbers>

Выход: 

<html>
    <head>
        <style>.all-equal {background-color:yellow;}</style>
    </head>
    <body>
        <table>
            <thead>
                <tr>
                    <th>Value</th>
                </tr>
            </thead>
            <tbody>
                <tr>
                    <td class="all-equal">20</td>
                </tr>
                <tr>
                    <td class="all-equal">20</td>
                </tr>
                <tr>
                    <td class="all-equal">20</td>
                </tr>
            </tbody>
        </table>
    </body>
</html>
0 голосов
/ 13 августа 2010

Вот существующий пример совместного использования XSLT и Javascript .

Это преобразование создает HTML-страницу с javascript, в которой нажатие на цифровую кнопку создает квадрат этого числа: 

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
     version="1.0">
<!-- squareAsHTMLJS1.xml: create an HTML document with JavaScript that
     interactively computes the square of each "number" element read from 
     the source tree. -->

  <xsl:template match="/"> <!-- Set up web page -->
    <html>
      <head>
        <title>Squares</title>
         <script language="JavaScript1.2">
           function showSquare(n) {
            alert("the square is " + n*n);
           }
        </script>
        <style> <!-- Put a little CSS in -->
           body { font-family: arial,helvetica; }
           h1   { font-size: 14pt }
           p    { font-size: 10pt}
        </style>
      </head>
      <body>
        <h1>Squares</h1>
        <p>Click a button to see the square of that number.</p>
        <form>
        <xsl:apply-templates/>
        </form>
      </body>
    </html>
  </xsl:template>

  <xsl:template match="number">
    <p><input type="button" value=" {.} " onClick="showSquare({.})"/></p>
  </xsl:template>

</xsl:stylesheet>

, когда это преобразование применяется к этому документу XML: 

<numbers>
  <number>2</number>
  <number>11</number>
  <number>100</number>  
  <number>-5</number>
</numbers>

результат : 

<html>
   <head>
      <meta http-equiv="Content-Type" content="text/html; charset=utf-8">

      <title>Squares</title><script language="JavaScript1.2">
           function showSquare(n) {
            alert("the square is " + n*n);
           }
        </script><style> 
           body { font-family: arial,helvetica; }
           h1   { font-size: 14pt }
           p    { font-size: 10pt}
        </style></head>
   <body>
      <h1>Squares</h1>
      <p>Click a button to see the square of that number.</p>
      <form>

         <p><input type="button" value=" 2 " onClick="showSquare(2)"></p>

         <p><input type="button" value=" 11 " onClick="showSquare(11)"></p>

         <p><input type="button" value=" 100 " onClick="showSquare(100)"></p>

         <p><input type="button" value=" -5 " onClick="showSquare(-5)"></p>

      </form>
   </body>
</html>

Вы можете поиграть с этим здесь: http://www.snee.com/xml/trxml33/numbersJS1.xml

И смотрите больше объяснений автора здесь: http://www.xml.com/pub/a/2003/02/05/tr.html

Добро пожаловать на сайт PullRequest, где вы можете задавать вопросы и получать ответы от других членов сообщества.

Нет похожих вопросов

...