Как мне написать предикат, который проверяет, существует ли значение в бесконечной последовательности? - PullRequest
Новая
       22

Как мне написать предикат, который проверяет, существует ли значение в бесконечной последовательности?

4 голосов
/ 19 июля 2010

Сегодня у меня была идея для функции высшего порядка, которую я не знаю, как написать.У меня есть несколько редких, ленивых бесконечных последовательностей, и я хочу создать абстракцию, которая позволяет мне проверять, находится ли данное число в любой из этих ленивых последовательностей.Чтобы повысить производительность, я хотел поместить значения разреженной последовательности в хэш-карту (или установить), динамически увеличивая количество значений в хеш-карте всякий раз, когда это необходимо.Автоматическое запоминание не является ответом здесь из-за редкости ленивых последовательностей.

Вероятно, код легче понять, так что вот что я имею до сих пор.Как изменить следующий код, чтобы предикат использовал закрытую хэш-карту, но при необходимости увеличивает размер хэш-карты и переопределяет себя, чтобы использовать новую хэш-карту? 

(defn make-lazy-predicate [coll]
  "Returns a predicate that returns true or false if a number is in
  coll. Coll must be an ordered, increasing lazy seq of numbers."
  (let [in-lazy-list? (fn [n coll top cache]
                        (if (> top n)
                          (not (nil? (cache n)))
                          (recur n (next coll) (first coll) 
                                 (conj cache (first coll)))]
    (fn [n] (in-lazy-list? n coll (first coll) (sorted-set)))))

(def my-lazy-list (iterate #(+ % 100) 1))

(let [in-my-list? (make-lazy-predicate my-lazy-list)]
  (doall (filter in-my-list? (range 10000))))

Как мне решить эту проблемупроблема, не возвращаясь к императивному стилю?

Ответы [ 2 ]

2 голосов
/ 19 июля 2010

Это поточно-ориентированный вариант решения Адама. 

(defn make-lazy-predicate
  [coll]
  (let [state        (atom {:mem #{} :unknown coll})
        update-state (fn [{:keys [mem unknown] :as state} item]
                       (let [[just-checked remainder]
                             (split-with #(<= % item) unknown)]
                         (if (seq just-checked)
                           (-> state
                             (assoc :mem (apply conj mem just-checked))
                             (assoc :unknown remainder))
                           state)))]
    (fn [item]
      (get-in (if (< item (first (:unknown @state)))
                @state
                (swap! state update-state item))
              [:mem item]))))

Можно также рассмотреть возможность использования ссылок, но тогда поиск по предикату может быть откатан в результате транзакции, в которую он включен.Это может или не может быть то, что вы хотите.

1 голос
/ 19 июля 2010

Эта функция основана на идее, как работает основная функция памятки.Только числа, уже использованные из ленивого списка, кэшируются в наборе.Он использует встроенный прием вместо выполнения поиска вручную. 

(defn make-lazy-predicate [coll]
  (let [mem (atom #{})
        unknown (atom coll)]
    (fn [item]
      (if (< item (first @unknown))
        (@mem item)
        (let [just-checked (take-while #(>= item %) @unknown)]
          (swap! mem #(apply conj % just-checked))
          (swap! unknown #(drop (count just-checked) %))
          (= item (last just-checked)))))))
...