Используйте XSLT для изменения элементов, встроенных в текст других элементов.

Question

Поскольку я бы, вероятно, испортил терминологию, я объясню на примере.

Мой исходный документ XML содержит такие элементы:

<paragraph>
    This paragraph has things like <link><xref label="lbl1">this</xref></link>
    and things like <emphasis type="bold">this</emphasis>
    and <emphasis type="italic">this</emphasis>.
</paragraph>

Для его преобразования необходимо использовать XSLT.на:

<p>
    This paragraph has things like <a href="[lbl1]">this</a>
    and things like <b>this</b>
    and <i>this</i>.
</p>

Спасибо !!

Answer 1

Текущие два решения слишком длинные, и одно из них даже не является правильно сформированным XML ...

Вот краткое и полное решение :

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="link">
  <a href="[{xref/@label}]">
   <xsl:apply-templates/>
  </a>
 </xsl:template>

 <xsl:template match="emphasis">
  <xsl:element name="{substring(@type,1,1)}">
   <xsl:apply-templates/>
  </xsl:element>
 </xsl:template>
 <xsl:template match="xref">
  <xsl:apply-templates/>
 </xsl:template>
</xsl:stylesheet>

когда это преобразование применяется к предоставленному документу XML:

<paragraph>This paragraph has things like <link><xref label="lbl1">this</xref></link> and things like <emphasis type="bold">this</emphasis> and <emphasis type="italic">this</emphasis>.
</paragraph>

желаемый, правильный результат получается :

<paragraph>This paragraph has things like <a href="[lbl1]">this</a> and things like <b>this</b> and <i>this</i>.
</paragraph>

Answer 2

Это должно сработать:

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl">

  <xsl:output method="xml" indent="yes" />

  <xsl:template match="/">
    <xsl:apply-templates />
  </xsl:template>

  <xsl:template match="paragraph">
    <xsl:element name="p">
      <xsl:apply-templates />
    </xsl:element>
  </xsl:template>

  <xsl:template match="link">
    <xsl:apply-templates />
  </xsl:template>

  <xsl:template match="xref">
    <xsl:element name="a">
      <xsl:attribute name="href">
        <xsl:text>[</xsl:text><xsl:value-of select="@label" /><xsl:text>]</xsl:text>
      </xsl:attribute>
      <xsl:apply-templates />
    </xsl:element>
  </xsl:template>

  <xsl:template match="emphasis">
    <xsl:variable name="elementName">
      <xsl:choose>
        <xsl:when test="@type='bold'">
          <xsl:text>b</xsl:text>
        </xsl:when>
        <xsl:when test="@type='italic'">
          <xsl:text>i</xsl:text>
        </xsl:when>
      </xsl:choose>    
    </xsl:variable>
    <xsl:if test="string-length($elementName)>0">
      <xsl:element name="{$elementName}">
        <xsl:apply-templates />
      </xsl:element>
    </xsl:if>
  </xsl:template>

  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>

</xsl:stylesheet>