объединить python-mode с org-mode для emacs

Question

Я объединил org-режим с lisp-режимом, чтобы добиться прекрасного сворачивания кода в emacs для lisp-кода: lisp-orgi-mode . По сути, я использую ';' вместо '*' в качестве заголовка. Для комментариев я просто ставлю пробел перед ';', делая это ';' так что это не считается заголовком ...

Однако, делать то же самое с python-mode не работает ... Возможно, потому что символ '#', используемый комментариями python, мешает настройкам режима org ...

Кто-нибудь смог успешно совместить функциональность? Я знаю, что люди комбинировали режим Python с режимом структуры ( ссылка ), но режим Outline не так хорош, как режим Org ...

Редактировать: Хорошо работает с outline-magic : python-magic.el

Answer 1

Я использую hideshow-org ( и небольшое введение здесь ) для этой цели, и я думаю, что это работает действительно очень хорошо.

Вот некоторые дополнительные, но полезные фрагменты:

(dolist (hook (list 'c-mode-common-hook
            'emacs-lisp-mode-hook
            'java-mode-hook
            'lisp-mode-hook
            'perl-mode-hook
            'sh-mode-hook))
  (add-hook hook 'my-hideshow-hook))

(defun my-hideshow-hook ()
  "thisandthat."
  (interactive)
  (progn (require 'hideshow-org)
     (global-set-key (kbd "C-c h") 'hs-org/minor-mode)
     (hs-org/minor-mode)))

(defadvice goto-line (after expand-after-goto-line activate compile)
  "hideshow-expand affected block when using goto-line in a collapsed buffer"
  (save-excursion
    (hs-show-block)))

Answer 2

Хорошо, у меня есть режим outline-minor-mode, хорошо работающий со следующим outline-regexp: "[\ t] * # \ | [\ t] + \ (class \ | def \ | if \ | elif \ | else \ | while \ | for \ | try \ | кроме \ | with \) " Теперь я получаю свертывание кода, используя как синтаксис python, так и строки комментариев в качестве заголовков.
Можно ли было бы адаптировать ваш код для использования табуляции для вызова команды «indent-for-tab-command», а если нечего делать, вызывать «контур-цикл»?

python-magic.el:

; require outline-magic.el by CarstenDominik found here: 
; http://www.astro.uva.nl/~dominik/Tools/outline-magic.el
; modified code here by Nikwin slightly found here: 
;  http://stackoverflow.com/questions/1085170/how-to-achieve-code-folding-effects-in-emacs/1085551#1085551

(add-hook 'outline-minor-mode-hook 
           (lambda () 
             (require 'outline-magic)
))
(add-hook 'python-mode-hook 'my-python-outline-hook)

(defun py-outline-level ()
  (let (buffer-invisibility-spec)
    (save-excursion
      (skip-chars-forward "    ")
      (current-column))))

(defun my-python-outline-hook ()
  (setq outline-regexp "[ \t]*# \\|[ \t]+\\(class\\|def\\|if\\|elif\\|else\\|while\\|for\\|try\\|except\\|with\\) ")
  (setq outline-level 'py-outline-level)

  (outline-minor-mode t)
  (hide-body)
  (show-paren-mode 1)
  (define-key python-mode-map [tab] 'outline-cycle)
  (define-key outline-minor-mode-map [S-tab] 'indent-for-tab-command)
  (define-key outline-minor-mode-map [M-down] 'outline-move-subtree-down)
  (define-key outline-minor-mode-map [M-up] 'outline-move-subtree-up)
)
(provide 'python-magic)

Answer 3

Я думаю, outline-magic был заменен на outshine, и я не знаю, работает ли с ним приведенный выше код.Но я смог заставить работать следующий код, благодаря сообщению в блоге Райана Дэвиса :

(defun python-mode-outline-hook ()
  (setq outline-level 'python-outline-level)

  (setq outline-regexp
    (rx (or
         ;; Commented outline heading
         (group
          (* space)  ; 0 or more spaces
          (one-or-more (syntax comment-start))
          (one-or-more space)
          ;; Heading level
          (group (repeat 1 8 "\*"))  ; Outline stars
          (one-or-more space))

         ;; Python keyword heading
         (group
          ;; Heading level
          (group (* space)) ; 0 or more spaces
          bow
          ;; Keywords
          (or "class" "def" "else" "elif" "except" "for" "if" "try" "while")
          eow)))))

(defun python-outline-level ()
  (or
   ;; Commented outline heading
   (and (string-match (rx
               (* space)
               (one-or-more (syntax comment-start))
               (one-or-more space)
               (group (one-or-more "\*"))
               (one-or-more space))
              (match-string 0))
    (- (match-end 0) (match-beginning 0)))

   ;; Python keyword heading, set by number of indentions
   ;; Add 8 (the highest standard outline level) to every Python keyword heading
   (+ 8 (- (match-end 0) (match-beginning 0)))))

(add-hook 'python-mode-hook 'python-mode-outline-hook)

Возможно, кто-то найдет это полезным.Я думаю, что это удивительный способ облегчить редактирование и навигацию по коду.