Как распечатать уникальные элементы в массиве Perl?

Question

Я помещаю элементы в массив во время оператора while. Каждый элемент является именем учителя. Когда цикл заканчивается, в массиве появляются повторяющиеся имена учителей. Иногда они не находятся рядом друг с другом в массиве, иногда они есть.

Как я могу распечатать только уникальные значения в этом массиве после того, как в него будут вставлены окончательные значения? Без необходимости разбирать весь массив каждый раз, когда я хочу напечатать элемент.

Вот код после того, как все было помещено в массив:

$faculty_len = @faculty;
$i=0;
while ($i != $faculty_len)
{
        printf $fh '"'.$faculty[$i].'"';
        $i++;
}   

Answer 1

use List::MoreUtils qw/ uniq /;
my @unique = uniq @faculty;
foreach ( @unique ) {
    print $_, "\n";
}

Answer 2

Лучше всего было бы использовать (в основном) встроенный инструмент, такой как uniq (, как описано в innaM) .

Если у вас нет возможности использовать uniq и вы хотите сохранить порядок, вы можете использовать grep для имитации этого.

my %seen;
my @unique = grep { ! $seen{$_}++ } @faculty;
# printing, etc.

Сначала вы получите хеш, в котором каждый ключ является каждой записью. Затем вы перебираете каждый элемент, подсчитываете их количество и добавляете первый. (Обновлено с комментариями Брайана Д. Фоя)

Answer 3

Я предлагаю вставить это в хеш. как это:

my %faculty_hash = ();
foreach my $facs (@faculty) {
  $faculty_hash{$facs} = 1;
}
my @faculty_unique = keys(%faculty_hash);

Answer 4

На этот вопрос дан ответ с несколькими решениями в perldoc. Просто введите в командной строке:

perldoc -q duplicate

Answer 5

@array1 = ("abc", "def", "abc", "def", "abc", "def", "abc", "def", "xyz");

@array1 = grep { ! $seen{ $_ }++ } @array1;

print "@array1\n"; 

Answer 6

Обратите внимание: некоторые ответы, содержащие хэш, изменят порядок массива. Хэши не имеют какого-либо порядка, поэтому получение ключей или значений приведет к созданию списка с неопределенным порядком.

Это не относится к grep { ! $seen{$_}++ } @faculty

Answer 7

Это однострочная команда для печати уникальных строк в порядке их появления.

perl -ne '$seen{$_}++ || print $_' fileWithDuplicateValues

Answer 8

Просто еще один способ сделать это, полезно , только если вы не заботитесь о заказе :

my %hash;
@hash{@faculty}=1;
my @unique=keys %hash;

Если вы хотите избежать объявления новой переменной, вы можете использовать как-то недокументированную глобальную переменную % _

@_{@faculty}=1;
my @unique=keys %_;

Answer 9

Я только что нашел избитый 3 лайнер, наслаждайся

my %uniq; 
undef @uniq(@non_uniq_array); 
my @uniq_array = keys %uniq; 

Answer 10

Если вам нужно каким-либо образом обработать список факультетов, карта с массивом, преобразованная в хеш для объединения ключей, а затем сортировки ключей, является еще одним хорошим способом:

my @deduped = sort keys %{{ map { /.*/? ($_,1):() } @faculty }};
print join("\n", @deduped)."\n";

Вы обрабатываете список, изменяя регулярное выражение /.*/ для выбора или анализа и захвата соответственно, и вы можете выводить один или несколько видоизмененных неуникальных ключей за проход, делая ($_,1):() произвольно сложным.

Если вам нужно изменить данные в полете с помощью регулярного выражения подстановки, скажем, для удаления точек из имен (s/\.//g), то подстановка в соответствии с вышеуказанным шаблоном приведет к изменению исходного массива @faculty из-за $_ алиасинг. Вы можете обойтись псевдонимом $_, сделав анонимную копию массива @faculty (см. Так называемый оператор "baby cart" ):

my @deduped = sort keys %{{ map {/.*/? do{s/\.//g; ($_,1)}:()} @{[ @faculty ]} }};
print join("\n", @deduped)."\n";
print "Unmolested array:\n".join("\n", @faculty)."\n";

В более поздних версиях Perl вы можете передать keys хэш-ссылку и использовать неразрушающую замену:

my @deduped = sort keys { map { /.*/? (s/\.//gr,1):() } @faculty };

В противном случае решения grep или $seen[$_]++ в других местах могут быть предпочтительнее.