Суммируйте содержание 2 списка в Groovy

Question

У меня есть два списка в Groovy, и мне нужно суммировать содержимое обоих.

Например:

list1 = [1,1,1]
list2 = [1,1,1]

Я ожидал этого результата:

total = [2,2,2]

---

Я пытаюсь суммировать с помощью метода + оператора o .sum, но у меня есть объединение списков.

[1, 1, 1, 1, 1, 1]

Это достаточно Groovy Groovy или мне нужно зациклить каждый элемент списков?

Answer 1

Groovy's List.transpose() работает как zip на некоторых других языках. Попробуйте это:

list1 = [1,2,3]
list2 = [4,5,6]
assert [list1, list2].transpose()*.sum() == [5,7,9]

Answer 2

Я не знаю встроенного решения, но вот обходной путь, использующий collect и метод poll() Java Queue:

def list1 = [1, 2, 3]
def list2 = [4, 5, 6] as Queue

assert [5, 7, 9] == list1.collect { it + list2.poll() }

Answer 3

В большинстве функциональных языков программирования это делается с помощью функции map2 (ocaml) или zipWith (haskell), например:

let total = List.map2 (+) list1 list2;;

Я не нашел никакого эквивалента в отличной документации, но, видимо, вы легко можете определить zipWith (находится в http://cs.calstatela.edu/wiki/index.php/Courses/CS_537/Summer_2008/Chapter_4._Collective_Groovy_datatypes):

zipWith = {f, a, b -> 
 result = []
 0.upto(Math.min(a.size(), b.size())-1){index -> result << f(a[index], b[index])}
 result}

assert zipWith({x, y -> x + y}, [1, 2, 3], [4, 5, 6, 7]) ==  [5, 7, 9]

Answer 4

Prototype (JavaScript Framework) имеет метод zip(), который делает именно то, что вам нужно. Это не поможет тебе, хотя, я знаю. Забавно, я ожидал, что у Groovy будет что-то похожее, но я не смог найти ничего ни в Collection, ни в List классе.

В любом случае, вот не слишком красивая реализация zip():

List.metaClass.zip = { List other, Closure cl ->
    List result = [];
    Iterator left = delegate.iterator();
    Iterator right = other.iterator();
    while(left.hasNext()&& right.hasNext()){
        result.add(
            cl.call(left.next(), right.next())
        );
    }
    result;
}

И вот оно в действии:

def list1 = [1, 1, 1]
def list2 = [1, 1, 1]

print (list1.zip(list2) {it1, it2 -> it1 + it2})

Выход:

[2, 2, 2]

---

Конечно, вы также можете сделать это менее общим способом, если хотите точно решить свою проблему (и не реализовать универсальную функцию zip / map):

List.metaClass.addValues = { List other ->
    List result = [];
    Iterator left = delegate.iterator();
    Iterator right = other.iterator();
    while(left.hasNext()&& right.hasNext()){
        result.add(
            left.next() + right.next()
        );
    }
    result;
}

def list1 = [1, 1, 1]
def list2 = [1, 1, 1]

print (list1.addValues(list2))
// Output again: [2, 2, 2]

Answer 5

Если вы находите решение. * Sum () выше немного запутанным для чтения (очень приятно), вы также можете сделать это:

l1=[1,2,3]
l2=[4,5,6]

println([l1,l2].transpose().collect{it[0]+it[1]})

Конечно, это допускает более сложные вычисления, чем просто суммирование.