Apache FOP: многостраничный PDF из итерации списка массивов xml - PullRequest
Новая
       15

Apache FOP: многостраничный PDF из итерации списка массивов xml

1 голос
/ 07 декабря 2010

У меня есть XML-документ, который содержит массив / список сложных элементов. Я хотел бы создать файл PDF таким образом, чтобы каждый сложный элемент отображался на новой странице. У меня это работает на одной странице. Мой пример XML выглядит так: 

<root> <list><x><1>10</1><2>20</2></x> <x><1>11</1><2>22</2></x> <x><1>13</1><2>23</2></x></list> </root>

Я пробовал следующее вокруг 

<xsl:for-each select="list/x">
<fo:page-sequence master-reference="my-page" initial-page-number="auto" format="1">
 <fo:flow flow-name="xsl-region-body">
 <fo:block> 
         ... my fo:table etc here
      </fo:block>
      <fo:block id="SV_RefID_PageTotal" />
</fo:page-sequence>
</xsl:for-each>

Я получаю ошибки проверки. Что я делаю неправильно? Есть ли лучший способ сделать это? Спасибо

1 Ответ

0 голосов
/ 08 декабря 2010

Поскольку они еще не были опубликованы, я предполагаю, что ваши ошибки связаны с тем, что ваш XML плохо сформирован.Имена элементов не могут начинаться с цифры.(См. «Правила именования XML» в Элементы XML )

Я также сделал быструю таблицу стилей XSL, которая сгенерирует действительный XSL-FO.Это, вероятно, не то, что вы хотите, но, может быть, вы можете использовать кусок или два из него?

Измененный образец XML 

<?xml version="1.0" encoding="UTF-8"?>
<root>
  <list>
    <x>
      <c1>10</c1>
      <c2>20</c2>
    </x>
    <x>
      <c1>11</c1>
      <c2>22</c2>
    </x>
    <x>
      <c1>13</c1>
      <c2>23</c2>
    </x>
  </list>
</root>

Таблица стилей XSL 

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format">
  <xsl:output indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="node()|@*">
    <xsl:choose>
      <xsl:when test="name() = 'root'">
        <xsl:apply-templates/>
      </xsl:when>
      <xsl:otherwise>
        <xsl:copy>
          <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>        
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

  <xsl:template match="list">
    <fo:root xmlns:fo="http://www.w3.org/1999/XSL/Format">
      <fo:layout-master-set>
        <fo:simple-page-master master-name="my-page">
          <fo:region-body/>
        </fo:simple-page-master>
      </fo:layout-master-set>
      <xsl:apply-templates/>
    </fo:root>
  </xsl:template>

  <xsl:template match="x">
    <fo:page-sequence master-reference="my-page" initial-page-number="auto" format="1">
      <fo:flow flow-name="xsl-region-body">
        <fo:table>
          <fo:table-body>
            <fo:table-row>
              <xsl:apply-templates/>
            </fo:table-row>
          </fo:table-body>
        </fo:table>
      </fo:flow>
    </fo:page-sequence>
  </xsl:template>

  <xsl:template match="c1|c2">
    <fo:table-cell>
      <fo:block>
        <xsl:apply-templates/>
      </fo:block>
    </fo:table-cell>
  </xsl:template>

</xsl:stylesheet>

XSL-FO 

<?xml version="1.0" encoding="UTF-8"?>
<fo:root xmlns:fo="http://www.w3.org/1999/XSL/Format">
   <fo:layout-master-set>
      <fo:simple-page-master master-name="my-page">
         <fo:region-body/>
      </fo:simple-page-master>
   </fo:layout-master-set>
   <fo:page-sequence master-reference="my-page" initial-page-number="auto" format="1">
      <fo:flow flow-name="xsl-region-body">
         <fo:table>
            <fo:table-body>
               <fo:table-row>
                  <fo:table-cell>
                     <fo:block>10</fo:block>
                  </fo:table-cell>
                  <fo:table-cell>
                     <fo:block>20</fo:block>
                  </fo:table-cell>
               </fo:table-row>
            </fo:table-body>
         </fo:table>
      </fo:flow>
   </fo:page-sequence>
   <fo:page-sequence master-reference="my-page" initial-page-number="auto" format="1">
      <fo:flow flow-name="xsl-region-body">
         <fo:table>
            <fo:table-body>
               <fo:table-row>
                  <fo:table-cell>
                     <fo:block>11</fo:block>
                  </fo:table-cell>
                  <fo:table-cell>
                     <fo:block>22</fo:block>
                  </fo:table-cell>
               </fo:table-row>
            </fo:table-body>
         </fo:table>
      </fo:flow>
   </fo:page-sequence>
   <fo:page-sequence master-reference="my-page" initial-page-number="auto" format="1">
      <fo:flow flow-name="xsl-region-body">
         <fo:table>
            <fo:table-body>
               <fo:table-row>
                  <fo:table-cell>
                     <fo:block>13</fo:block>
                  </fo:table-cell>
                  <fo:table-cell>
                     <fo:block>23</fo:block>
                  </fo:table-cell>
               </fo:table-row>
            </fo:table-body>
         </fo:table>
      </fo:flow>
   </fo:page-sequence>
</fo:root>
...