Создать динамический <table>из XML с помощью XSLT

Question

Я пытаюсь сделать легкий динамический <table> с входным XML.Мой XML-код выглядит так:

    <table>
        <col size="5%">#</col>
        <col size="55%">Title</col>
        <col size="10%">Author</col>
        <col size="10%">Date</col>
        <col size="10%">Modification</col>
        <col size="10%">Actions</col>

        <output>
            <row>1</row>
            <row>Title of the entry</row>
            <row>Administrator</row>
            <row>dd/mm/yyyy hh:mm</row>
            <row>dd/mm/yyyy hh:mm</row>
            <row>Edit Delete</row>
        </output>
    </table>

Я генерирую это, потому что я не хочу иметь один XSLT для внутренней панели, который преобразует мой выходной XML в <table> в зависимости от переменныхразличные разделы.

Я сделал этот XSLT-код:

                <table>
                    <tr>
                        <xsl:for-each select="page/index/table/col">
                            <td>
                                <xsl:attribute name="width"><xsl:value-of select="size" /></xsl:attribute>
                                <xsl:value-of select="." />
                            </td>
                        </xsl:for-each>
                    </tr>
                    <xsl:for-each select="page/index/table/output">
                        <tr>
                            <xsl:for-each select="row">
                                <td>
                                    <xsl:value-of select="." />
                                </td>
                            </xsl:for-each>
                        </tr>
                    </xsl:for-each>
                </table>

Я генерирую таблицу, но не могу заполнить атрибут WIDTH значением col / size.

Как я могу это сделать?

Answer 1

Использование :

  <td width="{@size}"><xsl:value-of select="."/></td>

В XSLT рекомендуется избегать использования <xsl:for-each>, если возможно .

Полное преобразование без<xsl:for-each> равно:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="table">
   <table>
    <tr>
      <xsl:apply-templates select="col"/>
    </tr>
    <xsl:apply-templates select="output"/>
   </table>
 </xsl:template>

 <xsl:template match="col">
  <td width="{@size}"><xsl:value-of select="."/></td>
 </xsl:template>

 <xsl:template match="output">
  <tr>
   <xsl:apply-templates/>
  </tr>
 </xsl:template>

 <xsl:template match="row">
  <td><xsl:value-of select="."/></td>
 </xsl:template>
</xsl:stylesheet>

, когда это преобразование применяется к следующему документу XML (исходный фрагмент XML, заключенный в элементы index и page):

<page>
    <index>
        <table>
            <col size="5%">#</col>
            <col size="55%">Title</col>
            <col size="10%">Author</col>
            <col size="10%">Date</col>
            <col size="10%">Modification</col>
            <col size="10%">Actions</col>
            <output>
                <row>1</row>
                <row>Title of the entry</row>
                <row>Administrator</row>
                <row>dd/mm/yyyy hh:mm</row>
                <row>dd/mm/yyyy hh:mm</row>
                <row>Edit Delete</row>
            </output>
        </table>
    </index>
</page>

желаемый, правильный результат получается :

<table>
   <tr>
      <td width="5%">#</td>
      <td width="55%">Title</td>
      <td width="10%">Author</td>
      <td width="10%">Date</td>
      <td width="10%">Modification</td>
      <td width="10%">Actions</td>
   </tr>
   <tr>
      <td>1</td>
      <td>Title of the entry</td>
      <td>Administrator</td>
      <td>dd/mm/yyyy hh:mm</td>
      <td>dd/mm/yyyy hh:mm</td>
      <td>Edit Delete</td>
   </tr>
</table>

Answer 2

Селектор для атрибута размера должен читать @size, а не просто size, т.е.

<xsl:value-of select="@size" />

Answer 3

Попробуйте @size вместо size: вы ищете атрибут, а не элемент.