QML Listview выделенный элемент выделяется при нажатии

Question

Привет, я хочу поставить этот код:

highlight: Rectangle {
    color: "black"
    radius: 5 
    opacity: 0.7
    focus: true
}

в mouseArea в обработчике onclick:

MouseArea {
    id: mouse_area1
    z: 1
    hoverEnabled: false
    anchors.fill: parent
    onClicked: {
    }

Это все listView:

ListView {
         id: listview1
         x: 0
         y: 82
        // width: 574
        // height: 967
         width: window.width
         height: window.height
         visible: true
         keyNavigationWraps: false
         boundsBehavior: Flickable.DragAndOvershootBounds
         opacity: 1
         maximumFlickVelocity: 2500
         anchors.leftMargin: 0
         highlightMoveSpeed: 489
         contentWidth: 0
         preferredHighlightEnd: 2
         spacing: 5
         highlightRangeMode: ListView.NoHighlightRange
         snapMode: ListView.SnapToItem
         anchors.bottomMargin: 0
         anchors.rightMargin: 0
         anchors.topMargin: 82
              anchors.fill: parent
              model: myModel
              delegate:Component {
                  //id: contactDelegate
                  Item {
                      property variant myData: model
                      width: 574; height: 90
                      Column {
                          x: 12
                          y: 0
                          width: 562
                          height: 90
                          anchors.rightMargin: 0
                          anchors.bottomMargin: 0
                          anchors.leftMargin: 12
                          anchors.topMargin: 0
                          anchors.fill: parent
                          spacing: 2
                          Text { text: '<b>ID: </b> ' + id_user ; verticalAlignment: Text.AlignTop; wrapMode: Text.NoWrap; horizontalAlignment: Text.AlignHCenter; color:"steelblue"; font.family: "Helvetica"; font.pointSize: 10 }
                          Text { text: '<b>Name: </b> ' + user_name; horizontalAlignment: Text.AlignHCenter; color:"steelblue"; font.family: "Helvetica"; font.pointSize: 10 }
                          Text { text: '<b>Lastname: </b> ' + user_lastname; horizontalAlignment: Text.AlignHCenter; color:"steelblue"; font.family: "Helvetica"; font.pointSize: 10 }
                          Text { height: 16; text: '<b>Tel number: </b> ' + user_number; verticalAlignment: Text.AlignVCenter; horizontalAlignment: Text.AlignHCenter; color:"steelblue"; font.family: "Helvetica"; font.pointSize: 10 }
                          Text { text: '<b>Address: </b> ' + user address; horizontalAlignment: Text.AlignHCenter; color:"steelblue"; font.family: "Helvetica"; font.pointSize: 10 }

                          MouseArea {
                              id: mouse_area1
                              z: 1
                              hoverEnabled: false
                              anchors.fill: parent
                              onClicked: 
                                  Item
                              {

                                }

                          }
                      }
                      }
              }

              //delegate: contactDelegate
              highlight: Rectangle
              {
                   color:"black"
                   radius: 5
                   opacity: 0.7
                   focus: true
              }
}

Пока выделение работает только при использовании стрелок, но это будет приложение для Android, поэтому мне нужно прикоснуться к тому же эффекту, и ВТОРОЙ вопрос - как прочитать определенные данные из выбранного элемента в списке? Внутри у меня есть идентификатор, имя, фамилия, номер и адрес. Я хочу поместить эти значения в поля text_input.

Спасибо

Answer 1

Похоже, вам нужно два решения вашего вопроса:

1. Вы хотите иметь возможность установить текущий элемент ListView при его нажатии
2. Вы хотите знать, когда изменяется текущий выбор

В документации Qt5 говорится об ListView работе с мышью и сенсорным управлением:

Представления обрабатывают перетаскивание и перетаскивание своего содержимого, однако они не обрабатывают взаимодействие с отдельными участниками. Чтобы делегаты реагировали на сенсорный ввод, например, чтобы установить currentIndex, делегат должен предоставить MouseArea с соответствующей логикой обработки касания.

Ввод с клавиатуры будет работать из коробки, но вам нужно будет явно перехватить событие мыши / касания на делегате и изменить значение ListView.currentIndex на основе значения index выбранного элемента делегата .

Вот полный пример:

import QtQuick 2.4
import QtQuick.Window 2.2

Window {
    width: 640
    height: 480
    visible: true

    ListModel {
        id: model
        ListElement {
            name:'abc'
            number:'123'
        }
        ListElement {
            name:'efg'
            number:'456'
        }
        ListElement {
            name:'xyz'
            number:'789'
        }
    }

    ListView {
        id: list
        anchors.fill: parent
        model: model
        delegate: Component {
            Item {
                width: parent.width
                height: 40
                Column {
                    Text { text: 'Name:' + name }
                    Text { text: 'Number:' + number }
                }
                MouseArea {
                    anchors.fill: parent
                    onClicked: list.currentIndex = index
                }
            }
        }
        highlight: Rectangle {
            color: 'grey'
            Text {
                anchors.centerIn: parent
                text: 'Hello ' + model.get(list.currentIndex).name
                color: 'white'
            }
        }
        focus: true
        onCurrentItemChanged: console.log(model.get(list.currentIndex).name + ' selected')
    }
}

Он делает следующие вещи:

• создает простой список и модель
• использует элемент MouseArea в делегате элемента для обновления, установите list.currentIndex = index, который является локальной переменной и уникальным для выбранного элемента
• прослушивает событие onCurrentItemChanged ListView, чтобы показать, как получить доступ к текущим значениям элемента модели
• привязывает текстовое значение выбранного в данный момент элемента к выделенному элементу, чтобы показать его, используя текущие выбранные значения в другом месте

Answer 2

Ответ предоставлен denoth : Вам необходимо добавить эту строку:

listview1.currentIndex = index 

Answer 3

ListView предоставляет так называемые прикрепленные свойства , то есть свойства, доступные в списке delegate.Среди них Listview.view - ссылка на сам список.Его можно использовать для доступа к свойству currentIndex и его обновления.Следовательно, чтобы решить вашу проблему просто:

1. Раскомментируйте //id: contactDelegate.
2. Установите contactDelegate.ListView.view.currentIndex = index в обработчике OnClick even.

Answer 4

Самый простой, чем когда-либо, вы можете использовать: onCurrentItemChanged

ListView{
    id: listViewMainMenu
    signal Myselect(int playmode)
    onCurrentItemChanged: Myselect(listViewMainMenu.currentIndex)
    // ...
}

Answer 5

Для тех, кто использует подсветку в ListView с определенной высотой (не заполненной на 100%):

Обязательно включите свойство clip объекта ListView, так как в противном случае выделение будет все еще видно за пределами границ ListView при прокрутке.

ListView 
{
    clip: true    
}   

Как обсуждено здесь: Скрыть прокрутку ListView при прокрутке