Flex: реализовать классическую функцию карри в actionscript?

Question

Как лучше всего реализовать классическую функцию карри в ActionScript с хорошим синтаксисом?

Я пробовал:

Function.prototype.curry = function()
{
return "helloWorld";
}

trace((function():void {}).curry());

... подход, но это не сработало.

Полагаю, я застрял в таком ужасном подходе, как:

FunctionUtils.curry(fp, ... args)

???

Answer 1

Должен признать, что я никогда не понимал разницу между "карри" и "частичным". Я использую следующую функцию, чтобы сделать более или менее то, что вы хотите сделать:

package {
  public function partial( func : Function, ...boundArgs ) : Function {
    return function( ...dynamicArgs ) : * {
      return func.apply(null, boundArgs.concat(dynamicArgs))
    }
  }
}

Примеры использования:

var multiply : Function = function( a : Number, b : Number ) : Number { return a * b; }
var multiplyByFour : Function = partial(multiply, 4);

trace(multiplyByFour(3)); // => 12

Answer 2

Закончено (во многом благодаря реализации додзё):

public static function curry(func:Function, ... args:Array):*
{
    var arity:int = func.length;
    var currying:Function = function(func:Function, arity:int, args:Array):*
    {
        return function(... moreArgs:Array):* {
            if(moreArgs.length + args.length < arity)
            {
                return currying(func, arity, args.concat(moreArgs));
            }
            return func.apply(this, args.concat(moreArgs));
        }
    }
    return currying(func, arity, args);
}

Запрос в разделе комментариев, чтобы показать пример того, как использовать это:

function foo(i:int, j:int):void
{
   trace(i+j);
}

function bar(fp:Function):void
{
   fp(2);
}

bar(FunctionUtils.curry(foo, 1)); //trace==3

Глупый пример, я знаю, но карри: он чрезвычайно полезен. Посмотрите на http://www.svendtofte.com/code/curried_javascript/ для теории.