Переключение из ListView в VirtualStringTree

Question

Я пытаюсь строить свои проекты с VirtualStringTree, а не с Listview, из-за огромной разницы в скорости.Дело в том, что даже после просмотра демонстрации я просто не могу понять, как именно я использовал бы его в качестве ListView.Например, добавление, удаление и в основном просто работа с элементами ListView очень просты, но когда я смотрю на VT, он становится слишком сложным.

Все, что я ищу, это VT, который выглядит какListView, с подпунктами и т. Д.

Вот некоторые подпрограммы, использующие ListView, которые я хотел бы использовать с VT (Это просто псевдо-пример:

procedure Add;
begin
  with ListView.Items.Add do
    Begin
      Caption := EditCaption.Text;
      SubItems.Add(EditSubItem.Text):
    End;

end;

Procedure ReadItem(I : Integer);
begin

   ShowMessage(ListView.Items[I].Caption);
   ShowMessage(ListView.Items[I].SubItems[0]);

end;

Конечно, такжеУдалите функцию, но поскольку это похоже на 1 строку, я не стал беспокоиться: P

Может кто-нибудь перевести приведенные выше примеры в использование VT в стиле ListView?

Спасибо!

Answer 1

Почему вы не используете представление списка в виртуальном режиме?Это будет выглядеть и чувствовать себя хорошо и работать отлично.

Элемент управления Delphi TListView является оболочкой для компонента представления списка Windows.В режиме работы по умолчанию копии данных списка передаются из вашего приложения в элемент управления Windows, и это происходит медленно.

Альтернативой этому в терминологии Windows является представление виртуального списка.Ваше приложение не передает данные в элемент управления Windows.Вместо этого, когда элемент управления должен отображать данные, он запрашивает у вашего приложения только те данные, которые необходимы.

Элемент управления Delphi TListView предоставляет виртуальные списки с помощью свойства OwnerData.Вам придется несколько переписать код представления списка, но это не слишком сложно.

Я также предлагаю ссылку на другой вопрос , который охватывает аналогичную основу.Как ни странно, принятый ответ на этот вопрос говорил о списках, хотя вопрос был об элементах управления представлением списка.

Answer 2

с VirtualStringTree это немного сложнее, чем простой TListView, однако вот очень простое руководство, которое я недавно создал для того, как использовать VirtualStringTree http://www.youtube.com/watch?v=o6FpUJhEeoY Надеюсь, это поможет, ура!

Answer 3

Просто используйте ваш обычный TListView, но используйте его в виртуальном режиме .

Это действительно просто:

1. Установите для свойства OwnerData значение true
2. Реализация обработчика событий OnData.

Пример реализации, который показывает простой список из 3 строк:

Type TMyItem=record
  Item:String;
  SubItem:String;
end;

var Items:Array of TMyItem;

// set up some in-memory dataset.. choose your own layout
SetLength(Items,3);
Items[0].Item := 'foo1';
Items[0].SubItem := 'bar1';

Items[1].Item := 'foo2';
Items[1].SubItem := 'bar2';

Items[2].Item := 'foo3';
Items[2].SubItem := 'bar3';

// tell ListView1 how many items there are
ListView1.Items.Count := Length(Items); 

procedure TfrmMain.ListView1Data(Sender: TObject; Item: TListItem);
begin
  Item.Caption := IntToStr(Item.Index);
  Item.SubItems.Add( MyArray[Item.Index] );
  Item.SubItems.Add( UpperCase(MyArray[Item.Index]) );
end;

// Updating a value:
Items[1].Item := 'bzzz';
ListView1.Update;

Вот и все!

Некоторые вещи, которые следует иметь в виду:

1. Вы больше не вызываете ListView1.Items.Add ().
2. Вам необходимо хранить свой собственный список данных где-то в памяти или создавать данные в режиме реального времени, чтобы вы больше не могли «сохранять» данные в просмотре списка.
3. Вынужно установить свойство items.count, иначе вы ничего не увидите.
4. Вызовите ListView1.Update (), если что-то изменится.

Answer 4

procedure Add;
Var
  Data: PLogData;
  XNode: PVirtualNode;
begin
  with vst do
    Begin
      XNode := AddChild(nil);
      ValidateNode(XNode, False);
      Data := GetNodeData(Xnode); 
      Data^.Name:= EditCaption.Text;
      Data^.Msg := EditSubItem.Text;
    End;

end;

Procedure ReadItem(I : Integer);
var
  Data: PLogData;
begin
  if not Assigned(vst.FocusedNode) then Exit;

  Data := vst.GetNodeData(vst.FocusedNode);
  ShowMessage(Data^.Name);
  ShowMessage(Data^.Msg);

end;

По сути, это то, что вам нужно сделать, но VirtualStringTree имеет / нуждается во многих других вещах, работающих вместе, чтобы полностью понять это.И как только вы «получите это», VST становится легким и мощным.Следующая веб-страница поможет вам: http://wiki.freepascal.org/VirtualTreeview_Example_for_Lazarus

и ниже я добавлю больше кода, который я использую для простого отображения журнала VST.Я храню весь код в модуле данных, просто используйте процедуру Журнал для отображения информации и измените свой FormMain.vstLog на ваш ...

unit udmVstLog;

interface

uses
  SysUtils, Windows, Forms, Classes, Graphics,
  VirtualTrees, ActnList, Dialogs, ExtDlgs;

type
  PLogData = ^TLogData;
  TLogData = record
    IsErr   : Boolean;
    Name: String;
    Msg : String;
  end;

type
  TdmVstLog = class(TDataModule)
    actlst1: TActionList;
    actClear: TAction;
    actSave: TAction;
    actCopyLine2Mem: TAction;
    sdlgLog: TSaveTextFileDialog;
    procedure DataModuleCreate(Sender: TObject);
    procedure actClearExecute(Sender: TObject);
    procedure actSaveExecute(Sender: TObject);
    procedure actCopyLine2MemExecute(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
    procedure VSTFreeNode(Sender: TBaseVirtualTree; Node: PVirtualNode);
    procedure VSTGetText(Sender: TBaseVirtualTree; Node: PVirtualNode;
      Column: TColumnIndex; TextType: TVSTTextType; var CellText: String);
    procedure VSTPaintText(Sender: TBaseVirtualTree;
      const TargetCanvas: TCanvas; Node: PVirtualNode; Column: TColumnIndex;
      TextType: TVSTTextType);
  end;

  procedure Log(aIsErr: Boolean; AName, AMsg: string); overload;
  procedure Log(AName, AMsg: string); overload;
  procedure Log(AMsg: string); overload;

var
  dmVstLog: TdmVstLog;

implementation

uses uFormMain, ClipBrd;

{$R *.dfm}
procedure Log(aIsErr: Boolean; AName, AMsg: string);
Var
  Data: PLogData;
  XNode: PVirtualNode;
begin
  XNode:=FormMain.vstLog.AddChild(nil);
  FormMain.vstLog.ValidateNode(XNode, False);
  Data := FormMain.vstLog.GetNodeData(Xnode);
  Data^.IsErr := aIsErr;
  if aIsErr then
    Data^.Name:= DateTimeToStr(Now) + ' ERROR ' + AName
  else
    Data^.Name:= DateTimeToStr(Now) + ' INFO ' + AName;
  Data^.Msg:= AMsg;
end;

procedure Log(AName, AMsg: string);
begin
  Log(False,AName,AMsg);
end;

procedure Log(AMsg: string);
begin
  Log(False,'',AMsg);
end;



// VirtualStringTree Events defined here
procedure TdmVstLog.VSTFreeNode(Sender: TBaseVirtualTree; Node: PVirtualNode);
var
  Data: PLogData;
begin
  Data:=Sender.GetNodeData(Node);
  Finalize(Data^);
end;

procedure TdmVstLog.VSTGetText(Sender: TBaseVirtualTree; Node: PVirtualNode;
 Column: TColumnIndex; TextType: TVSTTextType; var CellText: String);
var
  Data: PLogData;
begin
  Data := Sender.GetNodeData(Node);
  case Column of
    0: CellText := Data^.Name + ' - '+ Data^.Msg;
  end;
end;

procedure TdmVstLog.VSTPaintText(Sender: TBaseVirtualTree;
  const TargetCanvas: TCanvas; Node: PVirtualNode; Column: TColumnIndex;
  TextType: TVSTTextType);
Var
  Data: PLogData;
begin
  Data := Sender.GetNodeData(Node);

  if Data^.IsErr then
    TargetCanvas.Font.Color:=clRed;

end;

//PopUpMenu Actions defined here!
procedure TdmVstLog.actClearExecute(Sender: TObject);
begin
  FormMain.vstLog.Clear;
end;

procedure TdmVstLog.actCopyLine2MemExecute(Sender: TObject);
var
  Data: PLogData;
begin
  if not Assigned(FormMain.vstLog.FocusedNode) then Exit;

  Data := FormMain.vstLog.GetNodeData(FormMain.vstLog.FocusedNode);
  ClipBoard.AsText := Data^.Name + ' - ' + Data^.Msg;
end;

procedure TdmVstLog.actSaveExecute(Sender: TObject);
Var
  XNode: PVirtualNode;
  Data: PLogData;
  ts: TStringList;
begin
  If FormMain.vstLog.GetFirst = nil then Exit;
  XNode:=nil;
  if sdlgLog.Execute then begin
    ts:= TStringList.create;
    try
      Repeat
        if XNode = nil then XNode:=FormMain.vstLog.GetFirst Else XNode:=FormMain.vstLog.GetNext(XNode);
        Data:=FormMain.vstLog.GetNodeData(XNode);
        ts.Add(Data^.Name + ' - '+ Data^.Msg);
      Until XNode = FormMain.vstLog.GetLast();
      ts.SaveToFile(sdlgLog.FileName);
    finally
      ts.Free;
    end;
  end;

end;

// Datamodule Events defined here
procedure TdmVstLog.DataModuleCreate(Sender: TObject);
begin
  with FormMain.vstLog do begin
    NodeDataSize := SizeOf(TLogData);
    OnFreeNode := VSTFreeNode;
    OnGetText := VSTGetText;
    OnPaintText := VSTPaintText;
  end;
end;

end.

...

procedure RemoveSelectedNodes(vst:TVirtualStringTree);
begin
  if vst.SelectedCount = 0 then Exit;
  vst.BeginUpdate;
  vst.DeleteSelectedNodes;
  vst.EndUpdate;
end;

procedure RemoveAllNodes(vst:TVirtualStringTree);
begin
  vst.BeginUpdate;
  vst.Clear;
  vst.EndUpdate;
end;

Answer 5

Получите пакет VT Contributions и посмотрите некоторые из потомков виртуального дерева строк.Это там.Я не использовал их в проектах, но они, кажется, облегчают использование Virtual String Tree.

---

Тем не менее, вот мой учебник для начинающих:

После использования Virtual String Tree я обнаружил, что единственный способ, которым вы можете максимально использоватьэто путем реализации функций узла / потомка инициализации и установки количества корневых узлов, почти так же, как вы бы делали представление списка с владельцемdraw: = true.

Довольно просто делать вещи с VirtualStringTree, вам просто нужно реализовать функцию get text и функции размера узла (установите ее равной размеру любой записи, которую вы хотели бы использовать в качестве данных за вашимдерево)

Я обнаружил, что почти всегда проще TVirtualTreeNodeRecordData = record Data : TVirtualTreeNodeData; end

и создать объект данных для функций инициализации.Он создает указатели для вас, но вам нужно освободить объекты (опять же, используйте другой обратный вызов удаления узла).