flexunit обработки события клиента и Async.asyncHandler () - PullRequest
Новая
       42

flexunit обработки события клиента и Async.asyncHandler ()

3 голосов
/ 27 ноября 2010

Любой знает, как работает Async.asyncHandler(), и если Async.processOnEvent() можно использовать только в методе [До]. (Любой знает какой-нибудь полезный документ, кроме http://docs.flexunit.org/).

Я определяю компонент MXML с именем HelloCompo (расширяет Vbox), а компонент определяет функцию с именем hello (), в hello () рассылает событие клиента с именем HelloEvent (тип события только с именем «hello») и в другая функция с именем init () прослушала событие, я хочу проверить, правильно ли отправляется событие или нет. Итак, у меня есть следующий тест:

var helloCompo = new HelloCompo (); 

helloCompo.hello();

helloCompo.addEventListener("hello", Async.asyncHandler(this, handleHello, 1000, null, handleTimeOut));

Тест всегда будет оправдывать метод handleTimeOut (означает, что HelloEvent не отправляется, но когда helloCompo.hello () оправдывается, он действительно не обрабатывается, так что же происходит не так?)

Ответы [ 2 ]

6 голосов
/ 28 ноября 2010 
package flexUnitTests
{
    import flash.events.Event;

    import org.flexunit.asserts.assertTrue;
    import org.flexunit.asserts.fail;
    import org.flexunit.async.Async;

    public class HelloTest
    {       
        private var helloCompo:HelloCompo;

        [Before]
        public function setUp():void
        {
            helloCompo = new HelloCompo();
        }

        [After]
        public function tearDown():void
        {
            helloCompo = null;
        }

        [Test(async)]
        public function testHello():void
        {
            var handler:Function = Async.asyncHandler(this, helloHandler, 300, null, helloFailed);
            helloCompo.addEventListener("hello", handler);
            helloCompo.hello();
        }

        private function helloHandler(event:Event, passThroughObject:Object):void
        {
            //assert somthing
        }

        private function helloFailed(event:Event, passThroughObject:Object):void
        {
            fail("hello not dispatched");
        }


    }
}

HelloCompo.as 

package
{
    import flash.events.Event;
    import flash.events.EventDispatcher;
    import flash.events.IEventDispatcher;

    public class HelloCompo extends EventDispatcher
    {
        public function HelloCompo(target:IEventDispatcher=null)
        {
            super(target);
        }

        public function hello():void
        {
            dispatchEvent(new Event("hello"));
        }
    }
}
2 голосов
/ 27 ноября 2010

Я думаю, вам нужно добавить прослушиватель событий перед вызовом hello (), на самом деле

...