Как получить доступ к тексту поиска в компоненте TCRDBGrid? - PullRequest
Новая
       23

Как получить доступ к тексту поиска в компоненте TCRDBGrid?

2 голосов
/ 22 октября 2010

Есть ли способ получить доступ к тексту, введенному в панели поиска Devart (Core Lab) TCRDBGrid?

Я пытался реализовать событие OnKeyDown, но событие не происходило при вводе в поля поиска, толькокогда сама сетка была выбрана.Других событий, которые выглядят актуальными, нет.

Похоже, что текст входит в TEdit, который является частью TCRGridTitleEdit, который является частью TCRDBGrid, но является приватным.получить текст для поиска?

Пример TCFGBGrid: 

+---------+------------+
| UserId  |  UserName  | <- Column titles
+---------+------------+
|[987654] | [        ] | <- Search bar (searching for UserId 987654)
+---------+------------+
| 123456  |  Wile Cau  | <- Data
+---------+------------+
|   ...   |    ...     | <- More data

Если UserId 987654 не существует, я хочу предложить что-то вроде «Создать нового пользователя 987654?»и потенциально создать новую запись с UserId, установленным в 987654.

1 Ответ

3 голосов
/ 22 октября 2010

TCRDBGrid распространяется с исходным кодом.Вы можете изменить исходный код:

объявить тип события: 

  TOnTextChanged = procedure (Sender: TObject; Text: string) of object;

добавить объявление события в классе TCRGridTitleEdit: 

private 
    FOnFilterChanged: TOnTextChanged;
    FOnSearchChanged: TOnTextChanged;

public
    property OnFilterChanged: TOnTextChanged read FOnFilterChanged write FOnFilterChanged;
    property OnSearchChanged: TOnTextChanged read FOnSearchChanged write FOnSearchChanged;

вызвать это событие в процедуре ProcessEdit: 

procedure TCRGridTitleEdit.ProcessEdit;
begin
  if (FActiveColumn = nil) or (CRDBGrid = nil) or not FEdit.Modified then
    Exit;

  if FAsFilter then
    with CRDBGrid do begin
      try
        TCRColumn(FActiveColumn).GetFilterExpression(FEdit.Text);
        FFilterExpressions[FActiveColumn.Index] := FEdit.Text;
        Self.Caption := FFilterExpressions[FActiveColumn.Index];
        if Assigned(FOnFilterChanged) then
          FOnFilterChanged(self, FEdit.Text);
      except
        on EConvertError do begin
          FEdit.SelectAll;
          raise;
        end;
      end;
    end
  else
    try
      with FActiveColumn.Field do
        DataSet.Locate(FieldName, {$IFDEF CLR}Variant{$ENDIF}(FEdit.Text), [loCaseInsensitive,loPartialKey]);
      if Assigned(FOnSearchChanged) then
        FOnSearchChanged(self, FEdit.Text);
    except
      on EConvertError do
        Exit;
    end;
end;

и добавление объявления события в классе TCRDBGrid: 

private
  function GetOnFilterChanged: TOnTextChanged;
  procedure SetOnFilterChanged(Value: TOnTextChanged);
  function GetOnSearchChanged: TOnTextChanged;
  procedure SetOnSearchChanged(Value: TOnTextChanged);

published
  property OnFilterChanged: TOnTextChanged read GetOnFilterChanged write SetOnFilterChanged;
  property OnSearchChanged: TOnTextChanged read GetOnSearchChanged write SetOnSearchChanged;

реализация 

function TCRDBGrid.GetOnFilterChanged: TOnTextChanged;
begin
  Result := CRGridTitleEdit.OnFilterChanged;
end;

procedure TCRDBGrid.SetOnFilterChanged(Value: TOnTextChanged);
begin
  CRGridTitleEdit.OnFilterChanged := Value;
end;

function TCRDBGrid.GetOnSearchChanged: TOnTextChanged;
begin
  Result := CRGridTitleEdit.OnSearchChanged;
end;

procedure TCRDBGrid.SetOnSearchChanged(Value: TOnTextChanged);
begin
  CRGridTitleEdit.OnSearchChanged := Value;
end;
...