Получите доступ к VBA 2010, запросите таблицу и выполните итерацию результатов - PullRequest
Новая
       17

Получите доступ к VBA 2010, запросите таблицу и выполните итерацию результатов

15 голосов
/ 25 января 2011

У меня есть запрос, который я хочу выполнить для таблицы. С результатами я хочу что-то сделать. В моей голове псевдокод: 

var q = "select * from table where some condition";
var results = db.getResults(q);
foreach (row r in results )
    do something with result

Как бы я так чем-то похож на vba?

Ответы [ 3 ]

29 голосов
/ 25 января 2011

DAO является родным для Access и безусловно лучшим для общего использования.У ADO есть свое место, но вряд ли это оно. 

 Dim rs As DAO.Recordset
 Dim db As Database
 Dim strSQL as String

 Set db=CurrentDB

 strSQL = "select * from table where some condition"

 Set rs = db.OpenRecordset(strSQL)

 Do While Not rs.EOF

    rs.Edit
    rs!SomeField = "Abc"
    rs!OtherField = 2
    rs!ADate = Date()
    rs.Update

    rs.MoveNext
Loop
0 голосов
/ 25 января 2011

Ааа. Поскольку я пропустил ваш начальный пост, вот пример, который также СОДЕРЖИТ. Первый пример не сделал. В этом случае я получаю набор записей ADODB, затем загружаю данные в коллекцию, которую функция возвращает клиентскому коду:

РЕДАКТИРОВАТЬ: Не уверен, что я облажался при вставке кода, но форматирование немного болтается. Извините! 

Public Function StatesCollection() As Collection
Dim cn As ADODB.Connection
Dim cmd As ADODB.Command
Dim rs As ADODB.Recordset
Dim colReturn As New Collection

Set colReturn = New Collection

Dim SQL As String
SQL = _
    "SELECT tblState.State, tblState.StateName " & _
    "FROM tblState"

Set cn = New ADODB.Connection
Set cmd = New ADODB.Command

With cn
    .Provider = DataConnection.MyADOProvider
    .ConnectionString = DataConnection.MyADOConnectionString
    .Open
End With

With cmd
    .CommandText = SQL
    .ActiveConnection = cn
End With

Set rs = cmd.Execute

With rs
    If Not .EOF Then
    Do Until .EOF
        colReturn.Add Nz(!State, "")
        .MoveNext
    Loop
    End If
    .Close
End With
cn.Close

Set rs = Nothing
Set cn = Nothing

Set StatesCollection = colReturn

Функция завершения

0 голосов
/ 25 января 2011

Я знаю, что некоторые вещи изменились в AC 2010. Однако, насколько я знаю, старомодный ADODB - лучший путь в VBA.Пример: 

Dim cn As ADODB.Connection
Dim cmd As ADODB.Command
Dim prm As ADODB.Parameter
Dim rs As ADODB.Recordset
Dim colReturn As New Collection

Dim SQL As String
SQL = _
    "SELECT c.ClientID, c.LastName, c.FirstName, c.MI, c.DOB, c.SSN, " & _
    "c.RaceID, c.EthnicityID, c.GenderID, c.Deleted, c.RecordDate " & _
    "FROM tblClient AS c " & _
    "WHERE c.ClientID = @ClientID"

Set cn = New ADODB.Connection
Set cmd = New ADODB.Command

With cn
    .Provider = DataConnection.MyADOProvider
    .ConnectionString = DataConnection.MyADOConnectionString
    .Open
End With

With cmd
    .CommandText = SQL
    .ActiveConnection = cn
    Set prm = .CreateParameter("@ClientID", adInteger, adParamInput, , mlngClientID)
    .Parameters.Append prm
End With

Set rs = cmd.Execute

With rs
    If Not .EOF Then
        Do Until .EOF
            mstrLastName = Nz(!LastName, "")
            mstrFirstName = Nz(!FirstName, "")
            mstrMI = Nz(!MI, "")
            mdDOB = !DOB
            mstrSSN = Nz(!SSN, "")
            mlngRaceID = Nz(!RaceID, -1)
            mlngEthnicityID = Nz(!EthnicityID, -1)
            mlngGenderID = Nz(!GenderID, -1)
            mbooDeleted = Deleted
            mdRecordDate = Nz(!RecordDate, "")

            .MoveNext
        Loop
    End If
    .Close
End With

cn.Close

Set rs = Nothing
Set cn = Nothing
...