Копирование частей tdbgrid в буфер обмена? - PullRequest
Новая
       24

Копирование частей tdbgrid в буфер обмена?

2 голосов
/ 29 декабря 2008

Есть ли способ легко скопировать выделенную строку из TDBGrid в Delphi 2007 в буфер обмена?

1 Ответ

5 голосов
/ 29 декабря 2008

Этот метод взят из нашего внутреннего библиотечного блока. 

procedure BuildListFromDBGrid(DBGrid: TDBGrid; const FieldName: String; Strings :TStrings);
var
  i: Integer;
begin
  Strings.Clear();
  with DBGrid do
     begin
        Strings.BeginUpdate(); // If assocated with a UI control (Listbox, etc), this will prevent any flickering
        DataSource.DataSet.DisableControls();
        try
          for i := 0 to (SelectedRows.Count - 1) do
             begin
               Datasource.DataSet.GotoBookmark(Pointer(SelectedRows[i]));
               Strings.Add(DataSource.DataSet.FieldByName(FieldName).AsString);
             end;
        finally
           DataSource.DataSet.EnableControls();
           Strings.EndUpdate();
        end;
     end;
end;

Чтобы получить список выбранных элементов в буфер обмена, добавьте Clipbrd в ваше предложение использования и вызовите процедуру. 

var
  SelectedItems :TStringList;
begin
  SelectedItems := TStringList.Create();
  try
    BuildListFromDBGrid(MyDBGrid, 'InvoiceID', SelectedItems);
    Clipboard.AsText := SelectedItems.Text;
  finally
    SelectedItems.Free();
  end;
end;

Конечно, вы можете изменить вышеуказанный метод или создать новый, который напрямую добавляет выбранные элементы в буфер обмена (например, несколько полей, в специализированном формате и т. Д.)

...