замена атрибута xml на xslt

Question

Как заменить атрибут в xml с помощью преобразования xsl, в зависимости от его значения. Например, если есть такой xml

<Text Style='style1'>
...
</Text>

преобразовать его в

<Text Font='Arial' Bold='true' Color='Red'>
...
</Text>

Для Style = 'style2' установить другие атрибуты и значения, например Font = 'Sans' Italic = 'true'.

Answer 1

Один из возможных способов: использование наборов атрибутов.Эта таблица стилей:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes"/>
    <xsl:attribute-set name="style1">
        <xsl:attribute name="Font">Arial</xsl:attribute>
        <xsl:attribute name="Bold">true</xsl:attribute>
        <xsl:attribute name="Color">Red</xsl:attribute>
    </xsl:attribute-set>
    <xsl:attribute-set name="style2">
        <xsl:attribute name="Font">Sans</xsl:attribute>
        <xsl:attribute name="Italic">true</xsl:attribute>
    </xsl:attribute-set>
    <xsl:template match="Text[@Style='style1']">
        <xsl:copy use-attribute-sets="style1">
            <xsl:copy-of select="@*[name()!='Style']"/>
            <xsl:apply-templates/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="Text[@Style='style2']">
        <xsl:copy use-attribute-sets="style2">
            <xsl:copy-of select="@*[name()!='Style']"/>
            <xsl:apply-templates/>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

С этим входом:

<root>
    <Text Style='style1'></Text>
    <Text Style='style2'></Text>
</root>

Выход:

<Text Font="Arial" Bold="true" Color="Red"></Text>
<Text Font="Sans" Italic="true"></Text>

Другой способ: встроенные "наборы атрибутов".Эта таблица стилей:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:my="my"
 exclude-result-prefixes="my">
    <xsl:output indent="yes"/>
    <my:style1 Font="Arial" Bold="true" Color="Red"/>
    <my:style2 Font="Sans" Italic="true"/>
    <xsl:template match="Text[@Style]">
        <xsl:copy>
            <xsl:copy-of select="document('')/*/my:*
                                    [local-name()=current()/@Style]/@*"/>
            <xsl:copy-of select="@*[name()!='Style']"/>
            <xsl:apply-templates/>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

Answer 2

Вам понадобится какое-то правило, которое вы используете для преобразования стиля из одного в другой. Предполагая, что вы вводите HTML, вам понадобится что-то вроде.

  <xsl:template match="@* | node()">
    <xsl:choose>
      <xsl:when test="local-name() = 'Style'">
        <xsl:apply-templates select="." mode="Style" />
      </xsl:when>
      <xsl:otherwise>
        <xsl:copy>
          <xsl:apply-templates select="@* | node()"/>
        </xsl:copy>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

  <xsl:template match="@Style" mode="Style">
    <xsl:choose>
      <xsl:when test="node() = 'style1'">
        <xsl:attribute name="Font">Arial</xsl:attribute>
        <xsl:attribute name="Bold">true</xsl:attribute>
        <xsl:attribute name="Color">Red</xsl:attribute>
      </xsl:when>
      <xsl:when test="node() = 'style2'">
        <xsl:attribute name="Font">Sans</xsl:attribute>
        <xsl:attribute name="Bold">true</xsl:attribute>
      </xsl:when>
    </xsl:choose>
  </xsl:template>