нажмите на цветную кнопку и напишите в текстовой области с этим цветным шрифтом - PullRequest
Новая
       19

нажмите на цветную кнопку и напишите в текстовой области с этим цветным шрифтом

1 голос
/ 07 октября 2010

Я хочу сделать следующее: 

* click a "red" button
* write in textarea with red color font
* click "blue" button
* write in textarea with blue color font

Разве это не возможно в flash 10 с использованием AS3 ??????

Я попытался использовать setTextFormat, но проблемаЯ должен иметь текст, прежде чем вставлять в него формат.

Это то, что я хочу: 

* start writing in textarea with WHITE COLOR (eg: "abc")
* click BLUE COLOR BUTTON
* start writing in textarea with BLUE COLOR (eg: "abcdef" - abc in white and def in blue)
* click RED COLOR BUTTON
* start writing in textarea with RED COLOR (eg: "abcdefxyz" - abc in white and def in blue and xyz in red)

Пожалуйста, кто-нибудь подскажите, как это сделать?

Ответы [ 2 ]

1 голос
/ 07 октября 2010

В документации говорится, что если вы хотите изменить формат текста перед тем, как что-либо писать в текстовое поле, назначьте новый defaultTextFormat. в противном случае установка нового формата изменит текущий выбор.

Решение, приведенное ниже, работает, сохраняя фокус на текстовом поле, поэтому при нажатии кнопок текстовое поле остается в фокусе. если есть текущий выбор, выбор изменится на синий или красный, в зависимости от того, какая кнопка нажата. если выбора нет, применяется новый defaultTextFormat без изменения предыдущих defaultTextFormats, так как текстовое поле все еще имело фокус при применении нового формата. 

package
{   
import flash.display.Sprite;
import flash.events.Event;
import flash.text.TextField;
import flash.text.TextFieldType;
import flash.text.TextFormat;
import flash.events.MouseEvent;
import flash.events.FocusEvent;

public class ChangeTextColor extends Sprite
{
private var field:TextField;
private var redButton:Sprite;
private var blueButton:Sprite;

public function ChangeTextColor()
    {
    init();
    }

//Initialize
private function init():void
    {
    //Create Text Field
    field = new TextField();
    field.type = TextFieldType.INPUT;
    field.border = true;
    field.x = field.y = 10;
    addChild(field);

    //Retain Focus On TextField
    field.addEventListener(FocusEvent.FOCUS_OUT, fieldFocusOutHandler);

    //Create Button
    redButton = createButton(10, 120, 200, 20, 0xFF0000);
    blueButton = createButton(10, 150, 200, 20, 0x0000FF);
    }

//Create Button Method
private function createButton(x:uint, y:uint, width:uint, height:uint, color:uint):Sprite
    {
    var resultSprite:Sprite = new Sprite();

    resultSprite.graphics.beginFill(color);
    resultSprite.graphics.drawRect(0, 0, width, height);
    resultSprite.graphics.endFill();

    resultSprite.addEventListener(MouseEvent.CLICK, mouseClickEventHandler);

    resultSprite.x = x;
    resultSprite.y = y;
    addChild(resultSprite);

    return resultSprite;
    }

//Apply Text Format
private function changeTextFormatColor(color:uint):void
    {
    var format:TextFormat = new TextFormat();
    format.color = color;

    //Change Format Of Selection Or Set Default Format
    if  (field.selectionBeginIndex != field.selectionEndIndex)
        field.setTextFormat(format, field.selectionBeginIndex, field.selectionEndIndex);
        else
        field.defaultTextFormat = format;
    }

//Maintain Focus Of TextField When Color buttons Are Clicked
private function fieldFocusOutHandler(evt:FocusEvent):void
    {
    stage.focus = evt.currentTarget as TextField;
    }

//Button Click Event Handler
private function mouseClickEventHandler(evt:MouseEvent):void
    {
    switch  (evt.currentTarget)
            {
            case redButton:     trace("red clicked");
                                changeTextFormatColor(0xFF0000);
                                break;

            case blueButton:    trace("blue clicked");
                                changeTextFormatColor(0x0000FF);
            }
    }
}
}

в качестве альтернативы, если в вашей программе есть другие кнопки, которые не относятся к текстовому полю и должны заставить текстовое поле терять фокус при нажатии, просто удалите функцию fieldFocusOutHandler и поместите stage.focus = field; внутри метода buttonClickHandler. Вы также можете сохранить и адаптировать функцию fieldFocusOutHandler, если это является проблемой.

0 голосов
/ 11 октября 2010

Вот решение для тех, кто смотрит по сторонам (спасибо тем, кто решил мою проблему)

Используйте следующее в changehandler текстового поля: 

textfield.setTextFormat(default_format, textfield.caretIndex-1, textfield.caretIndex);

Используйте следующее в clickhandler кнопки: 

default_format.color = getColor("red");
    stage.focus = textfield;

С уважением

...