xsl: сортировка файла XML с использованием нескольких элементов

Question

Я пытаюсь отсортировать кучу записей в файле XML. Хитрость в том, что мне нужно сортировать, используя разные элементы для разных узлов. Чтобы привести простейший пример, я хочу сделать это: дано XML-файл

<?xml version="1.0" encoding="utf-8" ?>

<buddies>

<person>
<nick>Jim</nick>
<last>Zulkin</last>
</person>

<person>
<first>Joe</first>
<last>Bumpkin</last>
</person>

<person>
<nick>Pumpkin</nick>
</person>

<person>
<nick>Andy</nick>
</person>

</buddies>

Я хочу преобразовать его в

Andy
Joe Bumpkin
Pumpkin
Jim Zulkin

То есть человек может быть указан любым подмножеством имени, фамилии и псевдонима. Ключ сортировки - это фамилия, если она присутствует, в противном случае это псевдоним, если он присутствует, и имя в противном случае.

У меня возникли трудности, поскольку использование переменных в качестве ключей xsl: sort явно не разрешено .

Мой лучший лучший способ - двухэтапное преобразование: добавьте специальный тег к каждой записи, используя эту таблицу стилей

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output omit-xml-declaration="no" indent="yes"/>

<!-- *** convert each person record into a person2 record w/ the sorting key *** -->
<xsl:template match="/buddies">
    <buddies>
    <xsl:for-each select="person">
     <person2>
        <xsl:copy-of select="*"/>
        <!-- add the sort-by tag -->
        <sort-by>
        <xsl:choose>
            <xsl:when test="last"> <xsl:value-of select="last"/>
            </xsl:when>
            <xsl:otherwise>
                <xsl:choose>
                    <xsl:when test="nick"> <xsl:value-of select="nick"/> </xsl:when>
                    <xsl:otherwise> <xsl:value-of select="first"/> </xsl:otherwise>
                </xsl:choose>
            </xsl:otherwise>
        </xsl:choose>
    </sort-by>
  </person2>
</xsl:for-each>
</buddies>

А затем отсортировать полученный xml

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:template match="/buddies">
    <xsl:apply-templates>
        <xsl:sort select="sort-by"/>
    </xsl:apply-templates>
</xsl:template>

<xsl:template match="person2">
   <xsl:value-of select="first"/>
   <xsl:value-of select="nick"/>
   <xsl:value-of select="last"/><xsl:text>
</xsl:text>
</xsl:template>

Хотя это двухступенчатое преобразование работает, мне интересно, есть ли более элегантный способ сделать это за один раз?

Answer 1

Вы можете использовать функцию concat XPath:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:template match="/buddies">
        <xsl:apply-templates>
            <xsl:sort select="concat(last,nick,first)"/>
        </xsl:apply-templates>
    </xsl:template>
    <xsl:template match="person">
        <xsl:value-of select="concat(normalize-space(concat(first,
                                                            ' ',
                                                            nick,
                                                            ' ',
                                                            last)),
                                     '&#xA;')"/>
    </xsl:template>
</xsl:stylesheet>

Answer 2

Можете ли вы попробовать, если этот шаблон дает ожидаемый результат?Для вашего простого примера он дает правильный ответ, но могут быть и угловые случаи, которые не будут работать.Normalize-space используется здесь для удаления начальных и конечных пробелов, если один из элементов отсутствует.

<xsl:template match="/buddies">
    <xsl:for-each select="person">
        <xsl:sort select="normalize-space(concat(last, ' ', nick, ' ', first))"/>

        <xsl:if test="first">
            <xsl:value-of select="first" />
            <xsl:text> </xsl:text>
        </xsl:if>

        <xsl:if test="nick">
            <xsl:value-of select="nick" />
            <xsl:text> </xsl:text>
        </xsl:if>

        <xsl:value-of select="last" />
        <xsl:text>&#10;</xsl:text>
    </xsl:for-each>
</xsl:template>