xslt конвертирует строку xml в элементы xml

Question

вот хитрый.

У меня есть следующий XML

<test>
     <testElement SomeAttribute="<otherxml><otherElement>test test</otherElement></otherxml>">
      </testElement>
</test>

Используя XSLT, я хочу преобразовать этот XML, чтобы получить следующий результат.

<test>
     <testElement>
        <SomeAttributeTransformedToElement>
          <otherxml>
               <otherElement>test test</otherElement>
          </otherxml>
        </SomeAttributeTransformedToElement>
      </testElement>
</test>

По сути, некоторый текст в атрибуте должен быть преобразован в фактические элементы в конечном XML

Есть идеи, как этого добиться в XSLT?

Alex

Answer 1

Этого можно добиться, отключив экранирование выхода. Однако обратите внимание, что ваш входной документ не является допустимым XML-документом (< недопустим в значениях атрибутов и требует экранирования). Поэтому я изменил ваш входной документ следующим образом:

Входной документ

<?xml version="1.0" encoding="utf-8"?>
<test>
  <testElement SomeAttribute="&lt;otherxml>&lt;otherElement>test test&lt;/otherElement>&lt;/otherxml>">
  </testElement>
</test>

1010 * XSLT *

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="@SomeAttribute">
    <SomeAttributeTransformedToElement>
      <xsl:value-of select="." disable-output-escaping="yes"/>
    </SomeAttributeTransformedToElement>
  </xsl:template>
</xsl:stylesheet>

Имейте в виду, что с disable-output-escaping="yes" больше нет гарантии, что созданный выходной документ является правильно сформированным XML-документом.

Answer 2

У меня была такая же потребность, и мне наконец удалось построить что-то работающее.

Однако это далеко от совершенства . Но так как это решение работает для меня (и очень полезно в моем случае), я даю его им, чтобы поделиться им со всеми, кого можно было бы тоже заинтересовать.

Я надеюсь, что XSL-пуристы простят меня за это:

Этот именованный шаблон XSLT принимает текстовую переменную в качестве входных данных и генерирует элементы XML на выходе. Предупреждение : существуют некоторые ограничения:

• XML не должен иметь автономных элементов ( ... запрещено, так как элемент 'a' содержит еще один 'a')
• XML должен быть нормализован (один пробел между именем элемента и атрибутами, поэтому разрешено, но не (это можно исправить)
• & ltelement /> еще не обработан (извините, мне это не нужно, и я немного занят текущим проектом), но это легко исправить.

Итак, вас предупредили: не запускайте это в производство до того, как протестируете его и убедитесь, что оно неразборчиво для вашего случая. Также, если вам случится исправить или улучшить этот скрипт, пожалуйста, дайте мне знать.

Вот шаблоны:

<xsl:template name="t-convert">
    <xsl:param name="TEXT"/>
    <xsl:choose>
        <xsl:when test="starts-with($TEXT,'&lt;?')">
            <xsl:call-template name="t-convert">
                <xsl:with-param name="TEXT" select="substring-after($TEXT,'?&gt;')"/>
            </xsl:call-template>
        </xsl:when>
        <!-- Si le texte contient encore des elements -->
        <xsl:when test="contains($TEXT,'&lt;')">
            <xsl:variable name="before-first-open" select="substring-before($TEXT,'&lt;')"/>
            <xsl:variable name="after-first-open" select="substring-after($TEXT,'&lt;')"/>
            <!-- On ecrit le texte qui précéde l'élément -->
            <xsl:value-of select="$before-first-open"/>
            <!-- Le nom de l'élément -->
            <xsl:variable name="TRAD" select="translate($after-first-open,'&gt;',' ')"/>
            <!--  TODO : Gere le cas <ELEMENT />   -->
            <xsl:variable name="ELEMENT" select="substring-before($TRAD,' ')"/>
            <xsl:variable name="suite" select="substring-after($after-first-open,$ELEMENT)"/>
            <xsl:variable name="DEFINITION" select="substring-before($suite,'&gt;')"/>
            <xsl:variable name="CONTENT" select="substring-after(substring-before($suite,concat('&lt;/',$ELEMENT)),concat($DEFINITION,'&gt;'))"/>
            <xsl:variable name="FOLLOWING">
                <xsl:choose>
                    <xsl:when test="substring($DEFINITION,string-length($DEFINITION))='/'"><!--  ends-with($DEFINITION,'/') not compatible with all XSLT version -->
                        <xsl:value-of select="substring-after($suite,'/&gt;')"/>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:value-of select="substring-after(substring-after($suite,concat('&lt;/',$ELEMENT)),'&gt;')"/>
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:variable>
            <xsl:element name="{$ELEMENT}">
                <xsl:call-template name="t-attribs">
                    <xsl:with-param name="TEXT" select="$DEFINITION"/>
                </xsl:call-template>
                <xsl:call-template name="t-convert">
                    <xsl:with-param name="TEXT" select="$CONTENT"/>
                </xsl:call-template>
            </xsl:element>
            <xsl:call-template name="t-convert">
                <xsl:with-param name="TEXT" select="$FOLLOWING"/>
            </xsl:call-template>
        </xsl:when>
        <!-- no more element -->
        <xsl:otherwise>
            <xsl:value-of select="$TEXT"/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

<xsl:template name="t-attribs">
    <xsl:param name="TEXT"/>
    <xsl:if test="contains($TEXT,'=')">
        <!-- Assert TEXT=' NAME="VALUE".*' -->
        <xsl:variable name="NAME" select="substring-after(substring-before($TEXT,'='),' ')"/>
        <xsl:variable name="afterName" select="substring-after($TEXT,'=&quot;')"/>
        <xsl:variable name="VALUE" select="substring-before($afterName,'&quot;')"/>
        <xsl:variable name="FOLLOWING" select="substring-after($afterName,'&quot;')"/>
        <xsl:attribute name="{$NAME}">
            <xsl:value-of select="$VALUE"/>
        </xsl:attribute>
        <xsl:call-template name="t-attribs">
            <xsl:with-param name="TEXT" select="FOLLOWING"/>
        </xsl:call-template>
    </xsl:if>
</xsl:template>

И он вызывается с помощью:

<xsl:call-template name="t-convert">
        <xsl:with-param name="TEXT" select="//content"/>
</xsl:call-template>

Надеюсь, что это будет хоть как-то в мире (это было для меня!)