VBScript ошибка 800A004C

Question

Мне нужно создать текстовый файл с именем « listfile.txt » в папке C: \ Documents and Settings \ All Users \ Application Data \ netapp \ system , поэтому я сделал следующий VBScript, чтобы получить

Const CommonAppData = &H23&  ' the second & denotes a long integer '
Const OSCPATH = "\netapp\system"
Dim fso, MyFile

Set objShell  = CreateObject("Shell.Application")
Set objFolder = objShell.Namespace(CommonAppData)

Set objFolderItem = objFolder.Self

'MsgBox objFolderItem.Name & ": " & objFolderItem.Path


Set fso = CreateObject("Scripting.FileSystemObject")
Set MyFile = fso.CreateTextFile("objFolderItem.Path & OSCPATH\listfile.txt", True)
MyFile.WriteLine("This is a test.")
MyFile.Close

но его ошибки с указанием пути не найдены

** Windows Script Host

Скрипт: C: \ Documents and Settings \ puthuprf \ Desktop \ test.vbs Линия: 15 Чар: 1 Ошибка: путь не найден Код: 800A004C

Источник: ошибка выполнения Microsoft VBScript

OK
--------------------------- **

Answer 1

Эта строка в вашем скрипте неверна:

Set MyFile = fso.CreateTextFile("objFolderItem.Path & OSCPATH\listfile.txt", True)

Чтобы вставить переменные и свойства объекта в строку, вам нужно объединить их, используя оператор &, например:

Set MyFile = fso.CreateTextFile(objFolderItem.Path & OSCPATH & "\listfile.txt", True)

Обратите внимание, что рекомендуется использовать метод BuildPath для объединения нескольких частей пути, поскольку он освобождает вас от необходимости добавлять необходимые разделители пути (\) вручную:

strFileName = fso.BuildPath(objFolderItem.Path, OSCPATH)
strFileName = fso.BuildPath(strFileName, "listfile.txt")

Set MyFile = fso.CreateTextFile(strFileName, True)